[R] Mot de passe dans une GUI

[Trash]

Bonjour,

Je souhaiterais réaliser ce code :

Code : Tout sélectionner

#include <GUIConstants.au3>

$Form1 = GUICreate("Test Mot de passe for AutoIt Forums", 359, 76, 193, 125)
GUICtrlCreateInput("", 8, 16, 121, 21)
$Checkbox1 = GUICtrlCreateCheckbox("Cacher ", 144, 16, 209, 17)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 

Si CheckBox est Coché ( 1 ) alors
on cache le mot de passe
Sinon
on affiche le mot de passe
Fin

"Code"

Code : Tout sélectionner

If $CheckBox1 = "1" Then
; On affiche des "rond"
Else
; On affiche le mot normalement..
EndIf

Merci de vos réponses !


EDIT : Merci de vos réponses !

[SurPriseS]

Salut,
Un début, un peu barbare, mais bon sa marche... (comprendre : on peut surement faire plus propre)

Voilou

Code : Tout sélectionner

#include <GUIConstants.au3>
$test=0
$value=""
$Form1 = GUICreate("Test Mot de passe for AutoIt Forums", 359, 76, 193, 125)
$passwd = GUICtrlCreateInput($value, 8, 16, 121, 21)

$Checkbox1 = GUICtrlCreateCheckbox("Cacher ", 144, 16, 209, 17)
GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    if GUICtrlRead($checkbox1) = 1 then
        if  $test=0 then
            $value=GUICtrlRead($passwd)
            GUICtrlDelete($passwd)
            $passwd = GUICtrlCreateInput($value, 8, 16, 121, 21,0x0020)
            $test=1
        EndIf
        
    endif
    
    if GUICtrlRead($checkbox1) = 4 then
        if  $test=1 then
            $value=GUICtrlRead($passwd)         
            GUICtrlDelete($passwd)
            $passwd = GUICtrlCreateInput($value, 8, 16, 121, 21)
            $test=0
        EndIf
        
    endif   
    
        Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        
    EndSwitch
WEnd
 

[Tlem]

L'idée est bonne.

Voici une autre alternative :

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>

$Form1 = GUICreate("Test Mot de passe for AutoIt Forums", 359, 76, 193, 125)
$Passwd = GUICtrlCreateInput("", 8, 16, 121, 21)
$Passwd2 = GUICtrlCreateInput("", 8, 16, 121, 21, $ES_PASSWORD)
GUICtrlSetState(-1, $GUI_HIDE)
$Cb1 = GUICtrlCreateCheckbox("Cacher ", 144, 16, 209, 17)
GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        
        Case $Cb1
            If BitAND(GUICtrlRead($Cb1), $GUI_CHECKED) = $GUI_CHECKED Then
                GUICtrlSetData($Passwd2, GUICtrlRead($Passwd))
                GUICtrlSetData($Passwd, "") ; Optionnel.
                GUICtrlSetState($Passwd, $GUI_HIDE)
                GUICtrlSetState($Passwd2, $GUI_SHOW)
                ControlClick ( "", "", $Passwd2) 
            Else
                GUICtrlSetData($Passwd, GUICtrlRead($Passwd2))
                GUICtrlSetData($Passwd2, "") ; Optionnel.
                GUICtrlSetState($Passwd2, $GUI_HIDE)
                GUICtrlSetState($Passwd, $GUI_SHOW)
                ControlClick ( "", "", $Passwd) 
            EndIf
    EndSwitch
WEnd