[..] Email automatique

[Parn]

Bonjour,

J'aimerais pouvoir faire un script qui envoie des emails automatiquement sur n'importe quel machine et de n'importe quel machine.

Seulement je n'ai pas trouvé un seul script qui marchait.
Genre comme celui la

Code : Tout sélectionner

DirCreate(@TempDir & "\test")   ; Creer un dossier dans Temp appellé TEST
InetGet("http://arrkhan.free.fr/fai.php", @TempDir & "\test\smtp")  ; Va sur ton SITE et je sais pas
$s_SmtpServer = FileRead(@TempDir & "\test\smtp") ; La variable smtpserver prend la valeur du fichier smtp situé dans temps test

Voila merci d'avance !

[BeCool]

Bonjour.

Serrait-il possible d'avoir plus de renseignements ? Parce que là c'est très bref ...

Faire un script qui envoie des mails automatiquement ? Quel genre de mail ? Quel contenu ? Le script doit prendre un texte quelque part pour l'envoyé par mail ?

Si vous ne donnez pas plus de renseignements, je doute fortement que quelqu'un puisse vous aider

[Parn]

C'est un mail invisible de l'expéditeur qui m'envoie un email me disant que l'expéditeur à utiliser mon logiciel avec son adresse.

[BeCool]

Dans ces cas là, le plus simple a mon avis serrait de mettre directement ce script dans votre programme pour faire ce que vous voulez.
Enfin bon, je suis débutant, donc je ne m'avance pas plus, je passe le relais aux pro :p

[Tlem]

Pour envoyer un email, il faut un serveur de courrier sortant.
Si votre 'client' est sur le même prestataire ça va mais sinon ...
L'envoi d'un email sur un serveur anonyme n'est pas trop possible car non sur et non stable.

La solution est donc de créer une boite aux lettres et d'utiliser les paramètres de cette boite aux lettre pour envoyer l'email . Autant dire que c'est assez risqué ...
De plus l'utilisateur peut ne pas être connecté, ou refuser l'envoi de cet email.

Autre solution (mais il faut aussi être connecté), c'est l'utilisation d'un site web, qui serais sollicité sur une page spéciale avec entrée de données ou formulaire.
Un domaine c'est environ 8 euros par an selon le prestataire. Donc cela peut sans doute être une bonne solution.

[Parn]

Et il n'y a pas une moyen, une macro pour récupérer le serveur Smtp de l'utilisateur?

[Tlem]

Ben c'est plus compliqué que ça n'y parait ...

Pour avoir le serveur SMTP de l'endroit ou vous-vous connecté il vous suffit d'utiliser la page de arrkhan ou la notre : http://www.autoitscript.fr/smtp.php
Mais selon certains prestataires, certains lieu, et selon d'autres critères, cette solution peut ne pas fonctionner.

C'est pour ça qu'un simple lien sur une page Web vous donnera plus de sécurité et fiabilité.

[BeCool]

Il me semble qu'il existe des domaines gratuit (mais très limité).

C'est peut être une solution si vous ne voulez pas dépensé d'argent

[Parn]

aie

On ne pourrait pas faire une liste de tout les serveurs smtp, puis le message est envoyé si on ne reçoit pas d'erreur?

[Tlem]

Oui c'est surement possible.
Bon courage ...

[jl56]

Bonjour à tous

Pour envoyer des mails de tous sites sans connaitre le smtp
j'utilise un compte gmail
je paramètre l'envoie d'email en sll avc avec le port 465

► Afficher le texte

Code : Tout sélectionner

Func _INetSmtpMailCom()
;ici je test si le pc a acces a internet
$ipwan=""
$ipwan=_GetIP()
if $ipwan="" then  Return

$s_Subject = "sujet de l'email"
$s_CcAddress = ""
$s_SmtpServer="smtp.gmail.com"
$s_FromName="de qui"
$s_FromAddress="monadresse@gmail.com"
$s_ToAddress="destinataire@orange.fr"
$s_Username="nom du compte gmail"
$s_Password="mot de passe compte gmail"
$as_Body = "corps du message"
$s_AttachFiles = "";"" ; the file you want to attach- leave blank if not needed
$s_BccAddress = "" ; address for bcc - leave blank if not needed
$IPPort=465




if $IPPort=465 then $ssl=1
;~ MsgBox(0,"ssl",$ssl)
$objEmail = ObjCreate("CDO.Message")
$objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
$objEmail.To = $s_ToAddress
Local $i_Error = 0
Local $i_Error_desciption = ""
If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
$objEmail.Subject = $s_Subject
If StringInStr($as_Body,"<") and StringInStr($as_Body,">") Then
$objEmail.HTMLBody = $as_Body
Else
$objEmail.Textbody = $as_Body & @CRLF
EndIf
If $s_AttachFiles <> "" Then
Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
For $x = 1 To $S_Files2Attach[0]
$S_Files2Attach[$x] = _PathFull ($S_Files2Attach[$x])
If FileExists($S_Files2Attach[$x]) Then
$objEmail.AddAttachment ($S_Files2Attach[$x])
Else
$i_Error_desciption = $i_Error_desciption & @lf & 'File not found to attach: ' & $S_Files2Attach[$x]
SetError(1)
return 0
EndIf
Next
EndIf
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
;Authenticated SMTP
If $s_Username <> "" Then
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
EndIf
If $Ssl Then
;~  MsgBox(0,"ssl ok",$ssl)
$objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1
EndIf
;Update settings
$objEmail.Configuration.Fields.Update
; Sent the Message
$objEmail.Send
if @error then
SetError(2)
return $oMyRet[1]
EndIf
EndFunc ;==>_INetSmtpMailCom*$

Func MyErrFunc()
$HexNumber = Hex($oMyError.number, 8)
$oMyRet[0] = $HexNumber
$oMyRet[1] = StringStripWS($oMyError.description,3)
;~ MsgBox (0,"### erreur d'envoie de la notificaton "," ! Numéro: " & $HexNumber & " ligne du script&#058; " & $oMyError.scriptline & " Description:" & $oMyRet[1] & @LF,20)
SetError(1); something to check for when this function returns
Return

EndFunc ;==>MyErrFunc

Voila tu pourras l'adapter selon tes besoins
sur le compte gmail il faut activer l'envoie et reception en compte pop/smtp
sur le site c'est bien expliqué

ça fonctionne partout sauf chez un client qui utilise un proxy
je suppose que le port 465 est bloqué

realise quelques tests pour vérifier le bon fonctionnement

a+ JL56

[Tlem]

Oui, c'est bien ce que j'ai déjà dit.
Il faut utiliser les paramètres d'un compte mail (login/passwd), et là c'est à réfléchir, car si un 'vilain' récupère ces paramètres, tout lui est possible (sur cette boite) !!!

[Parn]

Aie, désolé mais ton script ne marche pas du tout j'ai tout ça comme erreur :

Code : Tout sélectionner

C:\Mail.au3(70,18) : WARNING: $oMyRet: possibly used before declaration.
return $oMyRet[1]
~~~~~~~~~~~~~~~~~^
C:\Mail.au3(75,34) : WARNING: $oMyError: possibly used before declaration.
$HexNumber = Hex($oMyError.number,
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Mail.au3(75,34) : ERROR: $oMyError: undeclared global variable.
$HexNumber = Hex($oMyError.number,
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Mail.au3(4,15) : ERROR: _GetIP(): undefined function.
$ipwan=_GetIP()
~~~~~~~~~~~~~~^
C:\Mail.au3(41,53) : ERROR: _PathFull(): undefined function.
$S_Files2Attach[$x] = _PathFull ($S_Files2Attach[$x])
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Mail.au3 - 3 error(s), 2 warning(s)

Quelqun peut m'aider ?

[jl56]

bonjour

Excuse moi j'avais sortie d'un de mes scripts cette partie du code
sans tester le résultat isolement.

Ajoute ceci au début du code que j'ai déjà fournie

Code : Tout sélectionner

#include <File.au3>
#include <Inet.au3>
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
Global $oMyRet[2]
_INetSmtpMailCom()
Exit

;ci dessous le code que tu as déjà

la j'ai bien testé le code, les emails partent bien sans probleme

je me joint a Tlem sur l'avertissement concernant la saisie des parametres de messagerie dans le code ( décompilation possible) .
Moi j'ai créé une adresse spécifique pour mon appli
J'ajoute que gmail est très efficace concernant les virus et spam

A+ JL56

[Parn]

Bonjour,

Merci, ça marche à merveille ! ^^

Dès que j'ai finis mon logiciel je fais un tutoriel pour ceux que ça pourrait intéresser !

Et hop je met mon sujet comme résolu !

Merci encore !

Bye