UDF > GDIPlus > Image >

_GDIPlus_ImageGetDimension

Obtient la largeur et la hauteur d'une image supportée par GDIPlus

#include <GDIPlus.au3>
_GDIPlus_ImageGetDimension ( $hImage )

Paramètre

$hImage  Le handle de l'objet image

Valeur de retour

Succès: Retourne un tableau à deux éléments:
    Array[0] = Largeur de l'objet image
    Array[1] = Hauteur de l'objet image
Échec: @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_ImageGetWidth, _GDIPlus_ImageGetHeight

Voir aussi

Consultez GdipGetImageDimension dans la librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aDim, $hImage, $sFile

    $sFile = FileOpenDialog("Please select an image", "", "Image (*.jpg;*.png;*.bmp;*.gif;*.tif)", BitOR($FD_PATHMUSTEXIST, $FD_FILEMUSTEXIST))
    If @error Then Exit MsgBox(BitOR($MB_TOPMOST, $MB_ICONERROR), "Error", "No image file has been selected", 30)

    _GDIPlus_Startup()

    $hImage = _GDIPlus_ImageLoadFromFile($sFile)
    If @error Or Not $hImage Then
        MsgBox(BitOR($MB_TOPMOST, $MB_ICONERROR), "Error", "This file isn't supported by GDIPlus!")
    Else
        $aDim = _GDIPlus_ImageGetDimension($hImage)
        MsgBox($MB_ICONINFORMATION, "Information", "Image dimension of " & @CRLF & $sFile & @CRLF & @CRLF & "Width = " & $aDim[0] & " pixel" & @CRLF & "Height = " & $aDim[1] & " pixel")
        _GDIPlus_ImageDispose($hImage)
    EndIf

    _GDIPlus_Shutdown()
EndFunc   ;==>Example