AutoIt Français

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_BitmapGetPixel
; Description ...: Détermine la couleur d'un pixel.
; Syntax.........: _GDIPlus_BitmapGetPixel($hBitmap, $iX, $iY)
; Parameters ....: $hBitmap - Handle vers l'image dont on cherche la couleur d'un pixel
;                  $iX      - Abscisse du pixel
;                  $iY      - Ordonnée du pixel
; Return values .: Couleur du pixel en ARGB
; Author ........: Tolf
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......;
; ===============================================================================================================================
Func _GDIPlus_BitmapGetPixel($hBitmap, $iX, $iY)
    Local $tArgb, $pArgb, $aRet
    $tArgb = DllStructCreate("dword Argb")
    $pArgb = DllStructGetPtr($tArgb)
    $aRet = DllCall($ghGDIPDll, "int", "GdipBitmapGetPixel", "hwnd", $hBitmap, "int", $iX, "int", $iY, "ptr", $pArgb)
    Return "0x" & Hex(DllStructGetData($tArgb, "Argb"))
EndFunc   ;==>GDIPlus_BitmapGetPixel

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_BitmapSetPixel
; Description ...: Définit la couleur d'un pixel.
; Syntax.........: _GDIPlus_BitmapSetPixel($hBitmap, $iX, $iY, $iArgb)
; Parameters ....: $hBitmap - Handle vers l'image à modifier
;                  $iX      - Abscisse du pixel
;                  $iY      - Ordonnée du pixel
;                  $iArgb   - Couleur du pixel en ARGB
; Return values .: None
; Author ........: Tolf
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......;
; ===============================================================================================================================
Func _GDIPlus_BitmapSetPixel($hBitmap, $iX, $iY, $iArgb)
    DllCall($ghGDIPDll, "int", "GdipBitmapSetPixel", "hwnd", $hBitmap, "int", $iX, "int", $iY, "dword", $iArgb)
EndFunc   ;==>_GDIPlus_BitmapSetPixel

Code : Tout sélectionner

#Include <GDIPlus.au3>

_GDIPlus_Startup()
$h_image = _GDIPlus_ImageLoadFromFile("c:\test.jpg") ; <== mettez un chemin vers une image existante
$color = _GDIPlus_BitmapGetPixel($h_image, 10, 20) ; <== détermine la couleur du pixel 10;20
msgbox(0,"",$color)
_GDIPlus_BitmapSetPixel($h_image, 20, 10, 0xFFFF0000) ; <== met le pixel 20;10 en rouge
_GDIPlus_ImageSaveToFile($h_image, "c:\test2.jpg") ; <== enregistre l'image modifiée dans "C:\test2.jpg"
_GDIPlus_ImageDispose($h_image)
_GDIPlus_Shutdown()

Func _GDIPlus_BitmapGetPixel($hBitmap, $iX, $iY)
    Local $tArgb, $pArgb, $aRet
    $tArgb = DllStructCreate("dword Argb")
    $pArgb = DllStructGetPtr($tArgb)
    $aRet = DllCall($ghGDIPDll, "int", "GdipBitmapGetPixel", "hwnd", $hBitmap, "int", $iX, "int", $iY, "ptr", $pArgb)
    Return "0x" & Hex(DllStructGetData($tArgb, "Argb"))
EndFunc   ;==>GDIPlus_BitmapGetPixel

Func _GDIPlus_BitmapSetPixel($hBitmap, $iX, $iY, $iArgb)
    DllCall($ghGDIPDll, "int", "GdipBitmapSetPixel", "hwnd", $hBitmap, "int", $iX, "int", $iY, "dword", $iArgb)
EndFunc   ;==>_GDIPlus_BitmapSetPixel