[..] Gestion de l'interface Livebox

[jguinch]

Oui, c'est encore mieux de se passer d'include, surtout que là on n'a pas besoin de 50 fonctions.

[walkson]

Bonjour,
@jguinch: pour le reboot, c'est un caprice de mon PC. Aujourd’hui, il fonctionne très bien (!?!).
J'ai 2 suggestions (demandes) à formuler:
La première serait un contrôle de connexion au démarrage, au Refresh et au reboot. J'avais pensé à l'UDF de Tlem ([UDF] _NicControl.au3 (Contrôle des connexions réseau)) mais il y a plus simple par InetRead() Tant qu'il renvoie @error, il n'y a pas de connexion.
Ma deuxième demande serait une analyse (simple) des données pour l'ignare que je suis. Quelque chose comme "bon" "moyen" "mauvais" sur les données récoltées afin de savoir si la connexion est correcte.(Une nouvelle Tab "Résumé_Analyse" par ex.)
En tout cas, merci pour le partage

[mikell]

My 2 cents : activer/désactiver le wifi

► Afficher le texte

Code : Tout sélectionner

Global $sLiveboxUsername = "admin"
Global $sLiveboxPassword = "XXXXXXXX"
Global $sContextID, $oHTTP = ObjCreate("Microsoft.XMLHTTP")

_Login()

_Wifi(false)
Msgbox(0,"", "wifi désactivé")

_Wifi(true)
Msgbox(0,"", "wifi activé")

_Logout()

;===========================================
Func _Wifi($bool)
    If not IsBool($bool) Then Return SetError(1, 0, 0)
    $bool = StringLower($bool)
    $params = '{"parameters":{"mibs":{"penable":{"wifi0_ath":{"PersistentEnable":' & $bool & ',"Enable":' & $bool & '}}}}}'
    $str = "/sysbus/NeMo/Intf/wl0:setWLANConfig"
    $oHTTP.Open("POST", "http://192.168.1.1" & $str, False)
    $oHTTP.SetRequestHeader("X-Context", $sContextID)
    $oHTTP.Send($params)
    Return 1
EndFunc

Func _Login()
    $str = "/authenticate?username=" & $sLiveboxUsername & "&password=" & $sLiveboxPassword
    $oHTTP.Open("POST", "http://192.168.1.1" & $str, False)
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.Send()
    $sData = $oHTTP.ResponseText
    $sContextID = StringRegExp($sData, 'contextID":"([^"]+)"|()$', 1)[0]
EndFunc

Func _Logout()
    $oHTTP.Open("POST", "http://192.168.1.1/logout", False)
    $oHTTP.Send()
    $oHTTP = 0
EndFunc
 

[jguinch]

Impec ! Ca marche bien.
Reste à savoir si cetipabo veut l'intégrer dans son interface...

[mikell]

C'est vrai que l'intérêt peut paraître discutable avec un bouton wifi on/off en façade

J'ai pas approfondi, mais bizarrement en regardant s'agiter les petits voyants verts j'ai remarqué que le comportement de l'engin n'était pas tout à fait le même selon la commande par script ou par ce bouton
Et puis ça permet une activation/désactivation logicielle sous conditions (plage horaire, applications en cours, etc) bien propre
En fait dans un script on peut faire un seul bouton dont l'action dépend du status en cours du wifi (ON si désactivé, OFF si activé)

► Afficher le texte

Code : Tout sélectionner

Global $sLiveboxUsername = "admin"
Global $sLiveboxPassword = "XXXXXXXX"
Global $sContextID, $status, $command
Global $oHTTP = ObjCreate("Microsoft.XMLHTTP")

$gui =  GuiCreate("wifi", 180, 70, -1, 200)
$lab_wifi = GuiCtrlCreateLabel("", 10, 10, 160, 20, 0x01)
$btn_wifi = GuiCtrlCreateButton("", 30, 35, 120, 25)
GuiSetState()

_Login()
_CheckWifiStatus()
_Logout()

While 1
   $msg = GuiGetMsg()
   If $msg = -3 Then Exitloop
   If $msg = $btn_wifi Then 
       _Login()
       $command = not _CheckWifiStatus()
       _ActivateWifi($command)
       _CheckWifiStatus()
       _Logout()
   EndIf
Wend
$oHTTP = 0


Func _ActivateWifi($bool)   ; true/false
    If not IsBool($bool) Then Return SetError(1, 0, 0)
    $bool = StringLower($bool)
    $params = '{"parameters":{"mibs":{"penable":{"wifi0_ath":{"PersistentEnable":' & $bool & ',"Enable":' & $bool & '}}}}}'
    $str = "/sysbus/NeMo/Intf/wl0:setWLANConfig"
    $oHTTP.Open("POST", "http://192.168.1.1" & $str, False)
    $oHTTP.SetRequestHeader("X-Context", $sContextID)
    $oHTTP.Send($params)
EndFunc

Func _CheckWifiStatus()
    ; Recuperation des donnees wifi
    $str = "/sysbus/NeMo/Intf/lan:getMIBs"
    $oHTTP.Open("POST", "http://192.168.1.1" & $str, False)
    $oHTTP.SetRequestHeader("X-Context", $sContextID)
    $oHTTP.Send('{"parameters":{"mibs":"base wlanvap","flag":"wlanvap","traverse":"down"}}')
    $sData = $oHTTP.ResponseText
$status = StringRegExpReplace($sData, '.*VAPStatus":"(\w+).*', "$1")  ; virtual acces point
 If $status = "Up" Then
   GuiCtrlSetData($lab_wifi, "Le Wifi est activé")
   GuiCtrlSetData($btn_wifi, "Désactiver le Wifi")
   Return 1
 ElseIf $status = "Down" Then
   GuiCtrlSetData($lab_wifi, "Le Wifi est désactivé")
   GuiCtrlSetData($btn_wifi, "Activer le Wifi")
   Return 0
 EndIf
EndFunc

Func _Login()
    $str = "/authenticate?username=" & $sLiveboxUsername & "&password=" & $sLiveboxPassword
    $oHTTP.Open("POST", "http://192.168.1.1" & $str, False)
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.Send()
    $sData = $oHTTP.ResponseText
    $sContextID = StringRegExp($sData, 'contextID":"([^"]+)"|()$', 1)[0]
EndFunc

Func _Logout()
    $oHTTP.Open("POST", "http://192.168.1.1/logout", False)
    $oHTTP.Send()
EndFunc
 

[Utilisateur 3309 supprimé]

Bonjour,
je n'ai pas eu le temps de m'occuper du script, je vais m'y remettre dès mon retour de vacances, mais tout ce que vous développez est très interessant, je vais l'intégrer dès que possible. Concernant le Wifi moi je trouve ca sympa (ca coute rien de le mettre) dans l'application. Et je trouve que c'est encore mieux dans un petit exécutable indépendant.
En fait La LiveBox a un bug connu concernant l'heure d'été/hiver qui n'est pas prise en compte sur les plages horaires d'activation du wifi. Avoir un outil qu'on peut intégrer dans une tache planifiée sur un serveur peut être très utile pour certains.

[Utilisateur 3309 supprimé]

bonjour,
j'ai fait une mise à jour en utilisant winhttp comme évoqué plus haut.
je suis actuellement en vacances chez des amis qui ont une FREEBOX donc je ne peux pas tester ce que je fais, je m'occuperai du wifi à mon retour.

[mikell]

Je viens de jeter un oeil à ton script
Attention dans le logout, "$oHTTP = 0" détruit l'objet winhttprequest, tu auras un bug si un utilisateur veut par exemple faire un refresh après une reconnexion ($oHTTP.Open => failure)

[Utilisateur 3309 supprimé]

ha merdum, voilà ce que c'est quand on ne teste pas tout...je rectifie de suite.
merci mikell

[Utilisateur 3309 supprimé]

Bonjour,
j'ai entrepris un nouveau script pour supprimer de sa LiveBox tous les périphériques non connectés ou "fantomes".
Sur les LB2 et LB3 cette fonctionnalité n'existe pas dans l'interface, pourtant il est possible de le faire car l'application MyLivebox d'orange le permet.
Ce programme étant assez lourd 80Mo + toutes les conneries qu'il installe avec...je me suis dit que j'allais faire un truc pour remédier à ça.

Mon script marche parfaitement sur ma LB3 Play mais n'ayant pas de LB2 je suis bloqué car il y a une petite différence pour récupérer la liste du matériel non connecté, mais malgé les indications qu'on me donne on n'y arrive pas, on doit rater une étape quelque part...
Voici la discution sur le forum Orange: http://www.forum-orange.com/forums/view ... p?id=73419

D'après les indications qu'on me donne ici et là
Je fais donc des requettes pour obtenir un nombre (le ChannelID) qui sera utilisé ensuite dans une requête permettant de demander la liste du matériel, mais on est bloqué là...

La partie concernant la LB2 dans mon script se situe à la ligne 128.

voilà la source:
http://pastebin.com/DRH0SAXb

et l'application compilée + source:
http://liveboxinfo.tk/download/LBRemoveDevice.zip



1) on indique le mot de passe de la Livebox et éventuellement son IP ou nom d'hote.
2) si la connexion est établie on obtient dans le menu déroulant la liste des périphériques déconnectés (ou fantômes).
3) on sélectionne le périphérique qu'on ne souhaite plus voir et on clique SUPPRIMER.
4) Pour supprimer tous les périphériques de la liste, utiliser le bouton de gauche.

[mikell]

Bon bin j'ai une mauvaise nouvelle : pas possible sur Livebox 2, la commande n'existe tout simplement pas
Le bazar est enregistré quelque part dans les entrailles de la bête et non modifiable
Du coup lister les équipements ne présente guère d'intérêt, ton code pour le faire ne marche pas sur ma LB2 et je t'avoue que vu les circonstances je n'ai pas essayé de savoir pourquoi

[Utilisateur 3309 supprimé]

pour résumer:
sur LB2 l'envoie en POST de : {"parameters":{"physAddress":"<ADRESSE_MAC>"}}
sur http://livebox/sysbus/Hosts:delHost

ne supprime pas l'appareil ??

[walkson]

Bonsoir,
Sur http://192.168.1.1/ (à droite)

Code : Tout sélectionner

aide
Cette page présente les équipements qui ont déjà été connectés à la Livebox au moins une fois lors des trois derniers mois, mais qui ne le sont pas actuellement. Les équipements qui n'ont pas été connectés lors des 3 derniers mois sont supprimés automatiquement de cette table.

et http://livebox/sysbus/Hosts:delHost => Firefox ne peut trouver le fichier à l'adresse http://livebox/sysbu/Hosts:delHost.

[Utilisateur 3309 supprimé]

haaa merdum...c'est un autre lien sur LB2 alors...

[mikell]

Sur ma LB2 il n'y a pas de commande manuelle permettant de supprimer un équipement (non connecté ou pas), donc fatalement la commande logicielle correspondante n'existe pas

[Utilisateur 3309 supprimé]

Oui, idem sur LB3
Et pourtant c'est possible avec l'application mylivebox, c'est comme ca que j'ai trouvé pour la LB3, en sniffant le reseau lorsque j'ai cliqué sur supprimer
je pense que le URL n'est pas la même sur LB2...

[Utilisateur 3309 supprimé]

c'est bon on arrive a obtenir la liste des périphériques sur LB2:
http://pastebin.com/ZLX3cB0Q
on avance...

EDIT:
ca y est ca marche !

[mikell]

Bravo
Il doit y avoir un petit souci d'array ou de combo parce qu'il manque les 3 derniers mais c'est vraiment un détail

[Utilisateur 3309 supprimé]

je ne sais pas comment c'est arrivé mais mon pastebin a disparu...bref je poste le code ici:

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=orange.ico
#AutoIt3Wrapper_UseUpx=y
#AutoIt3Wrapper_Res_Fileversion=1.0.0
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("LiveBox - Suppression de périphériques", 435, 153, 192, 124)
$Combo1 = GUICtrlCreateCombo("Périphépiques déconnectés", 24, 72, 385, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL,$CBS_DROPDOWNLIST))
        GUICtrlSetState($Combo1, $GUI_DISABLE)
$Label1 = GUICtrlCreateLabel("Selectionnez un périphérique à supprimer", 24, 56, 198, 16)
$Button1 = GUICtrlCreateButton("Supprimer", 336, 112, 75, 25)
$Button2 = GUICtrlCreateButton("Supprimer tout", 24, 112, 75, 25)
    GUICtrlSetState($Button1, $GUI_DISABLE)
    GUICtrlSetState($Button2, $GUI_DISABLE)
$Input1 = GUICtrlCreateInput("admin", 24, 24, 65, 21)
    GUICtrlSetState($Input1, $GUI_DISABLE)
$Input2 = GUICtrlCreateInput("", 96, 24, 161, 21, $ES_PASSWORD) ;Password
$Label2 = GUICtrlCreateLabel("Utilisateur", 24, 8, 50, 16)
$Label3 = GUICtrlCreateLabel("Mot de passe", 96, 8, 68, 16)
$Label4 = GUICtrlCreateLabel("Livebox IP/host", 264, 8, 79, 16)
$Input3 = GUICtrlCreateInput("livebox", 264, 24, 81, 21)
$Button3 = GUICtrlCreateButton("Connexion", 352, 22, 59, 24)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $USER = "admin"
Global $LIVEBOX = ""
Global $sContextID = ""
Global $PASSWORD = ""
Global $sDevice_list =""
Global $sMenu = ""
Global $sDefaut_device = ""


$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button3 ;Connexion ********************************************************

            $PASSWORD = GUICtrlRead($Input2)
            $LIVEBOX = GUICtrlRead($Input3)

            if ($PASSWORD ="") Then
                msgbox(48,"ERREUR","Veuillez indiquer votre mot de passe Livebox")
            Elseif ($LIVEBOX ="") Then
                msgbox(48,"ERREUR","Veuillez indiquer une IP ou un nom d'hote pour votre LiveBox")
            Else
                if auth_livebox()="" then
                    Device_list()
                    GUICtrlSetState($Combo1, $GUI_ENABLE)
                    GUICtrlSetState($Button1, $GUI_ENABLE)
                    GUICtrlSetState($Button2, $GUI_ENABLE)
                    GUICtrlSetData($Combo1, "", "") ; destruction liste précédente
                    GUICtrlSetData($Combo1, $sMenu, $sDefaut_device)
                    ;msgbox(0,"Connexion","Connexion établie.")
                endif
            EndIf

        Case $Button1 ;supprimer 1 périphérique *******************************************
            $sDevice = GUICtrlRead($Combo1)
            $aMac = StringSplit($sDevice,"/")
            if $sDevice<>"" Then
                $sMac = StringReplace($aMac[2]," ","") ; on enelève les espaces
                Delete_Device($sMac)
                msgbox(0,"Suppression","Périphérique supprimé.")
                Device_list()
                GUICtrlSetData($Combo1, "", "") ; destruction liste précédente
                GUICtrlSetData($Combo1, $sMenu, $sDefaut_device)
            Endif

        Case $Button2 ;supprimer tous les périphériques ************************************
            Delete_All()
            msgbox(0,"Suppression","Tous les périphériques ont été supprimés.")
            Device_list()
            GUICtrlSetData($Combo1, "", "") ; destruction liste précédente
            GUICtrlSetData($Combo1, $sMenu, $sDefaut_device)

    EndSwitch
WEnd


Func auth_livebox()
    $str = "/authenticate?username=" & $USER & "&password=" & $PASSWORD
    $oHTTP.Open("POST", "http://" & $LIVEBOX & $str, False)
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.Send()
    $oReceived = $oHTTP.ResponseText
    $sContextID = StringRegExp($oReceived, 'contextID":"([^"]+)"|()$', 1)[0]
    if $sContextID="" Then
        msgbox(48,"ERREUR"," Mot de passe incorrect : " & $PASSWORD)
        return "NOLOGIN"
    EndIf
EndFunc     ;==>auth_livebox

Func Device_list()
    if LB_type()="lbv3fr" Then ;Livebox 3
        $PARAMS = '{"parameters":{"expression":".Active==false","traverse":"down","flags":""}}'
        $oHTTP.Open("POST", "http://" & $LIVEBOX & "/sysbus/Devices:get", False)
        $oHTTP.SetRequestHeader("X-Context", $sContextID)
        $oHTTP.Send($PARAMS)
        $sDevice_list = $oHTTP.ResponseText

        $aDevice_Names = StringRegExp($sDevice_list, 'bridge","Name":"(.*?)","DeviceType', 3)
        $aDevice_MAC = StringRegExp($sDevice_list, 'PhysAddress":"(.*?)","Ageing', 3)
        $aDevice_IP = StringRegExp($sDevice_list, 'IPAddress":"(.*?)","IPAddressSource', 3)
        Global $aAll_MAC = $aDevice_MAC
        $sMenu = ""
        for $i=0 to ubound($aDevice_Names) - 1 ; creation de la liste pour menu déroulant
            $sMenu = $sMenu & $aDevice_Names[$i] & " / " & $aDevice_MAC[$i] & " / " & $aDevice_IP[$i] & "|"
        Next
        if isArray($aDevice_Names) then
            $sDefaut_device = $aDevice_Names[0] & " / " & $aDevice_MAC[0] & " / " & $aDevice_IP[0]
        Else
            $sDefaut_device=""
        Endif

    Elseif LB_type()="lbv2fr" Then ; Livebox 2
        $PARAMS = '{"parameters":{}}'
        $oHTTP.Open("POST", "http://" & $LIVEBOX & "/sysbus/Hosts:getDevices", False)
        $oHTTP.SetRequestHeader("X-Context", $sContextID)
        $oHTTP.Send($PARAMS)
        $sDevice_list = $oHTTP.ResponseText

        $aDevice_Names = StringRegExp($sDevice_list, 'hostName":"(.*?)","dnsName', 3)
        $aDevice_MAC = StringRegExp($sDevice_list, 'physAddress":"(.*?)","ipAddress', 3)
        $aDevice_ACTIV = StringRegExp($sDevice_list, 'active":(.*?),"lastConnection', 3)
        $aDevice_IP = StringRegExp($sDevice_list, 'ipAddress":"(.*?)","addressSource', 3)
        Global $aAll_MAC = $aDevice_MAC
        $sMenu = ""
        for $i=0 to ubound($aDevice_Names) - 1 ; creation de la liste pour menu déroulant
            if $aDevice_ACTIV[$i] = "false" Then
                $sMenu = $sMenu & $aDevice_Names[$i] & " / " & $aDevice_MAC[$i] & " / " & $aDevice_IP[$i] & "|"
            EndIf
        Next
        if isArray($aDevice_Names) then
            $sDefaut_device = $aDevice_Names[0] & " / " & $aDevice_MAC[0] & " / " & $aDevice_IP[0]
        Else
            $sDefaut_device=""
        Endif
    Endif

EndFunc     ;==>Device_list

Func Delete_Device($Mac_address)
    if $Mac_address="" Then
        msgbox(48,"ERREUR","Tous les périphériques ont été supprimés.")
    Else
        $PARAMS = '{"parameters":{"physAddress":"' & $Mac_address & '"}}'
        $oHTTP.Open("POST", "http://" & $LIVEBOX & "/sysbus/Hosts:delHost", False)
        $oHTTP.SetRequestHeader("X-Context", $sContextID)
        $oHTTP.Send($PARAMS)
    Endif
EndFunc     ;==>Delete_Device

Func Delete_All()
    For $i=0 to ubound($aAll_MAC) - 1
        $PARAMS = '{"parameters":{"physAddress":"' & $aAll_MAC[$i] & '"}}'
        $oHTTP.Open("POST", "http://" & $LIVEBOX & "/sysbus/Hosts:delHost", False)
        $oHTTP.SetRequestHeader("X-Context", $sContextID)
        $oHTTP.Send($PARAMS)
    Next
EndFunc     ;==>Delete_All

Func LB_type()
    $oHTTP.Open("GET", "http://" & $LIVEBOX, False)
    $oHTTP.Send()
    $return = $oHTTP.ResponseText

    $aModel = StringRegExp($return, "BUILD_PROJECT: '(.*?)',", 3)
    if IsArray($aModel) Then
        $sModel = $aModel[0]
    else
        msgbox(48,"ERREUR","Model de Livebox inconnu")
        Exit
    EndIf
    return $sModel

EndFunc     ;==>LB_type

[mikell]

Le souci d'affichage c'est bien la combo (vaut mieux laisser le stle par défaut)
Sinon la fonction Delete_All() supprime effectivement tout, même les équipements connectés