[Tuto] Divers Exemples de DllCall()

[SagePourpre]

Le but de ce sujet est de partager vos utilisations de DllCall
afin d'en faire profiter les autres.

Si vous n'y connaissez rien, allez tout d'abord voir ce tutoriel pour
vous initier à DllCall et ces possibilités énormes .
http://autoitscript.fr/forum/viewtopic. ... 147#p36147

Ensuite, pour pouvoir voir les fonctions à l'intérieur d'un dll précis,
vous aurez besoin de Dll Export Viewer
Site : http://www.nirsoft.net/utils/dll_export_viewer.html
Lien de téléchargement direct ( 32 bits ) : http://www.nirsoft.net/utils/dllexp.zip
Lien de téléchargement direct ( 64 bits ) : http://www.nirsoft.net/utils/dllexp-x64.zip

Enfin, si ce n'a pas été fait, un petit tour dans l'aide d'autoit pour la fonction DllCall peut vous
éclairer un peu plus.


Finalement, connaître le nom d'une fonction ne suffit pas, pour l'utiliser, il vous faut les renseignements
sur son fonctionnement. Vous pourrez trouver ces renseignement très facilement dans le cas
des dll de Windows sur MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx
(Fonction Sleep dans le lien suivant )



Afin que le tout soit clair, veuillez utiliser la formule suivante

Courte description

Code : Tout sélectionner

DllCall()

[Spoiler]Informations supplémentaires + exemple concis [/Spoiler]


*****************************************************


P.s. : Si vous voulez apprendre à utiliser DllCall correctement, je vous conseille vivement
de commencer par le tutoriel au début de ce message ( tutoriel en anglais )




edit : Pour commencer, voici un exemple facile à comprendre

Message Box

Code : Tout sélectionner

DllCall("user32.dll", "int", "MessageBox", "hwnd", 0, "str", "text", "str", "title", "int", 0)

► Afficher le texte

Exécuter le dllcall tel quel et modifiez les paramètres (non pas les "types") et voyez par
vous-même le résultat.

Lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

[SagePourpre]

Déplacer une fenêtre à l'aide de la souris.

Code : Tout sélectionner

DllCall("user32.dll", "long", "SendMessage", "hwnd", $gui, "int", $WM_SYSCOMMAND, "int", 0xF009, "int", 0)

► Afficher le texte

$gui est égal ici au handle de la fenêtre à déplacer
( Récupéré à l'aide de WinGetHandle ou encore la valeur retournée par GuiCreate )

$gui est le seul paramètre à être changé par le handle de votre fenêtre
Tous les autres paramètres doivent rester tel quel.

Exemple :

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include<misc.au3>
$gui = GUICreate("test")
GUISetState()
Do
    If _IsPressed(01) Then DllCall("user32.dll", "long", "SendMessage", "hwnd", $gui, "int", $WM_SYSCOMMAND, "int", 0xF009, "int", 0)
Until GUIGetMsg() = -3

lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Ouvrir un processus

Code : Tout sélectionner

$ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $i_PID)

► Afficher le texte

$i_pid doit être égal au PID d'un processus ( qui peut être retourné par ProcessExist() )



Exemple :

Code : Tout sélectionner

#include <Array.au3>
$i_PID = ProcessExists("explorer.exe")
        Local $ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $i_PID)
        _ArrayDisplay($ai_Handle,$i_PID)
        DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0])
 

Notez bien : comme vous pouvez le constater sur MSDN et sur mon présent exemple,
un dllcall vers "CloseHandle" doit être appelé après avoir terminé avec le handle récupéré.



À quoi ça sert exactement :
Récupérer le "Open handle" d'un processus peut servir si d'autres DllCall réclâme un tel "handle" , comme
dans le prochain exemple.

Lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Libérer la mémoire vive d'une application

Code : Tout sélectionner

DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0])

► Afficher le texte

$ai_Handle[0] doit être le "OpenHandle" du processus dont l'on souhaite vider le plus de mémoire vive
non utilisée.


Exemple :

Code : Tout sélectionner

#include <Array.au3>
$msg0 = ProcessExists("firefox.exe")
ConsoleWrite($msg0 & @CRLF)

$msg = _ReduceMemory($msg0)
ConsoleWrite($msg & @CRLF )

Func _ReduceMemory($i_PID = -1)

    If $i_PID <> -1 Then
        Local $ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $i_PID)

        Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0])
        DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0])
    Else
        Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', -1)
    EndIf

    Return $ai_Return[0]
EndFunc   ;==>_ReduceMemory_PngGui

Lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

[SagePourpre]

Obtenir la position du curseur de la souris

Code : Tout sélectionner

$tPOINTAPI = DllStructCreate("long x;long y")
DllCall("user32.dll","long","GetCursorPos","ptr",DllStructGetPtr($tPOINTAPI))

► Afficher le texte

Exemple :

Code : Tout sélectionner

$tPOINTAPI = DllStructCreate("long x;long y")
DllCall("user32.dll","long","GetCursorPos","ptr",DllStructGetPtr($tPOINTAPI))

ConsoleWrite('x' & DllStructGetData($tPOINTAPI,1) & @CRLF )
ConsoleWrite('y' & DllStructGetData($tPOINTAPI,2) & @CRLF )
 

lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

Je ne comprends pas comment tu as fait pour déterminer la structure ("long x;long y") de
DllStructCreate dans ton exemple.

Réponse : En lisant le paramètre de cette fonction sur le lien MSDN, ce que vous avez
évidemment fait avant de vous poser une pareille question, ceci est mentionné.

[quote name='MSDN']
pPoint [out]
LPPOINT

Pointer to a POINT structure that receives the screen coordinates of the cursor.[/quote]POINT, sur le site de MSDN, est un lien menant vers http://msdn.microsoft.com/en-us/library ... 85%29.aspx

En lisant les possible implémentation de "POINTAPI structure", on y voit 2
paramètres de déclarés
x (int 32)
y (int 32)

long correspond à une donnée de 32 bit signée...

Pourquoi long et pas (int, Uint, Ulong, etc...)
Quelle est la différence entre un "signed integer" et un "unsigned integer", je
l'ignore... Si quelqu'un le sait, je suis preneur.

Obtenir les informations sur un Volume (complexe)
Utilisation de DllStructCreate, DllStructGetPtr et DllStructGetData

Code : Tout sélectionner

DllCall('kernel32.dll','long','GetVolumeInformationW', _
'ptr' , DllStructGetPtr($lpRootPathName), _
'ptr' , DllStructGetPtr($lpVolumeNameBuffer), _
'long', $nVolumeNameSize, _
'ptr' , DllStructGetPtr($lpVolumeSerialNumber), _
'ptr' , DllStructGetPtr($lpMacimumComponentLength), _
'ptr' , DllStructGetPtr($lpFileSystemFlags), _
'ptr' , DllStructGetPtr($lpFileSystemNameBuffer), _
'long',$nFileSystemNameSize)

► Afficher le texte

Exemple complet :

Code : Tout sélectionner

; Le volume dont on veut obtenir les informations
$vol = 'C:\'

; Création d'une structure ( doit être 1 char. de plus grand que notre information )
$lpRootPathName = DllStructCreate('wchar[' & StringLen($vol)+1 & ']')

; Remplissage de notre structure
DllStructSetData($lpRootPathName,1,$vol)

; Création de la structure qui accomodera le nom de volume
$lpVolumeNameBuffer = DllStructCreate('wchar[255]')
; Indication de la longueur du tampon qui recevra le nom de volume
$nVolumeNameSize = 255
; création de la structure qui recevra le Numéro de série
$lpVolumeSerialNumber = DllStructCreate('wchar[255]')
;Cr.ation de la structure qui recevra le "Max. component length"
$lpMacimumComponentLength = DllStructCreate('dword')
;Création de la structure qui recevra le drapeau de système de fichiers ( File System Flag )
$lpFileSystemFlags = DllStructCreate('dword')
; Création de la structure qui recevra le "FileSystemName"
$lpFileSystemNameBuffer = DllStructCreate('wchar[255]')
;Indication de la longueur du tampon (buffer) pour le FileSystemName
$nFileSystemNameSize = 255


DllCall('kernel32.dll','long','GetVolumeInformationW', _
'ptr' , DllStructGetPtr($lpRootPathName), _
'ptr' , DllStructGetPtr($lpVolumeNameBuffer), _
'long', $nVolumeNameSize, _
'ptr' , DllStructGetPtr($lpVolumeSerialNumber), _
'ptr' , DllStructGetPtr($lpMacimumComponentLength), _
'ptr' , DllStructGetPtr($lpFileSystemFlags), _
'ptr' , DllStructGetPtr($lpFileSystemNameBuffer), _
'long',$nFileSystemNameSize)


; After DllCall ascertaining the values addressed in the pointer over the structures are included.
;To access these values, they will be read with "DllstructGetData ()"

; Les valeurs de pointeurs du dllcall se retrouvent à l'intérieur des structures créées et
; peuvent être lues avec DLLStructGetData
ConsoleWrite("Volume name: " & DllStructGetData($lpVolumeNameBuffer,1) & @CRLF )
ConsoleWrite('Serial number: ' & DllStructGetData($lpVolumeSerialNumber,1) & @CRLF)
ConsoleWrite('Max. Component Length: ' & DllStructGetData($lpMacimumComponentLength,1) & @CRLF )
ConsoleWrite('File System: ' & DllStructGetData($lpFileSystemNameBuffer,1) & @CRLF )
ConsoleWrite('File System Flags: ' & _checkFsflags(DllStructGetData($lpFileSystemFlags,1) & @CRLF ))

; Fonction auxilière pour examiner le dernier drapeau
Func _checkFsflags($flagssum)
    Local Const _
    $FS_CASE_IS_PRESERVED = 0x2, _
    $FS_CASE_SENSITIVE = 0x1, _
    $FS_UNICODE_STORED_ON_DISK = 0x4, _
    $FS_PERSISTENT_ACLS = 0x8, _
    $FS_FILE_COMPRESSION = 0x10, _
    $FS_VOL_IS_COMPRESSED = 0x8000
    Local $sFlags = @CRLF

    If BitAND($flagssum,$FS_CASE_IS_PRESERVED) Then $sFlags &= @TAB & 'FS_CASE_IS_PRESERVED' & @CRLF
    If BitAND($flagssum,$FS_CASE_SENSITIVE) Then $sFlags &= @TAB & 'FS_CASE_SENSITIVE' & @CRLF
    If BitAND($flagssum,$FS_UNICODE_STORED_ON_DISK) Then $sFlags &= @TAB & 'FS_UNICODE_STORED_ON_DISK' & @CRLF
    If BitAND($flagssum,$FS_PERSISTENT_ACLS) Then $sFlags &= @TAB & 'FS_PERSISTENT_ACLS' & @CRLF
    If BitAND($flagssum,$FS_FILE_COMPRESSION) Then $sFlags &= @TAB & 'FS_FILE_COMPRESSION' & @CRLF
    If BitAND($flagssum,$FS_VOL_IS_COMPRESSED) Then $sFlags &= @TAB & 'FS_VOL_IS_COMPRESSED' & @CRLF
    Return $sFlags
EndFunc

Lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

J'ai traduis ces 2 exemples trouvés sur autoit.de.

[SagePourpre]

Qu'est-ce que j'ai pour vous aujourd'hui ?
*pige 1 bout de papier dans son chapeau de dllcall*


Appui sur une touche

Code : Tout sélectionner

DllCall ("user32.dll","int","keybd_event","int",0x20,"int",0,"long",0,"long",0)

► Afficher le texte

L'utilité, me direz-vous puisque send peut faire presque...

Voilà ... Avec cette fonction, vous pourrez simuler l'appui sur des touches non supportées par send ou
encore faire des combos de touches non-réalisables par send ( comme appuyer sur "gauche" et "espace"
en même temps. ).

Exemple :

Code : Tout sélectionner

Const $VK_SPACE = 0x20
Const $VK_LEFT = 0x25
Const $KEYEVENTF_KEYUP = 2

DllCall ("user32.dll","int","keybd_event","int",0x20,"int",0,"long",0,"long",0)   ;Appui sur espace
DllCall ("user32.dll","int","keybd_event","int",0x25,"int",0,"long",0,"long",0)   ;Appui sur "Left"

 
DllCall ("user32.dll","int","keybd_event","int",0x20,"int",0,"long",$KEYEVENTF_KEYUP,"long",0)   ;Relâche espace
DllCall ("user32.dll","int","keybd_event","int",0x25,"int",0,"long",$KEYEVENTF_KEYUP,"long",0)   ;Relâche "Left"

Lien MSDN : http://msdn.microsoft.com/en-us/library ... 85%29.aspx
Liens vers les virtual keys tel que vu dans le lien précédent : http://msdn.microsoft.com/en-us/library ... 85%29.aspx

[SagePourpre]

Astuce du jour : Si vous êtes avide d'étudier plus de DllCall, les #include d'autoit
sont une bonne manière de voir les dllcall en action. (exemple : GdiPlus.au3)


Un très bon #include à ajouter dans votre librairie et qui de plus regorge de dllcall
de toutes sortes ...

WinAPIEx UDF
http://www.autoitscript.com/forum/index ... opic=98712

[timmalos]

Tuto tres utile, bravo

[Tlem]

Pour WinAPIEx, j'ai prévu de le rajouter dans le prochain Pack AutoIt-Fr.
UDF, api, properties, exemples et fichier d'aide, cet add-on est vraiment très complet.

Il faut juste que je regarde comment je pourrait le rajouter dans l'aide principale de AutoIt.

[GMib]

Il me semble que les sources de l'aide son disponible.
http://www.autoitscript.com/autoit3/fil ... .0-src.exe

[Tlem]

Certes, mais cela ne suffit pas. Il faut aussi des UDF non présents et le HTML Help Author de Microsoft.

Mais j'avais déjà tout cà.
J'ai donc terminé de re-créer le fichier AutoIt.chm pour prendre en compte WinAPIEx.chm.

Par contre, le fichier AutoIt.chm contient deux pages HTML dont une qui présente la dernière version de AutoIt. Donc le fichier AutoIt.chm contient le numéro de la version en cours de AutoIt.

[SagePourpre]

Tuto tres utile, bravo

Merci ! ...

J'aurais aimé pouvoir mettre plus de théorie pour accompagner ces quelques exemples
mais l'information sur le sujet est peu abondante.

[Tlem]

Pour ceux ou celles qui n'ont pas envie d'attendre la prochaine version du Pack AutoIt-FR mais qui souhaiteraient obtenir la version WinAPIEx avec la modification du fichier d'aide AutoIt.chm afin de prendre en compte WinAPIEx.chm, vous pouvez télécharger une archive autoextractible qui réalise l'installation complète ici : http://www.autoitscript.fr/download/ind ... Ex_2.4.exe

*** N'oubliez pas que la page principale AutoIt.chm affichera les infos de la version 3.3.6.0 de AutoIt.

[Tlem]

Mise à jour du message précédent pour WinAPIEx_2.4.