Double-clics remontés par la GUI en x86 mais pas en x64

Aide sur les Interfaces Graphique Utilisateurs (GUI).
Règles du forum
.
Répondre
Elwood
Niveau 1
Niveau 1
Messages : 2
Enregistré le : mer. 07 sept. 2022 20:20
Status : Hors ligne

Double-clics remontés par la GUI en x86 mais pas en x64

#1

Message par Elwood »

Bonjour,

Avec le même code, si je compile pour x86, je peux identifier les double-clics, mais si je compile pour x64, Autoit ne m'averti pas d'un double-clic effectué.

J'utilise par exemple le 2ème bout de code qu'on trouve sur cette page.
Celui qui contient GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Quelqu'un sait ce qui peut provoquer cette différence ?
J'ai trouvé ce bug report qui donne une idée mais je n'ai pas compris comment faire fonctionner la compilation en 64bits.
Avatar du membre
TommyDDR
Modérateur
Modérateur
Messages : 2037
Enregistré le : mar. 22 juil. 2008 21:55
Localisation : Nantes
Status : En ligne

Re: Double-clics remontés par la GUI en x86 mais pas en x64  

#2

Message par TommyDDR »

Il explique que
Local $tagNMHDR = DllStructCreate("int;int;int", $lParam)
n'est pas bon.

Mais qu'il faut utiliser :
Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)

Code complet fonctionnel :
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>
#include <Array.au3>

Global $aData[5] = [4, "Item 1", "Item 2", "Item 3", "Item 4"]
Global $aItem_Handles[UBound($aData)]

Global $hMain_GUI = GUICreate("TreeView Demo", 500, 500)

$hTree = GUICtrlCreateTreeView(10, 10, 480, 480)
$hRoot = GUICtrlCreateTreeViewItem("Root", $hTree)
For $i = 1 To $aData[0]
    $aItem_Handles[$i] = GUICtrlGetHandle(GUICtrlCreateTreeViewItem($aData[$i], $hRoot))
Next

GUISetState()

; Initialise "DoubleClick on TreeView function"
GUIRegisterMsg($WM_NOTIFY, "MY_WM_NOTIFY")

Global $fDblClk = False

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Check if tree view double clicked
    If $fDblClk = True Then
        $sText = _GUICtrlTreeView_GetText($hTree, _GUICtrlTreeView_GetSelection($hTree))
        MsgBox(0, "Hit", "You double clicked on " & $sText )
        $fDblClk = False
    EndIf
WEnd

Func MY_WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)

    Switch $wParam
        Case $hTree
            Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
            If @error Then Return
            If DllStructGetData($tNMHDR, 3) = $NM_DBLCLK Then $fDblClk = True
    EndSwitch

EndFunc  ;==>MY_WM_NOTIFY
3.1415926535897932384626433832795028841971693993751058209749445923078164062862089986280348253421170679
Elwood
Niveau 1
Niveau 1
Messages : 2
Enregistré le : mer. 07 sept. 2022 20:20
Status : Hors ligne

Re: Double-clics remontés par la GUI en x86 mais pas en x64

#3

Message par Elwood »

Cool !
Merci, je vais adapter ça à mon code.
Répondre