[UDF] 7-Zip avec Dll x32 et x64

[Tlem]

Voici un UDF qui va vous permettre de créer des archives Zip et 7z, ainsi que de faire l'extraction de fichiers d'archives 7z, zip, gzip, bzip2 et tar.

Post original ici.
Merci à rasim pour son magnifique travail.

Fonctions principales :

• - Support des archives 7z, zip, gzip, bzip2, tar.
  - Cryptage/decryptage des archives.
  - Inclusion/exclusion d'archives.
  - Inclusion/exclusion de fichiers.
  - Module SFX.
  - Archives multivolume.
  - Contrôle de d'archive.
  - Méthode de compression 0-9.
  - 3 méthodes de récursion.
  - Suppression de fichiers dans l'archive.
  - Mise à jour de l'archive.
  - Recherche dans l'archive.
  - Fonction Call-back Dll (pour utiliser 7-zip32.dll avec votre GUI)
  - Récupération la date/heure des fichiers de l'archive.
  - Récupération la taille compressée/décompréssée des fichiers de l'archive.
  - Récupération du ration de compression.
  - Récupération du CRC des fichiers.
  - Récupération du nombre de fichier de l'archive.
  - Lister les fichiers d'une archive

et plus encore ...

Liste des 29 fonctions de l'UDF :

• _7ZipStartup
  _7ZipShutdown
  _7ZipAdd
  _7ZipDelete
  _7ZIPExtract
  _7ZipExtractEx
  _7ZipUpdate
  _7ZipSetOwnerWindowEx
  _7ZipKillOwnerWindowEx
  _7ZipOpenArchive
  _7ZipCloseArchive
  _7ZipFindFirst
  _7ZipFindNext
  _7ZipGetFileName
  _7ZipGetArcOriginalSize
  _7ZipGetArcCompressedSize
  _7ZipGetArcRatio
  _7ZipGetDate
  _7ZipGetTime
  _7ZipGetCRC
  _7ZipGetAttribute
  _7ZipGetMethod
  _7ZipCheckArchive
  _7ZipGetArchiveType
  _7ZipGetFileCount
  _7ZipConfigDialog
  _7ZipQueryFunctionList
  _7ZipGetVersion
  _7ZipGetSubVersion
  _7ZipGetFilesList

L'UDF, les Dll et quelques exemples ce trouvent dans le fichier joint à ce message. Veuillez prendre note, que les Dll doivent impérativement être placées dans le même dossier que l'UDF ou votre compilation. Vous pouvez modifier le nom et l'emplacement de celles-ci dans la section des variables au début de l'UDF.

Vous trouverez ci-dessous quelques exemples simple d'utilisation de cet UDF :

► Afficher le texte

Code : Tout sélectionner

; Compression d'un répertoire avec ses sous répertoires.
$retResult = _7ZipAdd(0, "MonArchive.zip", "C:\Dir1")
If @error Then
    MsgBox(64, "_7ZipAdd", "Erreur lors de la création de l'archive")
Else
    MsgBox(64, "_7ZipAdd", "L'archive à été crée avec succés" & @LF & $retResult)
EndIf


; Compression des fichier *.txt d'un répertoire.
$retResult = _7ZipAdd(0, "MonArchive.zip", "C:\Dir1\*.txt")
If @error Then
    MsgBox(64, "_7ZipAdd", "Erreur lors de la création de l'archive")
Else
    MsgBox(64, "_7ZipAdd", "L'archive à été crée avec succés" & @LF & $retResult)
EndIf


; Extraction d'une archive vers un dossier.
$retResult = _7ZIPExtract(0, "MonArchive.zip", "C:\Dir2")
If @error = 0 Then
    MsgBox(64, "_7ZIPExtractEx", $retResult)
Else
    MsgBox(64, "_7ZIPExtractEx", "Erreur lors de l'extraction de l'archive")
EndIf

; Extraction du fichier Fichier1.txt de l'archive MonArchive.zip vers le dossier C:\Dir2.
$retResult = _7ZIPExtract(0, "MonArchive.zip", "C:\Dir2", 0, 0, 1, 0, 0, 0, "Fichier1.txt")
If @error = 0 Then
    MsgBox(64, "_7ZIPExtractEx", $retResult)
Else
    MsgBox(64, "_7ZIPExtractEx", "Une erreur est survenue")
EndIf

Edit du 07-10-2012 : Modification significative de l'UDF.

** De part l'ajout des fonctions _7ZipStartup et _7ZipShutdown, vous devrez probablement mettre à jour les anciens codes qui utilisent les fonctions répétitives.

Edit du 14-11-2017 : Modification de deux fonctions de l'UDF.
Suite aux très bonnes remarques de Elementary dans le message #59 :
Mise à jour de la fonction _7ZipStartup() et _7ZipAdd().
Voir explication dans le message #65.

► Afficher le texteMises à jour

Version du 7 Octobre 2012 (téléchargée 38 fois) :
- Première version à intégrer les dll 32 et 64 bit.
- Mise à jour de la dll 32 bit.
- Ajout des fonctions _7ZipStartup, _7ZipShutdown et _7ZipGetFilesList.
- Ajout de la gestion automatique de l'ouverture de la dll pour certaines fonctions (voir la liste en début d'UDF).
- Mise à jour et mise en forme des descriptions des fonctions.
- Modifications diverses et variées du code et des exemples pour adapter aux nouvelles fonctions.

Version du 7 Octobre 2012 :
- Modification de la fonction _7ZipStartup pour prendre en compte un bug remonté par babiol concernant l'ouverture des dll.

.

[Tlem]

Petite info pour ceux que ça peut intéresser :
Si vous voulez que l'UDF gère la compilation de la DLL dans l’exécutable automatiquement, et place la DLL dans le répertoire temporaire lors de l'utilisation de votre programme, modifiez les premières lignes de l'UDF comme ceci:

► Afficher le texte

Code : Tout sélectionner

; #VARIABLES# ==========================================================================
Global $hDLL_7ZIP
If FileExists(@ScriptDir & "\7-zip32.dll") Then
    $hDLL_7ZIP = DllOpen(@ScriptDir & "\7-zip32.dll")
Else
    FileInstall("7-zip32.dll", @TempDir & "\7-zip32.dll", 1)
    $hDLL_7ZIP = DllOpen(@TempDir & "\7-zip32.dll")
EndIf
If $hDLL_7ZIP = -1 Then Exit 1

N'oubliez pas évidemment de mettre la DLL dans le même répertoire que l'UDF avant la compilation en exécutable.

De part les modifications du 7-10-2012, ce message est obsolète.

[Tlem]

Correctif de l'UDF 7Zip.au3.
Voir lien d'origine pour plus d'info.

[DJSIR]

Je dois avoir du mal à comprendre aujourd'hui mais, quand j'extrais un fichier 7Z, il m'extrait touts les fichiers dans le même dossier et pas dans chaque dossier séparé comme dans l'archive. Comprendo ?

Non, alors je réexplique.
dans mon archive j'ai un dossier A, un B et un C. dans chaque dossier se situe un fichier info.txt et info2.txt.
Quand j'extrais l'archive avec _7ZExtract, tout se retrouve dans le même dossier. A, B et C étant vides !

Comment faire ?

[Tlem]

Un petit suppo, un petit dodo et demain lisez un peut mieux les fichiers d'exemple.

J'ai créé une archive 7z multi-dossier avec des fichiers dans chacun de ses dossiers et en utilisant _7ZIPExtractEx_Example.au3 j'ai bien extrait la même arborescence dossiers/fichiers.
Cela veut donc dire que vous n'avez pas utilisé la bonne méthode. Comprendo ?

[coke]

Bonjour,

J'essaye de faire un ZipUpdate en gardant l'arborescense mais sa ne fonctionne pas

Code : Tout sélectionner

 _7ZipUpdate("", $sArcName, $array[$i])
_7ZIPExtractEx("", $sArcName, @ScriptDir & "\test2")
 

dans le repertoire test2 je n'ai pas l'arborescense complete des fichiers ZIPPER
je ne comprend pas pourquoi

Merci d'avance

[Tlem]

Peut être qu'il vous maque un paramètre dans les fonctions.

Lisez le fichier 7Zip.au3 pour voir comment utiliser l'option de récursion.

[ricky]

Hello,

avec cette fonction : _7ZipOpenArchive

comment on peut faire pour avoir le handle d'un fichier zip qui a été splité en plusieurs?
Si je mets le nom du premier, j'ai bien les infos pour la première partie (le handle et le CRC), mais pas pour toute l'archive.

Merci d'avance pour votre aide.

[Tlem]

Je n'ai pas la réponse, mais peut être que sur le lien d'origine ...

[Tlem]

Bonjour à tous. Suite à un sujet du forum, j'ai créé la fonction _7ZipGetFilesList ci-dessous, qui permet d'avoir la liste complète des fichiers et dossiers d'une archive Zip ou 7z.

Cette fonction est dépendante de l'UDF 7zip.au3 ainsi que de 3 autres fonctions crées pour les besoins.

Petit conseil : Intégrez ces fonctions à l'UDF 7zip.au3, cela vous facilitera la vie. ^^

Note : Sur mon PC portable DualCore Centrino T5500 1,66Ghz, la liste d'une archive Zip de 250Mo contenant 9000 fichiers/Dossiers à été effectuée en 6 secondes.

Le code :

► Afficher le texte_7ZipGetFilesList + dépendances

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _7ZipGetFilesList
; Description ...: Returns an array of files and dir in an archive
; Syntax.........: _7ZipGetFilesList($hWnd, $sArcName)
; Parameters ....: $hWnd         - Handle to parent or owner window
;                  $sArcName     - Archive file name
; Return values .: Success - Returns an array of files and dir in an archive
;                  Failure - Returns 0 and set error
; Related .......: _7ZipOpenArchive, _7ZipCloseArchive, _7ZipGetFileCount, _7ZipFindFirst, _7ZipFindNext,
;                  _7ZipGetArcOriginalSize, _7ZipGetDate, _7ZipGetTime,
;                  _Get7zipStringAttribute, _OEMToAnsi, _7ZipDateTimeToStr
; Author ........: Tlem
; ===============================================================================================================================
Func _7ZipGetFilesList($hWnd, $sArcName)
    Local $hArc = _7ZipOpenArchive($hWnd, $sArcName)
    If $hArc = 0 Then Return SetError(1, 0, 0)

    Local $szFileCount = _7ZipGetFileCount($sArcName)
    Local $aArcFilesList[$szFileCount + 1][4]
    Local $iDosDate, $iDosTime, $iCount = 1
    $aArcFilesList[0][0] = $szFileCount
    $aArcFilesList[0][1] = "Size"
    $aArcFilesList[0][2] = "Attribute"
    $aArcFilesList[0][3] = "Date and Time"


    Local $tINDIVIDUALINFO = _7ZipFindFirst($hArc, "*")
    If $tINDIVIDUALINFO = -1 Then Return SetError(1, 0, 0)
    $aArcFilesList[1][0] = _OEMToAnsi(DllStructGetData($tINDIVIDUALINFO, "szFileName"))
    $aArcFilesList[1][2] = _Get7zipStringAttribute($hArc)
    If Not StringInStr($aArcFilesList[1][2], "D") Then
        $aArcFilesList[1][1] = DllStructGetData($tINDIVIDUALINFO, "dwOriginalSize")
    EndIf
    $iDosDate = _7ZipGetDate($hArc)
    $iDosTime = _7ZipGetTime($hArc)
    $aArcFilesList[1][3] = _7ZipDateTimeToStr($iDosDate, $iDosTime)

    While 1
        $iCount += 1
        $tINDIVIDUALINFO = _7ZipFindNext($hArc, $tINDIVIDUALINFO)
        If $tINDIVIDUALINFO = 0 Then ExitLoop
        $aArcFilesList[$iCount][0] = _OEMToAnsi(DllStructGetData($tINDIVIDUALINFO, "szFileName"))
        $aArcFilesList[$iCount][2] = _Get7zipStringAttribute($hArc)
        If Not StringInStr($aArcFilesList[$iCount][2], "D") Then
            $aArcFilesList[$iCount][1] = DllStructGetData($tINDIVIDUALINFO, "dwOriginalSize")
        EndIf
        $iDosDate = _7ZipGetDate($hArc)
        $iDosTime = _7ZipGetTime($hArc)
        $aArcFilesList[$iCount][3] = _7ZipDateTimeToStr($iDosDate, $iDosTime)
    WEnd

    _7ZipCloseArchive($hArc)
        Return $aArcFilesList
EndFunc   ;==>_7ZipGetFilesList

; #FUNCTIONS FOR INTERNAL USE# ==================================================================================================
Func _OEMToAnsi($sOEM)
    Local $a_AnsiFName = DllCall('user32.dll', 'Int', 'OemToChar', 'str', $sOEM, 'str', '')
    If @error = 0 Then $sAnsi = $a_AnsiFName[2]

    Return $sAnsi
EndFunc   ;==>_OEMToAnsi

Func _Get7zipStringAttribute($ArcHandle)
    Local $sAttrib
    Local $iAttrib = _7ZipGetAttribute($ArcHandle)

    If BitAND($iAttrib, 0X01) Then $sAttrib &= 'R'
    If BitAND($iAttrib, 0X02) Then $sAttrib &= 'H'
    If BitAND($iAttrib, 0X04) Then $sAttrib &= 'S'
    If BitAND($iAttrib, 0X08) Then $sAttrib &= 'L'
    If BitAND($iAttrib, 0X10) Then $sAttrib &= 'D'
    If BitAND($iAttrib, 0X20) Then $sAttrib &= 'A'
    If BitAND($iAttrib, 0X40) Then $sAttrib &= 'E'

    Return $sAttrib
EndFunc   ;==>_Get7zipStringAttribute

; This function is identical from _Date_Time_DOSDateTimeToStr function.
Func _7ZipDateTimeToStr($iDosDate, $iDosTime)
    Local $aDate[6]

    $aDate[0] = BitAND($iDosDate, 0x1F)
    $aDate[1] = BitAND(BitShift($iDosDate, 5), 0x0F)
    $aDate[2] = BitAND(BitShift($iDosDate, 9), 0x3F) + 1980
    $aDate[5] = BitAND($iDosTime, 0x1F) * 2
    $aDate[4] = BitAND(BitShift($iDosTime, 5), 0x3F)
    $aDate[3] = BitAND(BitShift($iDosTime, 11), 0x1F)

    Return StringFormat("%02d/%02d/%04d %02d:%02d:%02d", $aDate[0], $aDate[1], $aDate[2], $aDate[3], $aDate[4], $aDate[5])
EndFunc

Et voici un exemple d'utilisation :

Code : Tout sélectionner

#include '7Zip.au3'
#include <Array.au3>

$aFlist = _7ZipGetFilesList(0, 'Archive.zip')
_ArrayDisplay($aFlist)

Bon code à tous.

Edit du 07-10-2012 : Modification de la fonction afin de corriger deux bugs sur la taille des fichiers et des répertoires.

[Chokolaa]

Salut,

Serait t'il possible de faire un support des archives jar svp?

[Tlem]

c'est une boutade ???

http://fr.wikipedia.org/wiki/JAR_(format_de_fichier)
Extrait :

Les fichiers JAR sont créés et extraits à l'aide de la commande jar incluse dans le JDK. On peut cependant renommer les fichiers .jar avec l'extension.zip et les manipuler avec les outils ZIP. La classe Java JarFile du package java.util.jar hérite de ZipFile.

[mikell]

Roh la vache, comment passer pour un con en 2 secondes

[Chokolaa]

J'ai fait un programme qui utilise cet UDF il y a un mois, il marchais bien, mais aujourd'hui, je reprend mon projet et quand il lance l'extraction d'un fichier, la fenêtre d'extraction apparaît pendant une demi seconde puis disparaît et l'archive n'est pas extraite.

Pourtant le programme est le même qu'hier et la DLL ce trouve dans le dossier de mon script avec l'UDF 7-zip32. Je ne comprend pas ...

[silvere]

Tu peut toujours essayer http://www.autoitscript.fr/forum/viewto ... =21&t=6084 au moins tu n'auras plus de dll

[Tlem]

@silvere
Pour info, le titre du sujet que vous citez est : 7-Zip32 sans DLL (DLL en mémoire)
Donc finalement il y a toujours l'utilisation de la DLL, mais celle-ci est intégrée au script et directement chargée en mémoire.

@Chokolaa
Si vous n'avez fait aucun changement particulier depuis la dernière fois, regardez si le fichier de DLL ne serait pas endommagé et/ou si le code ne serait pas tributaire d'un élément qui n'est plus présent depuis la dernière fois.

[Chokolaa]

Ah merci, la DLL était endommagé, j'avais pas eu l'idée de la retélécharger ^^

[jide]

Bonjour et merci pour la partage !

Une petite correction ligne 74 :

Code : Tout sélectionner

If $sPassword Then $iSwitch &= " -p" & $sPassword

devient

Code : Tout sélectionner

If $sPassword Then $iSwitch &= " -p" & $sPassword & ' -mhe'

[Tlem]

@silvere
Pour info, le titre du sujet que vous citez est : 7-Zip32 sans DLL (DLL en mémoire)
Donc finalement il y a toujours l'utilisation de la DLL, mais celle-ci est intégrée au script et directement chargée en mémoire.

@Chokolaa
Si vous n'avez fait aucun changement particulier depuis la dernière fois, regardez si le fichier de DLL ne serait pas endommagé et/ou si le code ne serait pas tributaire d'un élément qui n'est plus présent depuis la dernière fois.

[Tlem]

Très grosse mise à jour de l'UDF. Merci de lire les modifications dans le premier message de ce sujet.

Malgré le temps passé à tester l'UDF, il peut subsister quelques erreurs ou problèmes. Merci à ceux qui voudrons bien tester les fonctions le plus intensivement possible.