[R] drag & drop, listview et $WS_CHILD problème

[serpafi]

Bonjour à tous,
Je cherche à pouvoir faire un drag & drop sur une listview située sur une gui enfant.
Le problème c'est en utilisant $WS_CHILD, le drag & drop ne fonctionne plus

Code: [Tout sélectionner] [Déplier/Replier]

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <file.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <GuiEdit.au3>

#Region
$gui1 = GUICreate("Form1", 738, 506, 548, 270,BitOR($GUI_SS_DEFAULT_GUI,$WS_MAXIMIZEBOX,$WS_SIZEBOX))
GUISetState ( @SW_LOCK ) ; empêche de le repeindre


$gui2 = GUICreate("Form2", 738, 506, 548, 270,$WS_POPUP, BitOR($WS_EX_ACCEPTFILES, $WS_EX_LAYERED, $WS_EX_TOPMOST, $WS_CHILD, $WS_EX_COMPOSITED),$gui1)
$List1 = GUICtrlCreateList("", 120, 320, 257, 149)
$ListView1 = GUICtrlCreateListView("", 384, 320, 322, 150)
GUICtrlSetState ( $ListView1, $GUI_DROPACCEPTED )
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_DROPPED
         ConsoleWrite("DropID case =" & @GUI_DropId & @CRLF)
      Case $GUI_EVENT_CLOSE
         Exit
   EndSwitch
WEnd

GeSHi © Extension Codebox Plus

La contrainte dans tout cela c'est que je dois garder au minimum ces styles sur les 2 GUI .
pour la GUI 1 : $GUI_SS_DEFAULT_GUI,$WS_MAXIMIZEBOX,$WS_SIZEBOX
pour la GUI 2 : $WS_POPUP, BitOR($WS_EX_ACCEPTFILES, $WS_EX_LAYERED, $WS_EX_TOPMOST, $WS_CHILD, $WS_EX_COMPOSITED),$gui1)

Est-ce un bug ou une erreur dans mon codage??
pour le coup, je n'ai pas de solution,
avez-vous des pistes ou autres?

Je vous remercie d'avance

[TommyDDR]

Vous vous emmêlez les pinceaux dans les styles et les styles étendus
GUICreate ( "title" [, width [, height [, left = -1 [, top = -1 [, style = -1 [, exStyle = -1 [, parent = 0]]]]]]] )
$WS_ = style
$WS_EX_ = style étendu

Vous ne pouvez donc pas avoir $WS_CHILD dans le paramètre "exStyle".
De plus :
$WS_POPUP 0x80000000 Creates a pop-up window. This style cannot be used with the WS_CHILD style.

$WS_POPUP ne peut être mis en même temps que $WS_CHILD, mais ce n'est pas grave car une WS_CHILD n'aura pas de bordure.

Essayez ce script :

Code: [Tout sélectionner] [Déplier/Replier]

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <file.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <GuiEdit.au3>


#Region
$gui1 = GUICreate("Form1", 738, 506, 548, 270,BitOR($GUI_SS_DEFAULT_GUI,$WS_MAXIMIZEBOX,$WS_SIZEBOX))
GUISetState(@SW_SHOW)


$gui2 = GUICreate("Form2", 738, 506, 0, 0, $WS_CHILD, BitOR($WS_EX_ACCEPTFILES, $WS_EX_LAYERED, $WS_EX_TOPMOST, $WS_EX_COMPOSITED),$gui1)
$List1 = GUICtrlCreateList("", 120, 320, 257, 149)
$ListView1 = GUICtrlCreateListView("", 384, 320, 322, 150)
GUICtrlSetState ( $ListView1, $GUI_DROPACCEPTED )
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_DROPPED
         ConsoleWrite("DropID case =" & @GUI_DropId & @CRLF)
      Case $GUI_EVENT_CLOSE
         Exit
   EndSwitch
WEnd

GeSHi © Extension Codebox Plus

[serpafi]

on en apprend tout les jours, merci beaucoup.
Le drag&drop fonctionne mais la listview ne s'affiche pas complétement , avez-vous le même soucis ?
En rajoutant $WS_POPUP dans le BitoR il s'affiche entièrement mais pas de D&D (logique $WS_CHILD et $WS_popup incompatible)
J'ai vraiment du mal avec la gestion des GUI CHILD
et merci pour l'info des bordures avec WS_CHILD ca va mettre utile.

[TommyDDR]

Si vous enlevez $WS_EX_LAYERED et $WS_EX_COMPOSITED, elle s'affiche bien

$WS_EX_LAYERED Creates a layered window. Note that this cannot be used for child windows.

[serpafi]

Merci TommyDDR pour vos conseils et votre temps.
grâce à vous, j'ai pu mieux comprendre les styles et régler mon problème.
Pas de code pour la résolution à proposer puisque j'ai résolu mon problème en un seul GUI donc hors sujet.
En tout cas merci beaucoup et continuer à aider, vous êtes un don du code.