[R] Image en plein écran

[timmalos]

Bonjour à tous.
J'ai eu l'envie de me faire un beau petit programme pour décompresser quand vous avez eu une rude journée.
Quoi de mieux que de belles images avec de la musique de fond a vous couper le souffle?
Voila le code, mais le problème avec c'est qu'a chaque fois qu'il change de musique, on voit la coupure pendant quelques dixièmes de seconde et ce n'est pas vraiment top ...
Des idées??

► Afficher le texteCode

Code : Tout sélectionner

#include <Sound.au3>
$hFile = "musique.mp3"
$mFile1 = "1.jpg"
$mFile2 = "2.jpg"
$mFile3 = "3.jpg"
$mFile4 = "4.jpg"
$mFile5 = "5.jpg"
$mFile6 = "6.jpg"
$mFile7 = "7.jpg"
$mFile8 = "8.jpg"
$mFile9 = "9.jpg"
;~ $mFile10 = ""
;~ $mFile11 = ""
;~ $mFile12 = ""
;~ $mFile13 = ""
;~ $mFile14 = ""

$sound =_SoundOpen ( $hFile )

;gestion des erreurs
If @error = 2 Then
    MsgBox(0, "Error", "The file does not exist")
    Exit
ElseIf @error = 3 Then
    MsgBox(0, "Error", "The alias was invalid")
    Exit
ElseIf @extended <> 0 Then
    $extended = @extended ;assign because @extended will be set after DllCall
    $stText = DllStructCreate("char[128]")
    $errorstring = DllCall("winmm.dll","short","mciGetErrorStringA","str",$extended,"ptr",DllStructGetPtr($stText),"int",128)
    MsgBox(0, "Error", "The open failed." & @CRLF & "Error Number: " & $extended & @CRLF & "Error Description: " & DllStructGetData($stText, 1) & @CRLF & "Please Note: The sound may still play correctly.")
EndIF


_SoundPlay ( $sound )
While 1
    Sleep(100)
    If _SoundPos($sound, 2) = _SoundLength($sound, 2) Then ExitLoop

SplashImageOn("Boo", $mFile1 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile2 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile3 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile4 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile5 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile6 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile7 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile8 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
SplashImageOn("Boo", $mFile9 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
Sleep(2200)
;~ SplashImageOn("Boo", $mFile10 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
;~ Sleep(2200)
;~ SplashImageOn("Boo", $mFile11 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
;~ Sleep(2200)
;~ SplashImageOn("Boo", $mFile12 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
;~ Sleep(2200)
;~ SplashImageOn("Boo", $mFile13 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
;~ Sleep(2200)
;~ SplashImageOn("Boo", $mFile14 ,@DesktopWidth ,@DesktopHeight , "", "", 1)
;~ Sleep(2200)
SplashOff ()    
    
    
WEnd
_SoundClose($sound)

Bien sur, après avoir réglé ce léger problème, je compte bien :

-Mettre les images dans un ordre aléatoire.
-Insérer les images dans le script
-Gérer une Gui pour choisir la musique, styles d'images, etc

Dans le .zip, vous avez les quelques images de démarrage ainsi qu'une musique que vous reconnaitrez et qui va parfaitement pour ce projet. (La premier qui me donne l'auteur a gagné )
Telechargement ICI (5 mo environs)

[Tlem]

Bon, alors pour l'auteur, c'est tout simplement Evángelos Odysséas Papathanassíou aussi connu sous le nom de Vangélis Papathanassíou ou encore plus simplement Vangelis.
Le titre de la musique est : Chariots of fire (Bande originale du film 'Les Chariots de feu' de Hugh Hudson), qui à l'origine fait pas moins de 20 min 41 s !!!

En ce qui concerne votre script, vous le trouverez ci-dessous amélioré et agrémenté de quelques simplifications et améliorations.
- Gestion automatique des images (Liste les jpg).
- Gestion automatique des musiques (Liste les MP3).
- Affiche les images de manière aléatoire.
- Joue les musiques de manière aléatoire.

► Afficher le texteCode

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <Sound.au3>
#Include <File.au3>

Opt("OnExitFunc", "Fin")
HotKeySet("{ESC}", "Fin")

; Répertoire des images et des MP3.
$RepMedia = @ScriptDir
Dim $hSound, $Tempo = 5000

$aImg = _FileListToArray($RepMedia, "*.jpg", 1)
$aZik = _FileListToArray($RepMedia, "*.mp3", 1)

_PlayZik()

$hGUI = GUICreate("", @DesktopWidth, @DesktopHeight, -1, -1, $WS_POPUP, $WS_EX_TOPMOST)
$Pic1 = GUICtrlCreatePic("", 0, 0, @DesktopWidth, @DesktopHeight)
GUISetState()

While 1
    ; 4 secondes avant la fin de la musique, on change de musique.
    If _SoundPos($hSound, 2) > _SoundLength($hSound, 2) - 4000 Then _PlayZik()

    ; Affiche une image prise au hazard dans le tableau $aImg
    GUICtrlSetImage($Pic1, $aImg[_Random($aImg[0])])
    Sleep($Tempo)
WEnd

; Joue une musique pris au hazard dans le tableau $aZik
Func _PlayZik()
    $hSound =_SoundOpen ($aZik[_Random($aZik[0])])
    _SoundSeek ($hSound, 0, 0, 2)
    _SoundPlay ($hSound)
EndFunc

; Petite fonction à cause d'un bug de Random (Random(1, 1, 1) => 0 !!!).
Func _Random($ValMax)
    $Res = Random(1, $ValMax, 1)
    If $Res = 0 Then $Res = 1
    Return $Res
EndFunc

Func Fin()
    _SoundClose($hSound)
    Exit 0
EndFunc

La barre des taches reste visible si elle n'est pas masquée, et certaines application peuvent apparaitre en premier plan, mais le SplashImage avait le fâcheux inconvénient de laisser apparaitre le bureau entre 2 images.

[arrkhan]

tiens, c'est toujours plus facile a faire qu'en AutoIt (honte sur moi ^^)

Timmalos_Saver.EXE

[timmalos]

Merci vous 2

Je me doutais devoir passer par une GUI, mais je voulais voir si c'etait possible autrement.
Bravo Tlem (pour Vangelis)

[Tlem]

Cela aurait été bien que tu précise que c'est un fichier d'installation et que c'est fait avec IScreenSaver (Qui à besoin de QuickTime) !!!

timmalos l'avait demandé en AutoIt donc ça ne répond pas trop à la question.
Sinon IView32 fait la même chose.

[arrkhan]

pour moi, il etait clair que mon post etait totalement hors sujet ^^