[UDF] 7-Zip avec Dll x32 et x64

[Tlem]

Comme je l'ai dit sur le forum Anglais, après une semaine (19 téléchargements ) il est frustrant de n'avoir aucun retour sur cet UDF qui apporte quand même le support 64 Bit et un correctif sur les nouvelles archive ZIP !!!

[babiol]

Bonjour,

Et tout d'abord un grand merci pour ton travail, impressionnant !
Je suis vraiment débutant sur autoit (1 semaine à peine) mais je trouve ce produit génial, j'ai créé un script pour déployer nos applications, on à des .zip (releases) dans un dossier mis à jour par svn et je les extrait avec 7Zip.au3, ça marche bien à partir du script mais après avoir compilé et lancé l'executable je tombe sur le message d'erreur.
J'ai essayé de mettre les dll à la fois dans le même dossier et dans le dossier Temp mais ça ne change rien. Une idée ?



Voici mon script:

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=application.ico
#AutoIt3Wrapper_Outfile=install Toto Rich Client.exe
#AutoIt3Wrapper_Outfile_x64=install Toto Rich Client x64.exe
#AutoIt3Wrapper_UseUpx=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <File.au3>
#include <WindowsConstants.au3>
#include <7Zip.au3>
#include <GuiListView.au3>
#include <ButtonConstants.au3>
;#include <ListViewConstants.au3>

;create a text file with all the releases of the rich client
;RunWait(@ComSpec & " /c " & 'listsvn.bat', "", @SW_HIDE)
RunWait(@ComSpec & " /c " & 'if exist listsvn%USERNAME%.txt @del /q listsvn%USERNAME%.txt', "", @SW_HIDE)
RunWait(@ComSpec & " /c " & '"C:\Program Files\SlikSvn\bin\svn.exe" up O:\Toto_binaries\releases\rc', "", @SW_HIDE)
RunWait(@ComSpec & " /c " & '"C:\Program Files\SlikSvn\bin\svn.exe" list -v -r HEAD https://svn_adress/svn/Toto/releases/rc>tmp%USERNAME%.txt', "", @SW_HIDE)
RunWait(@ComSpec & " /c " & 'more +1 tmp%USERNAME%.txt>tmp & move /y tmp tmp%USERNAME%.txt', "", @SW_HIDE)
RunWait(@ComSpec & " /c " & 'for /f "tokens=4,5,6,9,10,11 delims=-_V " %i in (tmp%USERNAME%.txt) do echo Toto_RC-%l-%m_V%n^|%m^|%l^|%~nn^|%j %i^|%k>>listsvn%USERNAME%.txt', "", @SW_HIDE)
RunWait(@ComSpec & " /c " & 'del /q tmp%USERNAME%.txt', "", @SW_HIDE)


Global $userspath = "listsvn" & @Username & ".txt"
$app = GUICreate("Toto Rich Client installation", 305, 160)
$install = GUICtrlCreateButton("Install", 265, 80, 40, 40, $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 271)
$uninstall = GUICtrlCreateButton("Uninstall", 265, 120, 40, 40, $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 32)
$rclist = GUICtrlCreateListView("zip|RC|Ver.|Core Release|Date|Hour", 0, 0, 265, 160)

GUISetState(@SW_SHOW)
GUISetIcon("application.ico", 0)

_Fill_List()


Do
    $msg = GUIGetMsg()
    Select
        Case $msg = $install
            Local $arr = StringSplit(GUICtrlRead(GUICtrlRead($rclist)), "|")
            If GUICtrlRead(GUICtrlRead($rclist)) Then
                ConsoleWrite($arr[1] & @LF)
                ;RunWait(@ComSpec & " /c " & 'unziprc.bat ' & $arr[2], "", @SW_HIDE)
                $sRelease = StringTrimRight($arr[1], 4)
                $sArchive = "O:\Toto_binaries\releases\rc\" & $arr[1] & ""
                $sOutDir = "D:\Programme\Toto\" & $sRelease & "\"
                ConsoleWrite($sOutDir & @LF)
                $retResult = _7ZIPExtractEx(0, $sArchive, $sOutDir, 0, 1)
                If @error = 0 Then
                    Run(@ComSpec & " /c " & 'D: & cd "' & $sOutDir & '" & ' & $sOutDir & 'Toto_create_links.bat', "", @SW_HIDE)
                    MsgBox(64, "_7ZIPExtractEx", "Installation finished", 2)
                Else
                    MsgBox(16, "_7ZIPExtractEx", "Error occurred")
                EndIf
                ConsoleWrite("Installation finished" & @LF)
            EndIf
        Case $msg = $uninstall
            ConsoleWrite("Uninstalling" & @LF)
            RunWait(@ComSpec & " /c " & 'FOR /D %X IN (D:\Programme\Toto\Toto_RC*) DO RD /S /Q "%X"', "", @SW_HIDE)
            RunWait(@ComSpec & " /c " & 'if exist "C:\Documents and Settings\%USERNAME%\Desktop\Toto Rich Client*.lnk" del /q "C:\Documents and Settings\%USERNAME%\Desktop\Toto Rich Client*.lnk"', "", @SW_HIDE)
            MsgBox(0, "", "Uninstallation finished", 2)
        Case $msg = $rclist
            ;MsgBox(0, "listview", "clicked=" & GUICtrlGetState($rclist), 2)
        Case $msg = $GUI_EVENT_CLOSE
            RunWait(@ComSpec & " /c " & 'del /q listsvn' & @Username & '.txt', "", @SW_HIDE)
    EndSelect
Until $msg = $GUI_EVENT_CLOSE

Func _Fill_List()
    ; Read the file into an array
    Local $array
    _FileReadToArray($userspath, $array)
    ; Check we read something
    If IsArray($array) Then
        Dim $item[UBound($array)]
        ; Convert to a string with delimiters
        For $i = 1 To $array[0]
            $item[$i] = GUICtrlCreateListViewItem($array[$i], $rclist)
        Next
        ; And fill the list
        GUICtrlSetData($rclist, $item)
    EndIf
    _GUICtrlListView_SetColumnWidth($rclist, 0, 0)
EndFunc

[babiol]

Pour contourner mon problème et étant donné que 7zip est déjà installé sur tous les postes j'ai fini par remplacer

Code : Tout sélectionner

$retResult = _7ZIPExtractEx(0, $sArchive, $sOutDir, 0, 1)

par

Code : Tout sélectionner

RunWait('"C:\Program Files\7-Zip\7zg.exe" x "'  & $sArchive & '" -y -o"' & $sOutDir & '"')

Bon c'est un contournement mais au moins je peux faire mon exe.

[Tlem]

C'est un contournement qui ne fonctionnera que sur les OS 32 bit !!!
J'aimerais bien avoir le message d'erreur SVP.

Edit : Pour le message d'erreur, vous avez oublié de lire ceci :

** De part l'ajout des fonctions _7ZipStartup et _7ZipShutdown, vous devrez probablement
mettre à jour les anciens codes qui utilisent les fonctions répétitives.

[babiol]

C'est un contournement qui ne fonctionnera que sur les OS 32 bit !!!
J'aimerais bien avoir le message d'erreur SVP.

Oui effectivement, merci de le souligner, je devrais faire des tests au préalable et utiliser %ProgramFiles% ou %programfiles(x86)%

Edit : Pour le message d'erreur, vous avez oublié de lire ceci :

** De part l'ajout des fonctions _7ZipStartup et _7ZipShutdown, vous devrez probablement
mettre à jour les anciens codes qui utilisent les fonctions répétitives.

J'ai un peu du mal à retrouver le bout de code qui utilise une fonction répétitive, pouvez-vous m'éclairer ?
Merci pour votre réponse.

[Tlem]

_7ZipStartup et _7ZipShutdown permettent de charger ou décharger la dll. Donc, soit vous avez une seule commande à lancer et dans ce cas vous commencez par _7ZipStartup, puis votre commande de l'UDF 7Zip et vous finissez par _7ZipShutdown (sauf pour certaines commandes prévues pour fonctionner de manière autonome car elles chargent la dll si elle n'est pas déjà ouverte), soit votre script doit lancer plusieurs commandes de l'UDF 7zip et dans ce cas vous commencez votre script par _7ZipStartup puis votre code qui utilise les commandes 7zip de l'UDF et quand vous quittez votre script, utilisez _7ZipShutdown pour fermer la dll.

En espérant que cela soit plus clair.

[babiol]

A oui merci, c'est vraiment plus clair, c'est bien pensé ce chargement optimal de la dll, je testerai demain, merci encore

[babiol]

Bonjour,

J'ai trouvé d'où venait l'erreur une fois le fichier compilé dans l'utilisation de _7ZipStartup(), dans mon cas j'ai mon .exe avec les dll 7zip dans le même dossier, et la fonction FileInstall me déplace ces dll dans le Temp, je les ai donc mis en lecture seule.
ça ne fonctionne toujours pas, en effet la copie des dll vers Temp via FileInstall ne prend pas en compte une latence système, la dll est bien copiée mais le Return SetError(3, 0, 0) est envoyé trop vite ou bien c'est autre chose. Peut-être le Or _
En modifiant légèrement le code de 7Zip.au3 dans le Else (donc quand on compile) ça fonctionne.

► Afficher le texte

Je remplace ça

Code : Tout sélectionner

    Else ; If compiled, test and open the right dll (that must be in ScriptDir for compiling)
        If Not FileInstall("7-zip32.dll", $sCompiledPath & $sZip32Dll, 1) Or _
           Not FileInstall("7-zip64.dll", $sCompiledPath & $sZip64Dll, 1) Then Return SetError(3, 0, 0)
        If @OSArch = "X86" Then
            $hDLL_7ZIP = DllOpen($sCompiledPath & $sZip32Dll) ; Open x32 dll from FileInstall path
        Else
            $hDLL_7ZIP = DllOpen($sCompiledPath & $sZip64Dll) ; Open x64 dll from FileInstall path
        EndIf
    EndIf

par ça

Code : Tout sélectionner

    Else ; If compiled, test and open the right dll (that must be in ScriptDir for compiling)
        If @OSArch = "X86" Then
            If Not FileInstall("7-zip32.dll", $sCompiledPath & $sZip32Dll, 1) Then
                Return SetError(3, 0, 0)
            Else
                $hDLL_7ZIP = DllOpen($sCompiledPath & $sZip32Dll) ; Open x32 dll from FileInstall path
            EndIf
        Else
            If Not FileInstall("7-zip64.dll", $sCompiledPath & $sZip64Dll, 1) Then
                Return SetError(3, 0, 0)
            Else
                $hDLL_7ZIP = DllOpen($sCompiledPath & $sZip64Dll) ; Open x64 dll from FileInstall path
            EndIf
        EndIf
    EndIf

[Tlem]

Correction prise en compte (de manière plus simple) et mise à jour du premier message. De plus cette suggestion évitera de décompresser inutilement la dll de l'autre architecture (j'aurais dut y penser avant ... ).

Merci babiol.

[babiol]

Je vous en prie, par contre j'ai laissé une petite erreur qui ne se voit pas en compilation mais qui se voit quand on Run le au3 (F5), il faut apparement toujours faire des retours à la ligne après les Then et Else, sinon on a des message d'erreur dans SciTE, j'ai corrigé dans le code ci-dessus.

[Tlem]

Je n'ai pas utilisé votre correction. J'ai fait bien plus simple ...

[davzell]

quelqu'un sait ce qui pourrait poser problème.

j'ai téléchargé le package fournit a la page 1, décompressé le fichier sur mon pc
ajouté le chemin vers le dossier décompressé dans SciTE config (dans la partie User Includes)

et quand je test le script d'exemple ca ne marche pas

Code : Tout sélectionner

#include <7Zip.au3>
; Compression d'un répertoire avec ses sous répertoires.
$retResult = _7ZipAdd(0, "MonArchive.zip", "C:\test")
If @error Then
    MsgBox(64, "_7ZipAdd", "Erreur lors de la création de l'archive")
Else
    MsgBox(64, "_7ZipAdd", "L'archive à été crée avec succés" & @LF & $retResult)
EndIf

dans Scite Si je commence a taper _7Zip... il ne me propose aucune des fonction inclus dans l'udf (du coup j'ai l'impression que le 7zip.au3 n'est pas prise en compte dans sciTE)

j'ai aussi essayé de copié le fichier 7zip.au3 (et les dll) dans le répertoire include mais pas mieux

[timmalos]

Premièrement il ne faut pas confondre l'autocompletion dans Scite et l'ajout d'un include.

Ce qu'il faut faire c'est soit copier l'include et les dlls dans le dossier de votre script et l'inclure avec #include "7Zip.au3" soit dans le dossier autoit/includes et l'inclure avec #include <7Zip.au3>

Ensuite si vous avez une erreur il faut nous la donner pour qu'on puisse vous aider

[davzell]

Premièrement il ne faut pas confondre l'autocompletion dans Scite et l'ajout d'un include.

Ce qu'il faut faire c'est soit copier l'include et les dlls dans le dossier de votre script et l'inclure avec #include "7Zip.au3" soit dans le dossier autoit/includes et l'inclure avec #include <7Zip.au3>

Ensuite si vous avez une erreur il faut nous la donner pour qu'on puisse vous aider

ah mince je pensais que l'autocompletion pouvait être un moyen de vérifier si les udf était bien prise en compte.

du coup j'ai testé les deux méthodes (udf dans includes et a coté de mon script) mais c'est la même chose j'ai une erreur "Erreur lors de la création de l'archive" dans le script donné juste avant

est ce que j'ai moyen de voir si les udf sont bien prise en compte dans sciTE ?

[timmalos]

Si vous n'avez pas d'erreur de compilation ce qui semble être le cas, l'UDF est bien ajouté.

Remplacez

Code : Tout sélectionner

MsgBox(64, "_7ZipAdd", "Erreur lors de la création de l'archive")

Par

Code : Tout sélectionner

MsgBox(64, "_7ZipAdd", "Erreur lors de la création de l'archive"& @error)

Et donnez nous le numero de l'erreur

[davzell]

j'ai: Erreur lors de la création de l'archive2

[timmalos]

Il n'arrive pas à ouvrir la DLL.
Celle-ci doit etre dans le même repertoire que votre script.
Verifiez que c'est bien le cas.
Essayez egalement les exemples qui sont dans le zip pour tester.

[davzell]

j'ai testé les exemples fournis avec et idem j'ai une erreur "enable to start dll"

pourtant elles sont bien au même endroit que mon script.

[Tlem]

Fonctionne parfaitement sur XP et W7 x64 avec AutoIt v3.3.8.0.
Fonction testée : _7ZipAdd_Example.au3

[davzell]

j'ai testé chez moi les mêmes manip et ca marche...

doit y avoir quelque chose qui bloque sur le poste du taf mais quoi ?

ya pas de prérequis ou autre a avoir sur le poste pour que ca fonctionne ?