AutoIt Français

Bonjour,
Suite à ce post du mois dernier
http://www.autoitscript.fr/forum/viewto ... =20&t=9725
où la demande était :
" Je suis à la recherche d'une fonction qui permet de supprimer les ligne blanches d'un array existant avec 1 ou plusieurs colonnes, détection automatique. "
J'avais proposé une solution variante de celle proposée dans ce post du forum US : remove-empty-rows-in-2d-array

Mais depuis, confronté au même problème, j'ai écrit cette petite fonction très simple qui est ~ 8 fois plus rapide ( test fait sur une array[4600][5] ), détecte automatiquement si l'array est 1D ou 2D, et qui est suffisamment souple pour pouvoir être facilement adaptée à d'autres conditions de suppression de lignes dans une array

► Afficher le texte

Ah, pas bête. Je pense que je vais ranger cette fonction quelque part.

Sinon, pour la variable "$fired", ça me fait penser à ça !

Bonsoir mikell.
Perso j'utilisais les fonctions de cet UDF en faisant un _Array2DToString puis un _StringToArray2D avec les bonnes options.

Code : Tout sélectionner

Local $sArray1 = _Array2DToString($aArrayTest, "", "", 1)
Local $aArray1 = _StringToArray2D($sArray1)

Bien que cette solution soit à peine un peut plus lente que la votre (environ 4 secondes d'écart pour un tableau de 100000 X 10 et quelques dixièmes de seconde pour des tableaux plus raisonnables), c'était surtout une solution détournée pour ne pas créer une fonction supplémentaire.

Maintenant, pourquoi ne pas rajouter votre fonction à l'UDF ArrayEx.

Tlem a écrit :Maintenant, pourquoi ne pas rajouter votre fonction à l'UDF ArrayEx.

Que pensez-vous de cette amélioration
(je me suis permis une coloration autoit pour une meilleure lisibilité)

► Afficher le texte

Code : Tout sélectionner

;=====================================
#cs
Paramètres optionnels :
$_string : chaîne à rechercher dans la ligne (plusieurs recherches possibles avec délimiteur)
              si "" , recherche des cellules de tableau vides (défaut)
$str_col : index de la colonne à vérifier (tableau 2D)
               si -1 : vérifie les cellules de  toutes les colonnes (défaut)
$_fullstring : si 0 , vérifie si la chaîne est présente dans la cellule (défaut)
                   si 1 , vérifie si la cellule ne contient exclusivement que la chaîne
$_delim : délimiteur pour les chaînes à rechercher ( | par défaut)

Exemples :
_ArrayDeleteRows($array) : supprime les lignes vides
_ArrayDeleteRows($array, "", 4) : supprime les lignes où la colonne 4 est vide
_ArrayDeleteRows($array, "test", -1) : supprime les lignes où la chaîne "test" existe
_ArrayDeleteRows($array, "test", 4) : supprime les lignes où la chaîne "test" existe dans la colonne 4
_ArrayDeleteRows($array, "test", 4, 1) : supprime les lignes où la colonne 4 ne contient que le mot "test"
_ArrayDeleteRows($array, "|test", 4) : supprime les lignes où la colonne 4 est vide ou contient la chaîne "test"
#ce
;=====================================



; #FUNCTION# =============================================================================
; Name...........: _ArrayDeleteRows
; Description ...: Delete rows in a 1D or 2D array if rows or cells are empty or contain a specific string
; Syntax.........: _ArrayDeleteRows(ByRef $_array[, $_string = ""[, $str_col = -1[, $_fullstring = 0[, $_delim = "|"]]]])
; Parameters ....: $_array - Name of the array to be revised
; Optional........: $_string - String to search for in the row or cell (or separated list of strings with a delimiter, default "|")
;                        $_str_col - Index of the column to check (2D array) 
;                   Case -1 : Check all the cells of the row (default)
;                        $_fullstring - Case 0 : checks if the string exists in the row or cell (default)
;                                             Case 1 : checks if the row or cell contains the string only
;                        $_delim : Separator to be used in a list of strings to search for (default "|")
; Return values .: Success - Returns a 1
;                       Failure - Returns a 0
;                      @Error - 0 = No error.
;                                     1 = Array is not valid or is not a 1D or 2D array
; Author ........: mikell  <autoitscript.fr>
; Examples of use ..........: 
;     _ArrayDeleteRows($array) : delete empty rows
;     _ArrayDeleteRows($array, "", 4) : delete rows whose cell in column 4 is empty
;     _ArrayDeleteRows($array, "test", -1) : delete rows where the string "test" exists
;     _ArrayDeleteRows($array, "test", 4) : delete rows if the string "test" exists in the cell in column 4
;     _ArrayDeleteRows($array, "test", 4, 1) : delete rows whose cell in column 4 contains the string "test" only
;     _ArrayDeleteRows($array, "|test", 4) : delete rows whose cell in column 4 contains the string "test" or is empty
; ========================================================================================

Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")
    Local $dims = UBound($_array, 0), $fired = 0
    If Not IsArray($_array) Or $dims > 2 Then Return SetError(1, 0, 0)
    Switch $dims

        Case 1 ; array 1D
            Local $temp[UBound($_array)]
            For $i = 0 To UBound($_array) - 1
                $row = $_array[$i]
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                $temp[$i - $fired] = $_array[$i]
            Next
            ReDim $temp[UBound($_array) - $fired]

        Case 2 ; array 2D
            Local $cols = UBound($_array, 2), $row = ""
            If $_str_col < -1 Or $_str_col > $cols - 1 Then $_str_col = -1
            Local $temp[UBound($_array)][$cols]

            For $i = 0 To UBound($_array) - 1
                If $_str_col = -1 Then
                    For $j = 0 To $cols - 1
                        $row &= $_array[$i][$j] ; concatène la ligne
                    Next
                Else
                    $row = $_array[$i][$_str_col] ; colonne
                EndIf
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne ou la cellule
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                For $j = 0 To $cols - 1
                    $temp[$i - $fired][$j] = $_array[$i][$j]
                Next
                $row = ""
            Next
            ReDim $temp[UBound($_array) - $fired][$cols]
    EndSwitch
    $_array = $temp
    $temp = ""
    Return 1
EndFunc   ;==>_ArrayDeleteRows

; INTERNAL USE ONLY ===============
Func _TestRow($_text, $s_string, $t_fullstring, $t_delim)
    $ts_string = StringSplit($s_string, $t_delim)
    For $i = 1 To $ts_string[0]
        If $ts_string[$i] = "" Then
            If StringRegExpReplace($_text, '\s', "") = "" Then Return 1
        Else
            If $t_fullstring = 1 Then
                If StringStripWS($_text, 3) = $ts_string[$i] Then Return 1
            Else
                If StringInStr($_text, $ts_string[$i]) Then Return 1
            EndIf
        EndIf
    Next
EndFunc   ;==>_TestRow

Pas mal.
Manque juste une bonne identation et une entête un peut plus standard.
Et un truc qui me tarabuste, c'est pourquoi $str_col est la seule variable à ne pas bénéficier du tirait vers le bas en début de variable ?

Tlem a écrit :Et un truc qui me tarabuste, c'est pourquoi $str_col est la seule variable à ne pas bénéficier du tirait vers le bas en début de variable ?

Qu'est-ce que j'en sais... peut-être parce que ce tiret existe déjà dans la variable ? ou qu'à un moment chaud, je me suis dit "salope de variable, tu me fais des soucis, pisque c'est comme ça pas de tiret, na "
Argh

Le boss et son univers impitoyable

Je corrigerai donc cet indécent nom de variable... elle va pas l'indentation ?
Au fait vous l'avez testé ce code ?
Et l'en-tête il le faut en angliche je parie

En ce moment, mes activités privées me demande énormément de temps, donc je ne peut être présent et actif comme je le souhaiterais.
Je testerais la fonction un peut plus tard, mais je ne doute aucunement de vos capacités.

Voilà, j'ai mis aux normes et édité dans le post précédent

Tu peux en disposer à ton aise (enfin bon, peut-être un petit crash-test d'abord, ça serait pas mal...)

mikell a écrit :Tu peux en disposer à ton aise

Voilà qui est fait. J'ai amélioré, renommé et ajouté la fonction dans l'UDF ArrayEx.au3.

J'ai passé un bon moment pour le crash test et il me semble que c'est bon (ceci dit, plusieurs avis serait appréciable).
Je te laisse jeter un œil dés que tu le pourra.

Hum ... "amélioré" ça se discute
Tu as supprimé la possibilité de faire une recherche sélective par colonne dans une array 2D, et tu imposes le point-virgule comme délimiteur alors que je préférais laisser le choix (avec le "|" par défaut qui est conventionnel)
Un détail : "Tlem adding conventional shaping of the function" ça d'accord, mais pour le reste tu exagères

mikell a écrit :Hum ... "amélioré" ça se discute

Tout est discutable.

mikell a écrit :Tu as supprimé la possibilité de faire une recherche sélective par colonne dans une array 2D

Ben, j'en voyais pas l'utilité puisque le but primaire était la suppression de lignes vides amélioré en ligne contenant une ou plusieurs valeurs ...

mikell a écrit :tu imposes le point-virgule comme délimiteur alors que je préférais laisser le choix (avec le "|" par défaut qui est conventionnel)

Beaucoup d'UDFs utilisent le point virgule pour des patterns à valeurs multiples. Il n'y à rien d'exceptionnel ici !

mikell a écrit :Un détail : "Tlem adding conventional shaping of the function" ça d'accord, mais pour le reste tu exagères

Ha ! Je ne m'attribue pas grand chose pourtant, malgré la grosse différence entre les deux fonctions. ^^

La grosse différence entre les deux fonctions tient essentiellement dans les suppressions d'options ^^
Y avait eu une évolution depuis le but primaire, comme l'indiquent les exemples de mon en-tête
Par exemple, si on veut supprimer seulement les lignes où la string à rechercher figure uniquement dans une seule colonne en particulier
Idem, dans la plupart des fctns du fichier d'aide le "| " est utilisé comme délimiteur par défaut, et il existe un Opt("GUIDataSeparatorChar") pour que l'utilisateur puisse en changer, c'est cette possibilité de choix qu'offrait la fctn initiale

Et donc, quelles sont tes revendications ?

Comme tu avais dit

Tlem a écrit :Je te laisse jeter un œil dés que tu le pourra.

j'ai jeté un oeil alors voilà

Simplement je ne reconnais plus la fonction de mon post #2, le nom a changé, les options que j'y avais introduites pour donner un max de souplesse et de polyvalence ont disparu, il n'en reste que l'idée
Telle qu'elle figure maintenant dans l'UDF, cette fctn édulcorée ne me satisfait (personnellement...) pas mais comme j'ai dit

mikell a écrit :Tu peux en disposer à ton aise

je ne m'autorise donc aucune revendication

Bonsoir Michel,
J'ai été "un peut contrarié" sur tes remarques et donc parce que c'est toi, j'ai fait l'effort de rajouter cette fameuse option de recherche par colonne (sans passer par une fonction interne) bien qu'actuellement je n'en vois pas l'utilité. Mais qui peut le plus, peut le moins et comme cela ne rajoute pas une trop grosse complexité de compréhension, pourquoi s'en passer après tout.

En ce qui concerne le séparateur, après moultes recherches, je n'ai trouvé aucune référence sur le fait que le "|" soit conventionnel. Il l'est sur des valeurs de sortie, mais pas sur des paramètres d'entrée à valeurs multiples.
En fouillant les includes, on retrouve bien des points virgule et des virgules, mais je n'ai pas trouvé de fonction avec des paramètres multiples en entrée qui utilise le "|" comme séparateur (mais bon, j'ai peut être mal cherché).

Je te met ci-dessous la fonction modifiée et attend tes commentaires avant de la mettre à jour dans l'UDF.

► Afficher le texte

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _ArrayDeleteLines
; Description ...: Delete line(s) that contain specified string on 1D or 2D arrays
; Syntax.........: _ArrayDeletelines(ByRef $avArray[, $sString = ""[, $iFlag = 1]])
; Parameters ....: $avArray             - Array to proceed (1D or 2D)
;                  $sString             - [optional] Deletion delimiter string(s) (blanc value by default for empty line)
;                                                    Can be multiple value separated by semicolon ("Value1;Value2; ...")
;                  $iFlag               - [optional] 0 Search string(s) in rows values(Default).
;                                                    1 Compare string(s) to rows values(exact match).
;                  $iRow                - [optional] -1 (Default) If > -1, search only in specified row.
;
; Return values .: Success - Return array without line(s) that contain the specified value(s)
;                  Failure - 0, sets @error:
;                  |1 - $avArray is not an array
;                  |2 - $avArray has too many dimensions (only up to 2D supported)
;
; Author ........: mikell (original function name was _ArrayDeleteEmptyRows)
; Modified.......: Tlem (tlem@tuxolem.fr) adding specified delimiter, multiple delimiters, total elements update,
;                  conventional shaping of the function
; Remarks .......: By default _ArrayDeleteLines($avArray) delete empty line (first idea)
; Related .......:
; Link ..........: Original function here : http://www.autoitscript.fr/forum/viewtopic.php?f=21&p=67660#p67660
; Example .......: Yes
; ===============================================================================================================================
Func _ArrayDeleteLines(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    If $iFlag <> 1 Then $iFlag = 0
    If $iRow > -1 Then
        $iRow = $iRow
    Else
        $iRow = -1
    EndIf
    Local $aString = StringSplit($sString, ";")
    Local $fired = 0, $iFlagRow = $iRow

    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1)
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    Switch $iDimension
        Case 1 ; 1D array
            Local $aArrayTmp[UBound($avArray)]
            For $k = 1 To $aString[0] ; String to search
                For $i = 0 To UBound($avArray) - 1
                    Switch $iFlag
                        Case 0 ; Line contain value
                            If StringInStr($avArray[$i], $aString[$k]) Then ; If line value contain $sString value
                                $fired += 1
                                ContinueLoop 2; Nextline (loop $i)
                            EndIf

                        Case 1 ; Exact match
                            If $avArray[$i] = $aString[$k] Then ; If line value is equal to $sString value
                                $fired += 1
                                ContinueLoop 2 ; next line (loop $i)
                            EndIf
                    EndSwitch
                Next
                $aArrayTmp[$i - $fired] = $avArray[$i]
            Next
            ReDim $aArrayTmp[UBound($avArray) - $fired]

        Case 2 ; 2D array
            Local $cols = UBound($avArray, 2)
            Local $aArrayTmp[UBound($avArray)][$cols]
            For $k = 1 To $aString[0] ; String to search
                For $i = 0 To UBound($avArray) - 1
                    Switch $iFlag
                        Case 0 ; Search value(s) in each row
                            For $j = 0 To $cols - 1
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If StringInStr($avArray[$i][$j], $aString[$k]) And $iFlagRow = $j Then ; If row values contain $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; Nextline (loop $i)
                                EndIf
                            Next

                            For $j = 0 To $cols - 1
                                $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                            Next

                        Case 1 ; Search exact match value(s) in each row
                            For $j = 0 To $cols - 1
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If $avArray[$i][$j] = $aString[$k] And $iFlagRow = $j Then ; If row values is equal to $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; next line (loop $i)
                                EndIf
                            Next

                            For $j = 0 To $cols - 1
                                $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                            Next
                    EndSwitch
                Next
            Next
            ReDim $aArrayTmp[$iUBound - $fired][$cols]
    EndSwitch

    ; Check and update elements number
    If $iDimension > 1 Then
        If $aArrayTmp[0][0] = $iUBound Then
            $aArrayTmp[0][0] = UBound($aArrayTmp, 1) - 1
        EndIf
    Else
        If $aArrayTmp[0] = $iUBound Then
            $aArrayTmp[0] = UBound($aArrayTmp, 1) - 1
        EndIf
    EndIf

    $avArray = $aArrayTmp
EndFunc   ;==>_ArrayDeleteLines

Je n'ai pas encore eu le temps de bien regarder le code et te répondrai donc plus tard mais en attendant

Tlem a écrit :j'ai fait l'effort de rajouter cette fameuse option de recherche par colonne (sans passer par une fonction interne) bien qu'actuellement je n'en vois pas l'utilité

C'est dommage que tu n'en voies pas l'utilité, parce que bien tenir compte de chaque cellule de chaque colonne t'aurait permis d'éviter que ta fonction _Array2DToHtml soit buggée
Teste _Array2DToHtml en laissant dans l'array une cellule vide ($array[0][2] par exemple) et regarde le résultat : la cellule vide est zappée et les autres cellules de la ligne sont décalées (elles changent de colonne) j'ai eu la blague ce we avec une array de compta où la 1ère cellule (date) reste vide si la date ne change pas par rapport à la ligne précédente, et je te dis pas le fourbi à la sortie

Edit
Je me suis arrêté au tout 1er test (_ArrayDeleteLines($array) : tous les params par défaut) qui n'est pas concluant
Edit 2
J'aurais dû tester l'ancienne version aussi d'ailleurs ^^

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>

Dim $aTmp[5][8] = [[0, 1, 2, 3, 1, 1, 2, 3], [2, 3, 4, 5, 6, 7, 8, 9], [" ", ""], ["", ""], [4, 5, 7, 8, 9, 6 , 5, 4]]
$aTmp1 = $aTmp
$aTmp2 = $aTmp
$aTmp3 = $aTmp

_ArrayDisplay($aTmp, "$aTmp_BEFORE")

_ArrayDeleteLines($aTmp1)
_ArrayDisplay($aTmp1, "Tlem_new")    ; nouvelle fonction

_ArrayDeleteLinesOld($aTmp2)
_ArrayDisplay($aTmp2, "Tlem_old")     ; ancienne fonction (prise dans ArrayEx.au3)

_ArrayDeleteRows($aTmp3)
_ArrayDisplay($aTmp3, "mikell")    ; fonction originale


;==========================================================

Func _ArrayDeleteLines(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    If $iFlag <> 1 Then $iFlag = 0
    If $iRow > -1 Then
        $iRow = $iRow
    Else
        $iRow = -1
    EndIf
    Local $aString = StringSplit($sString, ";")
    Local $fired = 0, $iFlagRow = $iRow

    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1)
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    Switch $iDimension
        Case 1 ; 1D array
            Local $aArrayTmp[UBound($avArray)]
            For $k = 1 To $aString[0] ; String to search
                For $i = 0 To UBound($avArray) - 1
                    Switch $iFlag
                        Case 0 ; Line contain value
                            If StringInStr($avArray[$i], $aString[$k]) Then ; If line value contain $sString value
                                $fired += 1
                                ContinueLoop 2; Nextline (loop $i)
                            EndIf

                        Case 1 ; Exact match
                            If $avArray[$i] = $aString[$k] Then ; If line value is equal to $sString value
                                $fired += 1
                                ContinueLoop 2 ; next line (loop $i)
                            EndIf
                    EndSwitch
                Next
                $aArrayTmp[$i - $fired] = $avArray[$i]
            Next
            ReDim $aArrayTmp[UBound($avArray) - $fired]

        Case 2 ; 2D array
            Local $cols = UBound($avArray, 2)
            Local $aArrayTmp[UBound($avArray)][$cols]
            For $k = 1 To $aString[0] ; String to search
                For $i = 0 To UBound($avArray) - 1
                    Switch $iFlag
                        Case 0 ; Search value(s) in each row
                            For $j = 0 To $cols - 1
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If StringInStr($avArray[$i][$j], $aString[$k]) And $iFlagRow = $j Then ; If row values contain $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; Nextline (loop $i)
                                EndIf
                            Next

                            For $j = 0 To $cols - 1
                                $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                            Next

                        Case 1 ; Search exact match value(s) in each row
                            For $j = 0 To $cols - 1
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If $avArray[$i][$j] = $aString[$k] And $iFlagRow = $j Then ; If row values is equal to $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; next line (loop $i)
                                EndIf
                            Next

                            For $j = 0 To $cols - 1
                                $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                            Next
                    EndSwitch
                Next
            Next
            ReDim $aArrayTmp[$iUBound - $fired][$cols]
    EndSwitch

    ; Check and update elements number
    If $iDimension > 1 Then
        If $aArrayTmp[0][0] = $iUBound Then
            $aArrayTmp[0][0] = UBound($aArrayTmp, 1) - 1
        EndIf
    Else
        If $aArrayTmp[0] = $iUBound Then
            $aArrayTmp[0] = UBound($aArrayTmp, 1) - 1
        EndIf
    EndIf

    $avArray = $aArrayTmp
EndFunc   ;==>_ArrayDeleteLines

;==========================================================

Func _ArrayDeleteLinesOld(ByRef $avArray, $sString = "", $iFlag = 1)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    If $iFlag <> 1 Then $iFlag = 0
    Local $aString = StringSplit($sString, ";")
    Local $fired = 0

    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1) - 1
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    Switch $iDimension
        Case 1 ; 1D array
            Local $aArrayTmp[UBound($avArray)]
            For $i = 0 To UBound($avArray) - 1
                For $k = 1 To $aString[0]
                    Switch $iFlag
                        Case 0 ; Line contain value
                            If StringInStr($avArray[$i], $aString[$k]) Then ; If line value contain $sString value
                                $fired += 1
                                ContinueLoop 2; Nextline (loop $i)
                            EndIf

                        Case 1 ; Exact match
                            If $avArray[$i] = $aString[$k] Then ; If line value is equal to $sString value
                                $fired += 1
                                ContinueLoop 2 ; next line (loop $i)
                            EndIf
                    EndSwitch
                Next
                $aArrayTmp[$i - $fired] = $avArray[$i]
            Next
            ReDim $aArrayTmp[UBound($avArray) - $fired]

        Case 2 ; 2D array
            Local $cols = UBound($avArray, 2), $row = ""
            Local $aArrayTmp[UBound($avArray)][$cols]
            For $i = 0 To UBound($avArray) - 1
                For $k = 1 To $aString[0]
                    $row = ""
                    For $j = 0 To $cols - 1
                        $row &= $avArray[$i][$j] ; Merge line values
                    Next

                    If $iFlag = 0 Then ; Line contain value
                        If StringInStr($row, $aString[$k]) Then ; If row values contain $sString value
                            $fired += 1
                            ContinueLoop 2 ; Nextline (loop $i)
                        EndIf
                    Else ; Exact match
                        If $row = $aString[$k] Then ; If row values is equal to $sString value
                            $fired += 1
                            ContinueLoop 2 ; next line (loop $i)
                        EndIf
                    EndIf

                    For $j = 0 To $cols - 1
                        $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                    Next
                Next
            Next
            ReDim $aArrayTmp[$iUBound - $fired][$cols]
    EndSwitch

    ; Check and update elements number
    If $iDimension > 1 Then
        If $aArrayTmp[0][0] = $iUBound Then
            $aArrayTmp[0][0] = UBound($aArrayTmp, 1) - 1
        EndIf
    Else
        If $aArrayTmp[0] = $iUBound Then
            $aArrayTmp[0] = UBound($aArrayTmp, 1) - 1
        EndIf
    EndIf

    $avArray = $aArrayTmp
EndFunc   ;==>_ArrayDeleteLines



;===========================================================

Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")
    Local $dims = UBound($_array, 0), $fired = 0
    If Not IsArray($_array) Or $dims > 2 Then Return SetError(1, 0, 0)
    Switch $dims

        Case 1 ; array 1D
            Local $temp[UBound($_array)]
            For $i = 0 To UBound($_array) - 1
                $row = $_array[$i]
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                $temp[$i - $fired] = $_array[$i]
            Next
            ReDim $temp[UBound($_array) - $fired]

        Case 2 ; array 2D
            Local $cols = UBound($_array, 2), $row = ""
            If $_str_col < -1 Or $_str_col > $cols - 1 Then $_str_col = -1
            Local $temp[UBound($_array)][$cols]

            For $i = 0 To UBound($_array) - 1
                If $_str_col = -1 Then
                    For $j = 0 To $cols - 1
                        $row &= $_array[$i][$j] ; concatène la ligne
                    Next
                Else
                    $row = $_array[$i][$_str_col] ; colonne
                EndIf
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne ou la cellule
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                For $j = 0 To $cols - 1
                    $temp[$i - $fired][$j] = $_array[$i][$j]
                Next
                $row = ""
            Next
            ReDim $temp[UBound($_array) - $fired][$cols]
    EndSwitch
    $_array = $temp
    $temp = ""
    Return 1
EndFunc   ;==>_ArrayDeleteRows

; INTERNAL USE ONLY ===============
Func _TestRow($_text, $s_string, $t_fullstring, $t_delim)
    $ts_string = StringSplit($s_string, $t_delim)
    For $i = 1 To $ts_string[0]
        If $ts_string[$i] = "" Then
            If StringRegExpReplace($_text, '\s', "") = "" Then Return 1
        Else
            If $t_fullstring = 1 Then
                If StringRegExpReplace($_text, '^\s*|\s*$', "") = $ts_string[$i] Then Return 1
            Else
                If StringRegExp($_text, $ts_string[$i]) Then Return 1
            EndIf
        EndIf
    Next
EndFunc   ;==>_TestRow

Effectivement, je m'était tellement concentré sur la recherche par colonne, que j'en avait oublié la fonction première (supprimer les lignes vides !).

J'ai donc rectifier le tir en modifiant légèrement le code et en effectuant plusieurs tests divers (sans doute pas assez, mais pas mal quand même). Lors de ces tests, je me suis rendu compte que ta fonction plantait dans certains cas et ne renvoyait pas le même nombre d'éléments que ma fonction (ou alors j'ai l'ai mal paramétré

). Ce qui m'a permit de déceler un problème potentiel dans ma fonction aussi puisqu'elle est basée sur le même principe.

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>

Dim $aArray1[501][51]
Dim $Resultat[5][3] = [["Traitement", "_ArrayDeleteLines", "_ArrayDeleteRows"],["Sans ligne vide"], ["Sans 2 Col 0"], ["sans ligne avec le 25"], ["Sans ligne avec le 5"]]
For $i = 0 To 500
    Local $Rnd = Random(1, 10, 1)
    For $j = 0 To 50
        If $Rnd <> 5 Then
            $aArray1[$i][$j] = Random(1, 100, 1)
        Else
            $aArray1[$i][$j] = ""
        EndIf
    Next
Next
$aArray2 = $aArray1
;_ArrayDisplay($aArray1, "Tableau à traiter :")

;Func _ArrayDeleteLines2(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)
_ArrayDeleteLines($aArray1)
$Resultat[1][1] = UBound($aArray1) - 1
;_ArrayDisplay($aArray1, "$aArray1 sans ligne vide")
_ArrayDeleteLines($aArray1, "2", 0, 0)
$Resultat[2][1] = UBound($aArray1) - 1
;_ArrayDisplay($aArray1, "$aArray1 sans 2 en colonne 0")
_ArrayDeleteLines($aArray1, "25")
$Resultat[3][1] = UBound($aArray1) - 1
;_ArrayDisplay($aArray1, "$aArray1 sans ligne avec le nombre 25")
_ArrayDeleteLines($aArray1, "5")
$Resultat[4][1] = UBound($aArray1) - 1
;_ArrayDisplay($aArray1, "$aArray1 sans ligne avec le nombre 5")


; Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")
_ArrayDeleteRows($aArray2)
$Resultat[1][2] = UBound($aArray2) - 1
;_ArrayDisplay($aArray2, "$aArray2 sans ligne vide")
_ArrayDeleteRows($aArray2, "2", 0)
$Resultat[2][2] = UBound($aArray2) - 1
;_ArrayDisplay($aArray2, "$aArray2 sans 2 colonne 0")
_ArrayDeleteRows($aArray2, "25")
$Resultat[3][2] = UBound($aArray2) - 1
;_ArrayDisplay($aArray2, "$aArray2 sans ligne avec le nombre 25")
_ArrayDeleteRows($aArray2, "5")
$Resultat[4][2] = UBound($aArray2) - 1
;_ArrayDisplay($aArray2, "$aArray2 sans ligne avec le nombre 5")

_ArrayDisplay($Resultat, "Elements retournés")

;==========================================================

Func _ArrayDeleteLines(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    If $iFlag <> 1 Then $iFlag = 0
    If $iRow > -1 Then
        $iRow = $iRow
    Else
        $iRow = -1
    EndIf
    Local $aString = StringSplit($sString, ";")
    Local $fired = 0, $iFlagRow = $iRow, $iLine

    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1)
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    Switch $iDimension
        Case 1 ; 1D array
            Local $aArrayTmp[UBound($avArray)]
            For $k = 1 To $aString[0] ; String to search
                For $i = 0 To UBound($avArray) - 1
                    Switch $iFlag
                        Case 0 ; Line contain value
                            If StringInStr($avArray[$i], $aString[$k]) Then ; If line value contain $sString value
                                $fired += 1
                                ContinueLoop 2; Nextline (loop $i)
                            EndIf

                        Case 1 ; Exact match
                            If $avArray[$i] = $aString[$k] Then ; If line value is equal to $sString value
                                $fired += 1
                                ContinueLoop 2 ; next line (loop $i)
                            EndIf
                    EndSwitch
                Next
                $aArrayTmp[$i - $fired] = $avArray[$i]
            Next
            ; In case of all lines deleted
            If UBound($avArray) - $fired < 1 Then
                ReDim $aArrayTmp[1]
            Else
                ReDim $aArrayTmp[UBound($avArray) - $fired]
            EndIf

        Case 2 ; 2D array
            Local $cols = UBound($avArray, 2)
            Local $aArrayTmp[UBound($avArray)][$cols]
            For $k = 1 To $aString[0] ; String to search
                If StringLen($aString[$k]) = 0 And $iRow = -1 Then $iFlag = -1 ; Blank line
                For $i = 0 To UBound($avArray) - 1 ; Count lines
                    Switch $iFlag
                        Case -1 ; Delete blank line
                            $iLine = ""
                            For $j = 0 To $cols - 1 ; Count rows
                                $iLine &= $avArray[$i][$j] ; Concatenate all rows and strip all spaces.
                            Next
                            If StringLen(StringStripWS($iLine, 8)) = 0 Then ; If line is blank line
                                $fired += 1
                                ContinueLoop 1 ; Nextline (loop $i)
                            EndIf

                        Case 0 ; Search value(s) in each row
                            For $j = 0 To $cols - 1 ;  Count rows
                                $iLine &= StringStripWS($avArray[$i][$j], 1)
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If StringInStr($avArray[$i][$j], $aString[$k]) And $iFlagRow = $j Then ; If row values contain $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; Nextline (loop $i)
                                EndIf
                            Next

                        Case 1 ; Search exact match value(s) in each row
                            For $j = 0 To $cols - 1 ;  Count  rows
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If $avArray[$i][$j] = $aString[$k] And $iFlagRow = $j Then ; If row values is equal to $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; next line (loop $i)
                                EndIf
                            Next

                     EndSwitch
                    For $j = 0 To $cols - 1
                        $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                    Next
                Next
            Next
            ; In case of all lines deleted
            If $iUBound - $fired < 1 Then
                ReDim $aArrayTmp[1][1]
            Else
                ReDim $aArrayTmp[$iUBound - $fired][$cols]
            EndIf
    EndSwitch

    ; Check and update elements number
    If $iDimension > 1 Then
        If $aArrayTmp[0][0] = $iUBound Then
            $aArrayTmp[0][0] = UBound($aArrayTmp, 1) - 1
        EndIf
    Else
        If $aArrayTmp[0] = $iUBound Then
            $aArrayTmp[0] = UBound($aArrayTmp, 1) - 1
        EndIf
    EndIf

    $avArray = $aArrayTmp
EndFunc   ;==>_ArrayDeleteLines


;===========================================================

Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")
    Local $dims = UBound($_array, 0), $fired = 0
    If Not IsArray($_array) Or $dims > 2 Then Return SetError(1, 0, 0)
    Switch $dims

        Case 1 ; array 1D
            Local $temp[UBound($_array)]
            For $i = 0 To UBound($_array) - 1
                $row = $_array[$i]
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                $temp[$i - $fired] = $_array[$i]
            Next
            If UBound($_array) - $fired < 1 Then
                ReDim $temp[1]
            Else
                ReDim $temp[UBound($_array) - $fired]
            EndIf

        Case 2 ; array 2D
            Local $cols = UBound($_array, 2), $row = ""
            If $_str_col < -1 Or $_str_col > $cols - 1 Then $_str_col = -1
            Local $temp[UBound($_array)][$cols]

            For $i = 0 To UBound($_array) - 1
                If $_str_col = -1 Then
                    For $j = 0 To $cols - 1
                        $row &= $_array[$i][$j] ; concatène la ligne
                    Next
                Else
                    $row = $_array[$i][$_str_col] ; colonne
                EndIf
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne ou la cellule
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                For $j = 0 To $cols - 1
                    $temp[$i - $fired][$j] = $_array[$i][$j]
                Next
                $row = ""
            Next
            If UBound($_array) - $fired < 1 Then
                ReDim $temp[1][$cols]
            Else
                ReDim $temp[UBound($_array) - $fired][$cols]
            EndIf
    EndSwitch
    $_array = $temp
    $temp = ""
    Return 1
EndFunc   ;==>_ArrayDeleteRows

; INTERNAL USE ONLY ===============
Func _TestRow($_text, $s_string, $t_fullstring, $t_delim)
    $ts_string = StringSplit($s_string, $t_delim)
    For $i = 1 To $ts_string[0]
        If $ts_string[$i] = "" Then
            If StringRegExpReplace($_text, '\s', "") = "" Then Return 1
        Else
            If $t_fullstring = 1 Then
                If StringRegExpReplace($_text, '^\s*|\s*$', "") = $ts_string[$i] Then Return 1
            Else
                If StringRegExp($_text, $ts_string[$i]) Then Return 1
            EndIf
        EndIf
    Next
EndFunc   ;==>_TestRow

Malgré la même modification que sur ma fonction pour le retour de tableau vide, cela n'a pas changé que les résultats n'étaient pas identiques (en dehors des lignes vide qui eux fonctionnent très bien sur les deux fonctions (maintenant

)).

Hé oui, la moralité c'est que personne n'est infaillible

J'avais en effet moi aussi une bonne grosse erreur de code

Ta fonction, si tu rajoutais juste la possibilité de choisir le séparateur, elle serait nickel
Manque juste un peu d'optimisation (la mienne aussi d'ailleurs) et bien sûr les crash-tests d'usage que je n'ai pas encore faits
Heu note quand même que la mienne est un poil plus rapide (~ 60 ms)

► Afficher le textegros gros test

Code : Tout sélectionner

#include <Array.au3>

Dim $aArray1[501][51]
Dim $Resultat[11][3] = [["Traitement", "_ArrayDeleteLines", "_ArrayDeleteRows"], _ 
                ["Sans ligne vide"], _ 
                ["Sans cellule vide Col 3"], _ 
                ["Sans 2 dans Col 45"], _ 
                ["sans ligne avec 25"], _ 
                ["sans ligne avec 25 ou vide"], _ 
                ["Sans ligne avec 25 ou 17"], _ 
                ["Sans ligne avec 5 (simple)"], _  
                ["Sans ligne avec 5 (fullstring)"], _ 
                [""], _ 
                ["Timer"]]
For $i = 0 To 500
    Local $Rnd = Random(1, 10, 1)
    For $j = 0 To 50
        If $Rnd <> 5 Then
            $aArray1[$i][$j] = Random(1, 100, 1) 
        Else
            $aArray1[$i][$j] = ""
        EndIf
    Next
Next
$aArray1[3][3] = ""      ; on vide la case 3x3 pour le test
$aArray2 = $aArray1
;_ArrayDisplay($aArray1, "Tableau à traiter :")
;==========================================

$begin1 = Timerinit()
;Func _ArrayDeleteLines(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)

_ArrayDeleteLines($aArray1)
$Resultat[1][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteLines($aArray1, "", 0, 3)
$Resultat[2][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteLines($aArray1, "2", 0, 45)
$Resultat[3][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteLines($aArray1, "25")
$Resultat[4][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
;_ArrayDeleteLines($aArray1, ";25")
$Resultat[5][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
;_ArrayDeleteLines($aArray1, "25;17")
$Resultat[6][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteLines($aArray1, "5")
$Resultat[7][1] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteLines($aArray1, "5", 1)
$Resultat[8][1] = UBound($aArray1) - 1


$Resultat[10][1] = Round(TimerDiff($begin1), 4)
;==============================================
$begin2 = Timerinit()

; Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1)
$Resultat[1][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "", 3)
$Resultat[2][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "2", 45)
$Resultat[3][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "25")
$Resultat[4][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "|25")
$Resultat[5][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "25|17")
$Resultat[6][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "5")
$Resultat[7][2] = UBound($aArray1) - 1

$aArray1 = $aArray2
_ArrayDeleteRows($aArray1, "5", -1, 1)
$Resultat[8][2] = UBound($aArray1) - 1


$Resultat[10][2] = Round(TimerDiff($begin2), 4)
_ArrayDisplay($Resultat, "Elements retournés")

;==========================================================

Func _ArrayDeleteLines(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    If $iFlag <> 1 Then $iFlag = 0
    If $iRow > -1 Then
        $iRow = $iRow
    Else
        $iRow = -1
    EndIf
    Local $aString = StringSplit($sString, ";")
    Local $fired = 0, $iFlagRow = $iRow, $iLine

    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1)
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    Switch $iDimension
        Case 1 ; 1D array
            Local $aArrayTmp[UBound($avArray)]
            For $k = 1 To $aString[0] ; String to search
                For $i = 0 To UBound($avArray) - 1
                    Switch $iFlag
                        Case 0 ; Line contain value
                            If StringInStr($avArray[$i], $aString[$k]) Then ; If line value contain $sString value
                                $fired += 1
                                ContinueLoop 2; Nextline (loop $i)
                            EndIf

                        Case 1 ; Exact match
                            If $avArray[$i] = $aString[$k] Then ; If line value is equal to $sString value
                                $fired += 1
                                ContinueLoop 2 ; next line (loop $i)
                            EndIf
                    EndSwitch
                Next
                $aArrayTmp[$i - $fired] = $avArray[$i]
            Next
            ; In case of all lines deleted
            If UBound($avArray) - $fired < 1 Then
                ReDim $aArrayTmp[1]
            Else
                ReDim $aArrayTmp[UBound($avArray) - $fired]
            EndIf

        Case 2 ; 2D array
            Local $cols = UBound($avArray, 2)
            Local $aArrayTmp[UBound($avArray)][$cols]
            For $k = 1 To $aString[0] ; String to search
                If StringLen($aString[$k]) = 0 And $iRow = -1 Then $iFlag = -1 ; Blank line
                For $i = 0 To UBound($avArray) - 1 ; Count lines
                    Switch $iFlag
                        Case -1 ; Delete blank line
                            $iLine = ""
                            For $j = 0 To $cols - 1 ; Count rows
                                $iLine &= $avArray[$i][$j] ; Concatenate all rows and strip all spaces.
                            Next
                            If StringLen(StringStripWS($iLine, 8)) = 0 Then ; If line is blank line
                                $fired += 1
                                ContinueLoop 1 ; Nextline (loop $i)
                            EndIf

                        Case 0 ; Search value(s) in each row
                            For $j = 0 To $cols - 1 ;  Count rows
                                $iLine &= StringStripWS($avArray[$i][$j], 1)
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If StringInStr($avArray[$i][$j], $aString[$k]) And $iFlagRow = $j Then ; If row values contain $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; Nextline (loop $i)
                                EndIf
                            Next

                        Case 1 ; Search exact match value(s) in each row
                            For $j = 0 To $cols - 1 ;  Count  rows
                                If $iRow = -1 Then $iFlagRow = $j ; For specified row
                                If $avArray[$i][$j] = $aString[$k] And $iFlagRow = $j Then ; If row values is equal to $sString value
                                    $fired += 1
                                    ContinueLoop 2 ; next line (loop $i)
                                EndIf
                            Next

                     EndSwitch
                    For $j = 0 To $cols - 1
                        $aArrayTmp[$i - $fired][$j] = $avArray[$i][$j]
                    Next
                Next
            Next
            ; In case of all lines deleted
            If $iUBound - $fired < 1 Then
                ReDim $aArrayTmp[1][1]
            Else
                ReDim $aArrayTmp[$iUBound - $fired][$cols]
            EndIf
    EndSwitch

    ; Check and update elements number
    If $iDimension > 1 Then
        If $aArrayTmp[0][0] = $iUBound Then
            $aArrayTmp[0][0] = UBound($aArrayTmp, 1) - 1
        EndIf
    Else
        If $aArrayTmp[0] = $iUBound Then
            $aArrayTmp[0] = UBound($aArrayTmp, 1) - 1
        EndIf
    EndIf

    $avArray = $aArrayTmp
EndFunc   ;==>_ArrayDeleteLines


;===========================================================

Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")
    Local $dims = UBound($_array, 0), $fired = 0
    If Not IsArray($_array) Or $dims > 2 Then Return SetError(1, 0, 0)
   Switch $dims

        Case 1 ; array 1D
            Local $temp[UBound($_array)]
            For $i = 0 To UBound($_array) - 1
                $row = $_array[$i]
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                $temp[$i - $fired] = $_array[$i]
            Next
            If UBound($_array) - $fired < 1 Then
                ReDim $temp[1]
            Else
                ReDim $temp[UBound($_array) - $fired]
            EndIf

        Case 2 ; array 2D
            Local $cols = UBound($_array, 2), $row = ""
            If $_str_col < -1 Or $_str_col > $cols - 1 Then $_str_col = -1
            Local $temp[UBound($_array)][$cols]

            For $i = 0 To UBound($_array) - 1    ; parcourt les lignes
                $row = ""
                If $_str_col = -1 Then
                    For $j = 0 To $cols - 1
                        $row &= "|" & $_array[$i][$j] & "|" ; concatène la ligne avec des séparateurs
                    Next
               Else
                    $row = "|" & $_array[$i][$_str_col] & "|"  ; cellule de colonne
                EndIf

                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne ou la cellule
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                For $j = 0 To $cols - 1
                    $temp[$i - $fired][$j] = $_array[$i][$j]
                Next

            Next
            If UBound($_array) - $fired < 1 Then
                ReDim $temp[1][$cols]
            Else
                ReDim $temp[UBound($_array) - $fired][$cols]
            EndIf
    EndSwitch
    $_array = $temp
    $temp = ""
    Return 1
EndFunc   ;==>_ArrayDeleteRows

; INTERNAL USE ONLY ===============
Func _TestRow($_text, $s_string, $t_fullstring, $t_delim)
 $ts_string = StringSplit($s_string, $t_delim)
    For $i = 1 To $ts_string[0]
        If $ts_string[$i] = "" Then
            If StringRegExpReplace($_text, '\||\s', "") = "" Then Return 1
        Else   
            If $t_fullstring = 1 Then
                 If StringInStr($_text, "|" & $ts_string[$i] & "|") Then Return 1
            Else
                 If StringInStr($_text, $ts_string[$i]) Then Return 1   ; gère aussi les blancs
             EndIf
        EndIf
    Next
EndFunc   ;==>_TestRow

Edit
crash-tests en cours

J'ai édité le code de test, ta fonction se met en "erreur autoit" sur une recherche multiple et plante sur une recherche de cellule vide par colonne (ou alors je l'ai mal paramétrée

)

Edit2
Apparemment dans ta fonction la recherche multiple est le seul souci... (test réédité)
J'ai corrigé ma fonction mais je ne sais pas encore comment modifier la tienne
Reste à brain-stormiser la gestion d'erreur ^^'

Trop cool ce petit jeu.

Alors, voici une énième version qui passe tous tes tests :

► Afficher le texte

Code : Tout sélectionner

Func _ArrayDeleteLines(ByRef $avArray, $sString = "", $iFlag = 0, $iRow = -1)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)

    Local $aString = StringSplit($sString, ";")
    If UBound($aString) - 1 > 1 Then
        For $i = 1 To UBound($aString) - 1
            _ArrayDeleteLines($avArray, $aString[$i], $iFlag, $iRow)
        Next
    EndIf

    If $iFlag <> 1 Then $iFlag = 0
    If $iRow > -1 Then
        $iRow = $iRow
    Else
        $iRow = -1
    EndIf
    Local $fired = 0, $iFlagRow = $iRow, $iLine

    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1)
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    Switch $iDimension
        Case 1 ; 1D array
            Local $aArrayTmp[UBound($avArray)]
            For $i = 0 To UBound($avArray) - 1
                Switch $iFlag
                    Case 0 ; Line contain value
                        If StringInStr($avArray[$i], $sString) Or $avArray[$i] = $sString Then ; If line value contain $sString value
                            $fired += 1
                            ContinueLoop 2; Nextline (loop $i)
                        EndIf

                    Case 1 ; Exact match
                        If $avArray[$i] = $sString Then ; If line value is equal to $sString value
                            $fired += 1
                            ContinueLoop 2 ; next line (loop $i)
                        EndIf
                EndSwitch
            Next
            $aArrayTmp[$i - $fired] = $avArray[$i]
            ; In case of all lines deleted
            If UBound($avArray) - $fired < 1 Then
                Dim $aArrayTmp[1]
            Else
                ReDim $aArrayTmp[UBound($avArray) - $fired]
            EndIf

        Case 2 ; 2D array
            Local $cols = UBound($avArray, 2)
            Local $aArrayTmp[UBound($avArray)][$cols]
            If StringLen($sString) = 0 And $iRow = -1 Then $iFlag = -1 ; Blank line
            For $i = 0 To UBound($avArray) - 1 ; Count lines
                $iLine = ""
                Switch $iFlag
                    Case -1 ; Delete blank line
                        For $j = 0 To $cols - 1 ; Count rows
                            If $iRow = -1 Then $iFlagRow = $j
                            $iLine &= $avArray[$i][$j] ; Concatenate all rows and strip all spaces.
                            If StringLen(StringStripWS($iLine, 8)) = 0 Then ; If line is blank line
                                $fired += 1
                                ContinueLoop 2 ; Nextline (loop $i)
                            EndIf
                        Next

                    Case 0 ; Search value(s) in each row
                        For $j = 0 To $cols - 1 ; Count rows
                            If $iRow = -1 Then $iFlagRow = $j
                            $iLine &= StringStripWS($avArray[$i][$j], 1)
                            If (StringInStr($avArray[$i][$j], $sString) Or $avArray[$i][$j] = $sString) And $iFlagRow = $j Then ; If row values contain $sString value
                                $fired += 1
                                ContinueLoop 2 ; Nextline (loop $i)
                            EndIf
                        Next

                    Case 1 ; Search exact match value(s) in each row
                        For $j = 0 To $cols - 1 ; Count rows
                            If $iRow = -1 Then $iFlagRow = $j
                            If $avArray[$i][$j] = $sString And $iFlagRow = $j Then ; If row values is equal to $sString value
                                $fired += 1
                                ContinueLoop 2 ; next line (loop $i)
                            EndIf
                        Next

                EndSwitch

                For $l = 0 To $cols - 1
                    $aArrayTmp[$i - $fired][$l] = $avArray[$i][$l]
                Next
            Next

            ; In case of all lines deleted
            If $iUBound - $fired < 1 Then
                Dim $aArrayTmp[1][1]
            Else
                ReDim $aArrayTmp[$iUBound - $fired][$cols]
            EndIf
    EndSwitch

    ; Check and update elements number
    If $iDimension > 1 Then
        If $aArrayTmp[0][0] = $iUBound Then
            $aArrayTmp[0][0] = UBound($aArrayTmp, 1) - 1
        EndIf
    Else
        If $aArrayTmp[0] = $iUBound Then
            $aArrayTmp[0] = UBound($aArrayTmp, 1) - 1
        EndIf
    EndIf

    $avArray = $aArrayTmp
EndFunc   ;==>_ArrayDeleteLines

Bon, elle est environ 4 fois plus lente, donc je risque peut être d'adopter ta version, mais avant il faudra que tu corrige un autre bug sur ta version. Essaie _ArrayDeleteRows($aArray1, "2", 55) sur un tableau de 500*50, ou tout simplement refait ce test sur un tableau 1D.

Edit :
D'ailleurs, cette dernière version m'a inspiré une nouvelle approche, car ma fonction sur du 1D est 2X plus rapide, donc je pense être parti sur une mauvaise approche en ce qui concerne le 2D.
Dès que j'en aurais le temps, je t'en ferait part.

Et puis, je me suis rendu compte d'un autre problème concernant le code que j'ai rajouté en cas ou toutes les valeurs serait supprimées.
Je faisait :

Code : Tout sélectionner

            If UBound($avArray) - $fired < 1 Then
                ReDim $aArrayTmp[1]
            Else
                ReDim $aArrayTmp[UBound($avArray) - $fired]
            EndIf

alors qu'il faut faire :

Code : Tout sélectionner

            If $iUBound - $fired < 1 Then
                Dim $avArray[1]
            Else
                ReDim $avArray[$iUBound - $fired]
            EndIf

Tlem a écrit : il faudra que tu corrige un autre bug sur ta version. Essaie _ArrayDeleteRows($aArray1, "2", 55) sur un tableau de 500*50, ou tout simplement refait ce test sur un tableau 1D.

Heu je vois pas le problème

Ton 55 c'est un index de colonne, donc ce param est simplement ignoré dans le traitement d'une array 1D, et pour une array 2D il est géré par les lignes

Code : Tout sélectionner

        Case 2 ; array 2D
            Local $cols = UBound($_array, 2)
            If $_str_col < -1 Or $_str_col > $cols - 1 Then $_str_col = -1

qui remettent ce param à la valeur par défaut s'il est supérieur au nb de colonnes
Tu préfèrerais que je mette un SetError ?

► Afficher le texteexemple avec array 1D

Code : Tout sélectionner

#include <Array.au3>

Dim $aArray1[51]
For $i = 0 To 50
      $aArray1[$i] = $i+1
Next

_ArrayDisplay($aArray1 )
_ArrayDeleteRows($aArray1, "2", 55)
_ArrayDisplay($aArray1 )

;===============================================

Func _ArrayDeleteRows(ByRef $_array, $_string = "", $_str_col = -1, $_fullstring = 0, $_delim = "|")
    Local $dims = UBound($_array, 0), $fired = 0
    If Not IsArray($_array) Or $dims > 2 Then Return SetError(1, 0, 0)
    If $_fullstring <> 0 and $_fullstring <> 1 Then Return SetError(2, 0, 0)
    If StringRegExp($_delim, '\w+') Then Return SetError(3, 0, 0)   ; interdit lettre, chiffre ou _ comme délimiteur
   
   Switch $dims

        Case 1 ; array 1D
            Local $temp[UBound($_array)]
            For $i = 0 To UBound($_array) - 1
                $row = $_array[$i]
                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                $temp[$i - $fired] = $_array[$i]
            Next
            If UBound($_array) - $fired < 1 Then
                ReDim $temp[1]
            Else
                ReDim $temp[UBound($_array) - $fired]
            EndIf

        Case 2 ; array 2D
            Local $cols = UBound($_array, 2), $row = ""
            If $_str_col < -1 Or $_str_col > $cols - 1 Then $_str_col = -1
            Local $temp[UBound($_array)][$cols]

            For $i = 0 To UBound($_array) - 1    ; parcourt les lignes
                $row = ""
                If $_str_col = -1 Then
                    For $j = 0 To $cols - 1
                    ;    If StringInStr($_array[$i][$j], $_delim) Then $_array[$i][$j] = StringReplace($_array[$i][$j], $_delim, "")
                        $row &= "|" & $_array[$i][$j] & "|" ; concatène la ligne avec des séparateurs
                    Next
               Else
                ;   If StringInStr($_array[$i][$_str_col], $_delim) Then $_array[$i][$_str_col] = StringReplace($_array[$i][$_str_col], $_delim, "")
                   $row = "|" & $_array[$i][$_str_col] & "|"  ; cellule de colonne
                EndIf

                If _TestRow($row, $_string, $_fullstring, $_delim) Then ; teste la ligne ou la cellule
                    $fired += 1
                    ContinueLoop ; passe à la ligne suivante
                EndIf
                For $j = 0 To $cols - 1
                    $temp[$i - $fired][$j] = $_array[$i][$j]
                Next

            Next
            If UBound($_array) - $fired < 1 Then
                ReDim $temp[1][$cols]
            Else
                ReDim $temp[UBound($_array) - $fired][$cols]
            EndIf
    EndSwitch
    $_array = $temp
    $temp = ""
    Return 1
EndFunc   ;==>_ArrayDeleteRows

; INTERNAL USE ONLY ===============
Func _TestRow($_text, $s_string, $t_fullstring, $t_delim)
 $ts_string = StringSplit($s_string, $t_delim)
    For $i = 1 To $ts_string[0]
        If $ts_string[$i] = "" Then
            If StringRegExpReplace($_text, '\||\s', "") = "" Then Return 1
        Else   
            If $t_fullstring = 1 Then
                 If StringInStr($_text, "|" & $ts_string[$i] & "|") Then Return 1
            Else
                 If StringInStr($_text, $ts_string[$i]) Then Return 1   ; gère aussi les blancs
             EndIf
        EndIf
    Next
EndFunc   ;==>_TestRow

AutoIt Français

[Func] Suppression conditionnelle de ligne dans array 1 - 2D

[Func] Suppression conditionnelle de ligne dans array 1 - 2D

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1

Re: [Func] Suppression conditionnelle de ligne dans array 1