#cs ===================================================================================================================
						GUI for	Network Connection Control (NCC) by Tlem
	
	There is a simple GUI to use NetConControl.au3 UDF.
	But if you want make it simple folow this :
	
	; Return the state of Network Connection (1 = active  0 = No Active)
	$Res = _NetCC("Connexion au réseau local", 4)
	
	; Return an array of Network Connections
	#include <array.au3>
	$aNicList = _NetCCGetList()
	_ArrayDisplay($aNicList,"")
	
	; Disable Local Area Connection and get return and error code :
	$Res = _NetCC('Local Area Connection', 0)
	MsgBox(0, "", "$Res=" & $Res & "  @Error=" & @error)
	
	Activate all connections :
	_NetCC('All', 1)
	
#ce ===================================================================================================================
#NoTrayIcon
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <NetCC.au3>

Dim $Res, $Mode
$MainGUI = GUICreate("NetCC", 280, 140, -1, -1)

$List = GUICtrlCreateCombo("", 10, 55, 255, 100)

GUISetFont(10, 800, 0, "System")
$Label1 = GUICtrlCreateLabel("Select Network Connection." & @CRLF & "Or type a part of the name.", 35, 10, 210, 35, $SS_CENTER)
$Off = GUICtrlCreateButton("OFF", 10, 90, 60, 25, 0)
GUICtrlSetColor(-1, 0xC00404)
$On = GUICtrlCreateButton("ON", 75, 90, 60, 25, 0)
GUICtrlSetColor(-1, 0x009800)
$Toggle = GUICtrlCreateButton("Toggle", 140, 90, 60, 25, 0)
GUICtrlSetColor(-1, 0xCA00CB)
$Repair = GUICtrlCreateButton("Repair", 205, 90, 60, 25, 0)
GUICtrlSetColor(-1, 0x0000FD)
$Label2 = GUICtrlCreateLabel("Network Connections Controls", 35, 120, 210, 35, $SS_CENTER)

$aNicList = _NetCCGetList()
GUICtrlSetData($List, "All Connection", "All Connection")
For $i = 1 To $aNicList[0]
	GUICtrlSetData($List, $aNicList[$i])
Next

GUISetState(@SW_SHOW)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit

		Case $Off
			$Res = _NicName($aNicList, $Mode)
			$Ret = _NetCC($Res, 0, $Mode)
			ConsoleWrite("OFF = Return = " & $Ret & " and Error = " & @error & @CRLF)

		Case $On
			$Res = _NicName($aNicList, $Mode)
			$Ret = _NetCC($Res, 1, $Mode)
			ConsoleWrite("ON = Return = " & $Ret & " and Error = " & @error & @CRLF)

		Case $Toggle
			$Res = _NicName($aNicList, $Mode)
			$Ret = _NetCC($Res, 2, $Mode)
			ConsoleWrite("Toggle = Return = " & $Ret & " and Error = " & @error & @CRLF)
			
		Case $Repair
			$Res = _NicName($aNicList, $Mode)
			$Ret = _NetCC($Res, 3, $Mode)
			ConsoleWrite("Repair = Return = " & $Ret & " and Error = " & @error & @CRLF)

	EndSwitch
WEnd

Func _NicName($aNicList, ByRef $Mode)
	$Res = StringLower(GUICtrlRead($List))
	
	; Case for all NIC
	If $Res = "all" Or $Res = "all connection" Then
		$Res = "All"
		$Mode = 1
		Return $Res
	EndIf
	
	; Case Full Name or partial name
	For $i = 1 To $aNicList[0]
		; Case Full Name
		If $Res = $aNicList[$i] Then
			$Mode = 1
			Return $Res
			; Case Partial Name
		ElseIf StringInStr($aNicList[$i], $Res) Then
			$Mode = 0
			Return $Res
		EndIf
	Next
	Return 0
EndFunc   ;==>_NicName