[R] Video Youtube et commandes play pause next prev

#1

Bonjour à tous ,
Je cherche un moyen de commander la lecture d'une vidéo Youtube dans IE!

Je la lit ainsi:

► Afficher le texte

Je voudrais savoir s'il exist un moyen de mettre la video en pause puis de la reprendre à volonté.

Merci de votre aide par avance !!!

#2

salut Pierrot
Il y a les combinaisons clavier, mais tu cherches certainement un truc un peu moins bancal...

#3

Merci de votre réponse qui pourrait me convenir !

#4

Les commandes suivantes fonctionnent trés bien en effet mais je dois cliquer sur la vidéo au préalable (pas seulement sur la page IE), hors j'ouvre IE en mode caché !

;Shortcut Actions
;Space Play / Pause
;Left Go back 5 Seconds
;Right Go forward 5 Seconds
;Up Increase Volume
;Down Decrease Volume
;F Fullscreen
;Esc Exit Fullscreen

#5

Pour cliquer sur la vidéo, ça va pas être évident...
Tu pourrais créer un IE embarqué dans une GUI, comme ça ce serait vraiment plus simple pour donner le focus à la vidéo.

Petit exemple :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>


_IEErrorHandlerRegister()


$embedCode = '<html><head><body><div style="position: absolute; top:0px; left:0px; align: center"><iframe width="400" height="300" src="http://www.youtube.com/embed/{videoID}" frameborder="0" allowfullscreen></iframe></div></body></head></html>'


$oIE = _IECreateEmbedded()
$gui = GUICreate("Youtube watcher", 440, 440)
$url = GUICtrlCreateInput("http://www.youtube.com/watch?v=7rvNmVuGf84", 10, 10, 390, 20)
$go =  GUICtrlCreateButton("->", 410, 10, 20, 20)

$ieID = GUICtrlCreateObj($oIE, 20, 40, 400, 300)

$play =    GUICtrlCreateButton(">> | ||", 10, 380, 120, 20)
GUICtrlSetTip(-1, "Play / Pause")

$restart = GUICtrlCreateButton("[<-", 140, 380, 50, 20)
GUICtrlSetTip(-1, "Jump to the beginning of a video")

$back5sec = GUICtrlCreateButton("<- 5s", 200, 380, 50, 20)
GUICtrlSetTip(-1, "Seek back 5 seconds")

$forward5sec = GUICtrlCreateButton("5s ->", 270, 380, 50, 20)
GUICtrlSetTip(-1, "Seek forward 5 seconds")

$mute = GUICtrlCreateButton("M", 10, 410, 50, 20)
GUICtrlSetTip(-1, "Mute")

$fullScreen = GUICtrlCreateButton("[ <-> ]", 70, 410, 50, 20)
GUICtrlSetTip(-1, "Fullscreen view (Press ESC to leave fullscreen mode)")


Local $commands[6][2] = [ [ $play, "{SPACE}" ] , _
[ $restart, "0" ] , _
[ $back5sec, "{LEFT}" ] , _
[ $forward5sec, "{RIGHT}" ] , _
[ $mute, "M" ] , _
[ $fullScreen, "F" ] ]

GUISetState()



While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then Exit
    If $msg = $go Then
        
        $videoID = GUICtrlRead($url)
        
        If StringRegExp($videoID, "\Ahttp://.*v=") Then $videoID = StringRegExpReplace($videoID, ".*v=(.*)", "$1")
        
        $f = FileOpen(@TempDir & "\youtubeEmbeded.html", 2)
        FileWrite($f, StringReplace($embedCode, "{videoID}", $videoID) )
        FileClose($f)
        _IENavigate ($oIE, "file://" & @TempDir & "\youtubeEmbeded.html")
        $oIE.document.body.scroll = "no"
        
    EndIf
    
    For $i = 0 To UBound($commands, 1) - 1
        If $msg = $commands[$i][0] Then
            ControlFocus($gui, "", "[CLASS:MacromediaFlashPlayerActiveX; INSTANCE:1]")
            ControlSend($gui, "", "[CLASS:MacromediaFlashPlayerActiveX; INSTANCE:1]", $commands[$i][1] )
        EndIf
    Next

WEnd

#6

Cela fonctionne trés bien mais pas dans mon cas puisque ma fenetre est cachée.

#7

Peut-être ça

Code : Tout sélectionner

#include <IE.au3>
$oIE = _IECreate ( "http://www.youtube.com/watch?v=xFrGuyw1V8s", 0, 0, 1 )
$_HwndIE = _IEPropertyGet ( $oIE, "hwnd" )

HotKeySet("p", "_Play")

while 1
    sleep(100)
WEnd

Func _Play()
    ControlSend($_HwndIE, "", "[CLASS:MacromediaFlashPlayerActiveX; INSTANCE:1]", "{SPACE}")
EndFunc

#8

J'avais adapté mon code avec la première méthode qui finalement fonctionnait, mais cette dernière version est plus proche de mon code et fonctionne tout aussi bien !

Merci beaucoup

#9

J'ai essayé la fonction FULLSCREEN mais évidemment , il me faut définir une GUI et utiliser la fonction '$IE = _IECreateEmbedded()'

mon code:

► Afficher le texte

J'ai bien la fonction FULLSCREEN mais mais intégrez à ma GUI !
Je voudrais pouvoir utiliser le fonction FULLSCREEN et retour à la normal sans redémarrage de la vidéo !

alex1205 · #10

Ou alors il y a la solution de passer Youtube en mode HTML5 pour que tu puisse exploiter les objets (et donc le bouton play/pause) :
http://www.youtube.com/html5?hl=fr Tu appuies sur Participer à l'essai HTML5 et normalement tu passe en HTML5.

Alex1205

#11

Désolé Pierrot, je n'ai pas compris le problème de Fullscreen...
Pourquoi y-aurait t-il besoin d'une GUI ?

#12

Pierrot dans tes 2 codes IE est en mode invisible, à quoi sert fullscreen ?

#13

jguinch,
Je voudrais pouvoir cantonner la vidéo plein écran à une partie de l'écran (800x600 seulement) mais pouvoir utiliser l'option 'resize' d'une GUI.

mikell,
He bien le but serait d'avoir un mode en plein écran avec visualisation de la video et non seulement écouter le son !
Une option quoi ,mais le mode audio seul restant le mode principal!

alex1205 · #14

Bonjour, pierrotm77, regarde mon message et peut etre que ca te résoudrait ton probleme.

Alex1205

#15

alex1205,
Merci de cette proposition, mais je voudrais rester proche de mon code et juste trouver un moyen d'avoir la video incluse dans une GUI (en option)

De plus , je suis toujours sous vista donc IE9.

AutoIt Français

[R] Video Youtube et commandes play pause next prev

[R] Video Youtube et commandes play pause next prev

Re: [..] Video Youtube et commandes play pausenext prev

Re: [..] Video Youtube et commandes play pausenext prev

Re: [..] Video Youtube et commandes play pausenext prev

Re: [..] Video Youtube et commandes play pause next prev

Re: [..] Video Youtube et commandes play pause next prev

Re: [..] Video Youtube et commandes play pause next prev

Re: [..] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev

Re: [R] Video Youtube et commandes play pause next prev