[..] Script de gestionnaire de téléchargement.

[ELGAMALI]

Bonjour tout le monde,

Je vous prie de m'aider ou de me donner des directives (exemple) pour confectionner un script de gestion de téléchargement qui doit permettre:
1- La reprise de téléchargements interrompus,
2- D’accélérer la vitesse de téléchargements sur Internet,
3- de mettre en pause et de planifier les téléchargements sur Internet.

Voici un exemple de script (comme base) sur le quel on peut ajouter les fonctions de gestionnaire de téléchargement.

► Afficher le texte

#NoTrayIcon
#include <WindowsConstants.au3>
#include <ProgressConstants.au3>
;=============================================
DirCreate(@ProgramFilesDir&"\NOM DU REERTOIRE DE DISTINATION")
;=======================================
ConnexionActive()

$ProgressForm = GUICreate("Veillez passionter, téléchargement en cours ..", 480, 20, -1, 20)
$ProgressBar = GUICtrlCreateProgress(0, 0, 488, 21, $PBS_SMOOTH)
GUISetState(@SW_SHOW, $ProgressForm)
$URL = 'http://XXX.com/NOM DE FICHIER A TELECHARGER'
;==========================================
$nstal= @ProgramFilesDir&"\NOM DU REERTOIRE DE DISTINATION\"
DownloadFile($URL) ;On lance le téléchargement
Exit

Func DownloadFile($FileUrl, $ToFolder = $nstal)
FileCreateShortcut(@ProgramFilesDir& "\NOM DE FICHIER A TELECHARGER", @DesktopDir & "\NOM DE FICHIER A TELECHARGER.lnk", @ProgramFilesDir);racourci
Local $ArchiveName = StringTrimLeft($FileUrl, StringInStr($FileUrl, '/', 0, -1)) ;On définit le nom du fichier cible
Local $hDownload = InetGet($FileUrl, $ToFolder & '\' & $ArchiveName, 1, 1) ;On lance le téléchargement
$aData = InetGetInfo($hDownload) ;On récupére la taille du fichier
While $aData[1] = 0
Sleep(100) ;Nb : normalement la boucle n'est pas obligatoire

$aData = InetGetInfo($hDownload) ; ayant des soucis de connexion j'ai du passer par cette boucle
WEnd

GUICtrlSetData($ProgressBar, 0) ;init de la barre de progression
While $aData[0] < $aData[1] ;On boucle tant que le téléchargement n'est pas finalisé
$aData = InetGetInfo($hDownload)
GUICtrlSetData($ProgressBar, $aData[0] / $aData[1] * 100) ;On gére l'avancement de la barre de progression
Sleep(1000) ;On temporise pour laisser du process au petits copains
;On temporise pour laisser du process au petits copains
;==========================
Global $nBytes

$nBytes = InetGetInfo($hDownload, 0)
If $nBytes =XXXX then ;TAILLE FICHIER A TELECHARGER
MsgBox(64, "Félicitations La sauvegarde de votre contenu s'est bien déroulée! ", "Un raccourci portant le nom de votre contenu va être installé sur votre bureau !")
; \________________/
INSTALL ()
EndIf
WEnd
EndFunc
;==========================
Func LanceMedia()
Global $Taille=XXXXX ;TAILLE FICHIER A TELECHARGER
; \____________/
if FileGetSize(@ProgramFilesDir&"\NOM DE FICHIER A TELECHARGER")=$Taille Then
ShellExecuteWait(@ProgramFilesDir&"\NOM DE FICHIER A TELECHARGER")
Exit
EndIf

EndFunc

;===========================================
; tester connection

While 1
sleep(15000)
ConnexionActive()
WEnd
func ConnexionActive()
$var = Ping("www.google.com")
If $var = 0 Then
Msgbox(48,"Problème de connexion.Ce programme va s'arrêter. ", "La connexion au réseau internent a échoué, soit que votre modem n’est pas installer, ou soit le niveau du signal du réseau est trop bas. Avant de reprendre à nouveau cette application, assurez vous que la connexion au réseau internent est bien rétablie.")
Exit

Else
;Msgbox(48,"Fatal Error", " connexion internet active, 10 ")
EndIf
EndFunc

;=================================
Func INSTALL ()
LanceMedia()
EndFunc
;====================================

[blacksoul305]

Bonjour,

accélérer la vitesse de téléchargement ? Je doute que ce soit possible car je pense que ça vient pas du programme qui télécharge mais plutôt la capacité de ton modem et autres périphériques réseaux. Le seul remède que je vois c'est limité ou arrêter les processus susceptibles de manger de la connexion comme Youtube ou des jeux en ligne.

EDIT : Ton code dans une balise spoiler peut être

[ELGAMALI]

Bonjour
Ta raison blacksoul305.
J’ai trouvé une fonction magnifique de Matwachich qui répond à ma demande mais il lui manque la barre de progression + %. Le problème ce n’est pas le script de la barre de progression mais plutôt où le placer dans la dite fonction ?
Merci pour votre aide.
voir fonction de Matwachich ici:

► Afficher le texte

#cs ----------------------------------------------------------------------------

AutoIt Version: 3.3.6.1
Author: Matwachich

Script Function:
Inspired from HTTP.au3 by Greg "Overload" Laabs

#ce ----------------------------------------------------------------------------
#include-once

#Region - ### Example ###
Global $old = 0

$url = _Url_To_Host("http://files2.freedownloadmanager.org/l ... e-lngs.exe")
For $i In $url
ConsoleWrite($i & @CRLF)
Next

Do
$ret = _InetGetX($url[0], $url[1], @DesktopDir & "\fdminst-lite-lngs.exe", -1, 0, "_callBack")
ConsoleWrite($ret & " - " & @error & " - " & @extended & @CRLF)
Until $ret = 1 And not @error

Func _callBack($i, $total)
Local $p = Round(($i/$total)*100)
If $old <> $p Then ConsoleWrite("- " & $p & " %" & @CRLF)
$old = $p
EndFunc
#EndRegion ###


; # FUNCTION # ================================================================================================
; Name...........: _InetGetX
; Description....: Téléchager un fichier, fonction reprendre prise en charge
;
; Parameters.....: - $sHost = Le server (ex: "www.site.fr", "http://mon_site.hebergeur.com/")
; - $sRessource = Le fichier à télécharger (ex: "/dossier/fichier.exe", "dossier/fichier.txt")
; - $sFile = Le chemin du fichier local (destination)
; - $iStartByte = Le position (en octet) d'ou commencer/reprendre le téléchargement
; (DEFAULT: 0 = Depuis le début)
; Si = -1, le téléchargement reprend depuis la taille du fichier en local
; - $bForce = Forcer le téléchargement même si la taille du fichier ne peut être récupérer
; (DEFAULT: 0)
; (Si = 1, Aucune vérification ne sera faite à la fin du téléchargement)
; Voir Return values
; - $sCallBack = Fonction call-back de forme:
; Func _callBack($iDownloaded, $iTotalSize)
; (DEFAULT: "" => Aucun call-back)
; - $iTimeOut = Time-out (en secondes) PS: temps maximum sans recevoir de données du serveur
; (DEFAULT: 5)
; - $sAgent = User-Agent (Header HTTP)
; (DEFAULT: "AutoItMacro")
;
; Return values..: - $bForce = 0
; - Ret = 0, @error = 1 => Echec inetgetsize
; - Ret = 1, @error = 2 => taille fichier local = Taille fichier distant (@extended = Taille)
; - Ret = 1, @error = 0 => Succes, @extended = Total télécharge (octets)
; (PS: Ici, @extended = FileGetSize("Fichier télécharger"))
; - Ret = 0, @error = 7 => Echec, @extended = Total télécharge (octets)
; - $bForce = 1
; - Ret = -1, @error = 0 => La fonction s'est bien terminé, mais impossible de vérifier le téléchargement
;
; - Ret = 0:
; - @error = -x => Vérifiez le paramètre N° x
; - @error = 3 => Impossible de se connecter
; - @error = 4 => Impossible d'envoyer la requête HTTP
; - @error = 5 => Timed-out (@extended = Total télécharger (octets))
; - @error = 6 => Impossible d'ouvrir le fichier destination
;
; Author.........: Matwachich, Inspired from HTTP.au3 by Greg "Overload" Laabs
; Remarks........: - La fonction reprend très bien un téléchargement (sans corruption du fichier) si on a
; killer le processus AutoIt.exe, aussi bien que si il y a un problème de connection
; - La meilleur méthode est de lancer cette fonction avec $iStartByte = -1, comme cela,
; Elle récupère la taille du fichier destination et continue automatiquement à
; partire de cette taille.
; Exemple:
; Voir entête de l'UDF
; ===========================================================================================================
Func _InetGetX($sHost, $sRessource, $sFile, $iStartByte = 0, $bForce = 0, $sCallBack = "", $iTimeOut = 5, $sAgent = "AutoItMacro")
; Checking parameters
If String($sHost) <> $sHost Or $sHost = "" Then Return SetError(-1, 0, 0)
If String($sRessource) <> $sRessource Or $sRessource = "" Then Return SetError(-2, 0, 0)
If String($sFile) <> $sFile Or $sFile = "" Then Return SetError(-3, 0, 0)
If Number($iStartByte) <> $iStartByte Then Return SetError(-4, 0, 0)
If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0)
If String($sCallBack) <> $sCallBack Then Return SetError(-6, 0, 0)
If Number($iTimeOut) <> $iTimeOut Or $iTimeOut = 0 Then Return SetError(-7, 0, 0)
If String($sAgent) <> $sAgent Or $sAgent = "" Then Return SetError(-8, 0, 0)
$iTimeOut = $iTimeOut * 1000

If StringRight($sHost, 1) = "/" Then $sHost = StringTrimRight($sHost, 1)
If StringLeft($sHost, 7) = "http://" Then $sHost = StringTrimLeft($sHost, 7)
If StringLeft($sRessource, 1) <> "/" Then $sRessource = "/" & $sRessource

Local $iFileSize = FileGetSize($sFile)
If $iStartByte < 0 Then $iStartByte = $iFileSize

; Getting ressource size
Local $iSize = 0x10 ; just random value
If Not $bForce Then
$iSize = InetGetSize("http://" & $sHost & "/" & $sRessource, 1)
ConsoleWrite($iSize & @CRLF)
If @error Then Return SetError(1, @error, 0)
; If Local FileSize = Remote FileSize Then cancel download
If $iSize = $iFileSize Then Return SetError(2, $iFileSize, 1)
EndIf

; Connecting to Server
TCPStartup()
Local $ip = TCPNameToIP($sHost)
Local $socket = TCPConnect($ip, 80)
If $socket <= 0 Then Return SetError(3, @error, 0) ; Could not connect XXX

; Creating command string
Local $command = "GET " & $sRessource & " HTTP/1.1" & @CRLF
$command &= "Host: " & $sHost & @CRLF
$command &= "User-Agent: " & $sAgent & @CRLF
If $iStartByte > 0 Then $command &= "Range: bytes=" & $iStartByte & "-" & @CRLF
$command &= "Connection: close" & @CRLF & @CRLF
ConsoleWrite($command & @CRLF)

; Sending command string
Local $bytessent = TCPSend($socket, $command)
If $bytessent = 0 Then
;FileClose($hFile)
;FileDelete($sFile)
TCPCloseSocket($socket)
TCPShutdown()
Return SetError(4, @error, 0) ; Could not send request XXX
EndIf

; Receiving and writing
Local $hFile, $openFlag = 1, $bBinary = 0, $bStripLastCRLF = 0
Local $recv, $crlfPos, $split, $writing = 0, $iFirst = 1
Local $timer = TimerInit()
; Pour ne pas fausser la fonction call-back si c'est une reprise de téléchargement
Local $iTotalDwn = $iStartByte

While 1
$recv = TCPRecv($socket, 4096) ; On recoit un paquet de données
If @error Then ExitLoop ; $socket n'est plus valide (déconnecté)
If Not $recv Then ; Pas de données
; Test time-out
If TimerDiff($timer) >= $iTimeOut Then
FileClose($hFile)
TCPCloseSocket($socket)
TCPShutdown()
Return SetError(5, $iTotalDwn, 0) ; Timed out XXX
EndIf
ContinueLoop ; => continuer la boucle
EndIf

$timer = TimerInit() ; Si des données sont reçues, on réinitialise le timer

; Si on recoit des données binaires, on les convertie en String
If IsBinary($recv) Then
$recv = BinaryToString($recv)
; Si c'est le premier paquet de données, on règle le flag d'ouverture du fichier
; et on met $bBinary à 1
If $iFirst Then
$openFlag = 17
$bBinary = 1
EndIf
EndIf

; Si c'est le premier paquet de données, on ouvre le fichier et on met $iFirst à 0
If $iFirst Then
$hFile = FileOpen($sFile, $openFlag)
If $hFile = -1 Then Return SetError(6, @error, 0) ; File creation failed XXX
FileSetAttrib($sFile, "+H")
$iFirst = 0
EndIf

; Si on est pas en train d'ecrire (CaD, on est au premier paquet), On passe les headers de la réponse HTTP:
If Not $writing Then
$split = StringSplit($recv, @CRLF, 1)
If StringInStr($recv, 2) <> @CRLF Then $bStripLastCRLF = 1 ; Because the loop (*) inserts a @CRLF
; at the end of reconstructed $recv string
$recv = ""
For $i = 1 To $split[0]
If $split[$i] = "" And Not $writing Then
$writing = 1
ContinueLoop
EndIf
If $writing Then
$recv &= $split[$i] & @CRLF ; Loop (*)
EndIf
Next
If $bStripLastCRLF Then $recv = StringTrimRight($recv, 2) ; Trims the last @CRLF inserted by the loop (*)
EndIf

; Ici, on ecrit les données dans le fichier
If $writing Then
If $bBinary Then
$recv = Binary($recv)
$iTotalDwn += BinaryLen($recv)
Else
$iTotalDwn += StringLen($recv)
EndIf
FileWrite($hFile, $recv)
; Appel de la fonction call-back
If $sCallBack <> "" Then Call($sCallBack, $iTotalDwn, $iSize)
EndIf
Wend
FileClose($hFile)
FilesetAttrib($sFile, "-H")

; Verifications
$iFileSize = FileGetSize($sFile)
If Not $bForce Then
If $iFileSize = $iSize Then
Return SetError(0, $iTotalDwn, 1)
Else
return setError(7, $iTotalDwn, 0) ; Download failed XXX
EndIf
Else ; If $bForce Then we don't check file size
Return SetError(0, $iTotalDwn, -1)
EndIf

EndFunc

; ##############################################################
; Permet de convertit un URL en $sHost et $sRessource utilisables par
; _InetGetX
; $ret[0] = $sHost
; $ret[1] = $sRessource
Func _Url_To_Host($url)
Local $ret[2]
$url = StringReplace($url, 'http://', '')
$ret[0] = StringLeft($url, StringInStr($url, '/') - 1)
$ret[1] = StringTrimLeft($url, StringInStr($url, '/'))
Return $ret
EndFunc

[blacksoul305]

J'vais avoir du mal à travailler sur le code avec le temps que j'ai, voici quelques informations dont tu auras besoin :

La taille totale du fichier : $fileSize
La taille du fichier téléchargé : $fileSizeDL

On fait donc :

Code : Tout sélectionner

$value = Round($fileSize/100,1) ; on calcule la valeur d'un pourcent de la taille du fichier
$percent = Round($fileSizeDL/$value)
GUICtrlSetData($Progress1,$percent & "% / 100%")

Si tu retrouves ces informations, tu appliques ce calcul et tu devrais y arriver. Après, où exactement je sais pas du tout. Il me faudrait un peu de temps.

[ELGAMALI]

Bonjour tout le monde
J'ai trouvé une solution mais très aléatoire.
Je pense que c'est impossible d’ajouter au script de Matwachich une barre de progression + %. J’ai passé des heures et des heures pour intégrer les solutions que j’ai trouvé sur ce forum mais sans résultat!?
Avez-vous une aidée à ce sujet merci?

[mikell]

T'as passé des heures !? tu te fous de qui ? ça prend 2 minutes !

Code : Tout sélectionner

Func _callBack($i, $total)
    Local [b]$p = Round(($i/$total)*100)[/b]
    If $old <> $p Then [b]ConsoleWrite("- " & $p & " %" & @CRLF)[/b]
    $old = $p
EndFunc

Un simple test montre que la variable $p te renvoie dans le ConsoleWrite le pourcentage de fichier téléchargé, donc rien de plus facile que d'afficher ça dans une progressbar
Je mets le script parce que je suis pas méchant, mais ya des coups de pied au Q qui se perdent

► Afficher le texte

Code : Tout sélectionner

#include <ProgressConstants.au3>

Global $old = 0, $progressbar
$url = _Url_To_Host("http://files2.freedownloadmanager.org/lite/fdminst-lite-lngs.exe")
;For $i In $url
;   ConsoleWrite($i & @CRLF)
;Next

GUICreate("My GUI Progressbar", 260, 80, -1, 200)
$progressbar = GUICtrlCreateProgress(10, 20, 200, 20, $PBS_SMOOTH)
$label = GuiCtrlCreateLabel("", 220, 23, 15, 20, 2)
GuiCtrlCreateLabel("%", 240, 23, 10, 20)
$button = GUICtrlCreateButton("Start", 75, 50, 60, 20)
GUISetState()

While 1
$msg = GUIGetMsg()
   If $msg = -3 Then Exit
   If $msg = $button Then
    Do
        $ret = _InetGetX($url[0], $url[1], @DesktopDir & "\fdminst-lite-lngs.exe", -1, 0, "_callBack")
        ConsoleWrite($ret & " - " & @error & " - " & @extended & @CRLF)
    Until $ret = 1 And not @error
    Msgbox(0,"", "Terminé !")
    Exit
   EndIf
Wend

;===================================

Func _callBack($i, $total)
    Local $p = Round(($i/$total)*100)
    If $old <> $p Then 
        GUICtrlSetData($progressbar, $p)   ; ConsoleWrite("- " & $p & " %" & @CRLF)
        GUICtrlSetData($label, $p) 
    EndIf
    $old = $p
EndFunc


; # FUNCTION # ================================================================================================
; Name...........:  _InetGetX
; Description....:  Téléchager un fichier, fonction reprendre prise en charge
;
; Parameters.....:  - $sHost = Le server (ex: "www.site.fr", "http://mon_site.hebergeur.com/")
;                   - $sRessource = Le fichier à télécharger (ex: "/dossier/fichier.exe", "dossier/fichier.txt")
;                   - $sFile = Le chemin du fichier local (destination)
;                   - $iStartByte = Le position (en octet) d'ou commencer/reprendre le téléchargement 
;                       (DEFAULT: 0 = Depuis le début)
;                       Si = -1, le téléchargement reprend depuis la taille du fichier en local
;                   - $bForce = Forcer le téléchargement même si la taille du fichier ne peut être récupérer
;                       (DEFAULT: 0)
;                       (Si = 1, Aucune vérification ne sera faite à la fin du téléchargement)
;                       Voir Return values
;                   - $sCallBack = Fonction call-back de forme:
;                       Func _callBack($iDownloaded, $iTotalSize)
;                       (DEFAULT: "" => Aucun call-back)
;                   - $iTimeOut = Time-out (en secondes) PS: temps maximum sans recevoir de données du serveur
;                       (DEFAULT: 5)
;                   - $sAgent = User-Agent (Header HTTP)
;                       (DEFAULT: "AutoItMacro")
;
; Return values..:  - $bForce = 0
;                       - Ret = 0, @error = 1 => Echec inetgetsize
;                       - Ret = 1, @error = 2 => taille fichier local = Taille fichier distant (@extended = Taille)
;                       - Ret = 1, @error = 0 => Succes, @extended = Total télécharge (octets)
;                           (PS: Ici, @extended = FileGetSize("Fichier télécharger"))
;                       - Ret = 0, @error = 7 => Echec, @extended = Total télécharge (octets)
;                   - $bForce = 1
;                       - Ret = -1, @error = 0 => La fonction s'est bien terminé, mais impossible de vérifier le téléchargement
;
;                   - Ret = 0:
;                       - @error = -x => Vérifiez le paramètre N° x
;                       - @error = 3 => Impossible de se connecter
;                       - @error = 4 => Impossible d'envoyer la requête HTTP
;                       - @error = 5 => Timed-out (@extended = Total télécharger (octets))
;                       - @error = 6 => Impossible d'ouvrir le fichier destination
;
; Author.........:  Matwachich, Inspired from HTTP.au3 by Greg "Overload" Laabs
; Remarks........:  - La fonction reprend très bien un téléchargement (sans corruption du fichier) si on a
;                       killer le processus AutoIt.exe, aussi bien que si il y a un problème de connection
;                   - La meilleur méthode est de lancer cette fonction avec $iStartByte = -1, comme cela,
;                       Elle récupère la taille du fichier destination et continue automatiquement à 
;                       partire de cette taille.
;   Exemple:
;       Voir entête de l'UDF
; ===========================================================================================================
Func _InetGetX($sHost, $sRessource, $sFile, $iStartByte = 0, $bForce = 0, $sCallBack = "", $iTimeOut = 5, $sAgent = "AutoItMacro")
    ; Checking parameters
    If String($sHost) <> $sHost Or $sHost = "" Then Return SetError(-1, 0, 0)
    If String($sRessource) <> $sRessource Or $sRessource = "" Then Return SetError(-2, 0, 0)
    If String($sFile) <> $sFile Or $sFile = "" Then Return SetError(-3, 0, 0)
    If Number($iStartByte) <> $iStartByte Then Return SetError(-4, 0, 0)
    If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0)
    If String($sCallBack) <> $sCallBack Then Return SetError(-6, 0, 0)
    If Number($iTimeOut) <> $iTimeOut Or $iTimeOut = 0 Then Return SetError(-7, 0, 0)
    If String($sAgent) <> $sAgent Or $sAgent = "" Then Return SetError(-8, 0, 0)
    $iTimeOut = $iTimeOut * 1000

    If StringRight($sHost, 1) = "/" Then $sHost = StringTrimRight($sHost, 1)
    If StringLeft($sHost, 7) = "http://" Then $sHost = StringTrimLeft($sHost, 7)
    If StringLeft($sRessource, 1) <> "/" Then $sRessource = "/" & $sRessource
    
    Local $iFileSize = FileGetSize($sFile)
    If $iStartByte < 0 Then $iStartByte = $iFileSize
    
    ; Getting ressource size
    Local $iSize = 0x10 ; just random value
    If Not $bForce Then
        $iSize = InetGetSize("http://" & $sHost & "/" & $sRessource, 1)
        ConsoleWrite($iSize & @CRLF)
        If @error Then Return SetError(1, @error, 0)
        ; If Local FileSize = Remote FileSize Then cancel download
        If $iSize = $iFileSize Then Return SetError(2, $iFileSize, 1)
    EndIf
    
    ; Connecting to Server
    TCPStartup()
    Local $ip = TCPNameToIP($sHost)
    Local $socket = TCPConnect($ip, 80)
    If $socket <= 0 Then Return SetError(3, @error, 0) ; Could not connect XXX
    
    ; Creating command string
    Local $command = "GET " & $sRessource & " HTTP/1.1" & @CRLF
    $command &= "Host: " & $sHost & @CRLF
    $command &= "User-Agent: " & $sAgent & @CRLF
    If $iStartByte > 0 Then $command &= "Range: bytes=" & $iStartByte & "-" & @CRLF
    $command &= "Connection: close" & @CRLF & @CRLF
    ConsoleWrite($command & @CRLF)
    
    ; Sending command string
    Local $bytessent = TCPSend($socket, $command)
    If $bytessent = 0 Then
        ;FileClose($hFile)
        ;FileDelete($sFile)
        TCPCloseSocket($socket)
        TCPShutdown()
        Return SetError(4, @error, 0) ; Could not send request XXX
    EndIf
    
    ; Receiving and writing
    Local $hFile, $openFlag = 1, $bBinary = 0, $bStripLastCRLF = 0
    Local $recv, $crlfPos, $split, $writing = 0, $iFirst = 1
    Local $timer = TimerInit()
    ; Pour ne pas fausser la fonction call-back si c'est une reprise de téléchargement
    Local $iTotalDwn = $iStartByte
    
    While 1
        $recv = TCPRecv($socket, 4096) ; On recoit un paquet de données
        If @error Then ExitLoop ; $socket n'est plus valide (déconnecté)
        If Not $recv Then ; Pas de données
            ; Test time-out
            If TimerDiff($timer) >= $iTimeOut Then
                FileClose($hFile)
                TCPCloseSocket($socket)
                TCPShutdown()
                Return SetError(5, $iTotalDwn, 0) ; Timed out XXX
            EndIf
            ContinueLoop ; => continuer la boucle
        EndIf
        
        $timer = TimerInit() ; Si des données sont reçues, on réinitialise le timer
        
        ; Si on recoit des données binaires, on les convertie en String
        If IsBinary($recv) Then
            $recv = BinaryToString($recv)
            ; Si c'est le premier paquet de données, on règle le flag d'ouverture du fichier
            ; et on met $bBinary à 1
            If $iFirst Then
                $openFlag = 17
                $bBinary = 1
            EndIf
        EndIf
        
        ; Si c'est le premier paquet de données, on ouvre le fichier et on met $iFirst à 0
        If $iFirst Then
            $hFile = FileOpen($sFile, $openFlag)
            If $hFile = -1 Then Return SetError(6, @error, 0) ; File creation failed XXX
            FileSetAttrib($sFile, "+H")
            $iFirst = 0
        EndIf
        
        ; Si on est pas en train d'ecrire (CaD, on est au premier paquet), On passe les headers de la réponse HTTP:
        If Not $writing Then
            $split = StringSplit($recv, @CRLF, 1)
            If StringInStr($recv, 2) <> @CRLF Then $bStripLastCRLF = 1 ; Because the loop (*) inserts a @CRLF
                                                                       ; at the end of reconstructed $recv string
            $recv = ""
            For $i = 1 To $split[0]
                If $split[$i] = "" And Not $writing Then 
                    $writing = 1
                    ContinueLoop
                EndIf
                If $writing Then
                    $recv &= $split[$i] & @CRLF ; Loop (*)
                EndIf   
            Next
            If $bStripLastCRLF Then $recv = StringTrimRight($recv, 2) ; Trims the last @CRLF inserted by the loop (*)
        EndIf
        
        ; Ici, on ecrit les données dans le fichier
        If $writing Then
            If $bBinary Then 
                $recv = Binary($recv)
                $iTotalDwn += BinaryLen($recv)
            Else
                $iTotalDwn += StringLen($recv)
            EndIf
            FileWrite($hFile, $recv)
            ; Appel de la fonction call-back
            If $sCallBack <> "" Then Call($sCallBack, $iTotalDwn, $iSize)
        EndIf
    Wend
    FileClose($hFile)
    FilesetAttrib($sFile, "-H")
    
    ; Verifications
    $iFileSize = FileGetSize($sFile)
    If Not $bForce Then
        If $iFileSize = $iSize Then
            Return SetError(0, $iTotalDwn, 1)
        Else
            return setError(7, $iTotalDwn, 0) ; Download failed XXX
        EndIf
    Else ; If $bForce Then we don't check file size
        Return SetError(0, $iTotalDwn, -1)
    EndIf

EndFunc

; ##############################################################
; Permet de convertit un URL en $sHost et $sRessource utilisables par
; _InetGetX
; $ret[0] = $sHost
; $ret[1] = $sRessource
Func _Url_To_Host($url)
    Local $ret[2]
    $url = StringReplace($url, 'http://', '')
    $ret[0] = StringLeft($url, StringInStr($url, '/') - 1)
    $ret[1] = StringTrimLeft($url, StringInStr($url, '/'))
    Return $ret
EndFunc
 

EDIT : Ton code dans une balise spoiler peut être

Tes codes dans une balise spoiler et une balise code

[ELGAMALI]

Cher mikell
Le problème il n’est pas là.. la solution, est d’ajouter ta fonction au script de Matwachich ci-dessus

► Afficher le texte

Func _callBack($i, $total)
Local $p = Round(($i/$total)*100)
If $old <> $p Then ConsoleWrite("- " & $p & " %" & @CRLF)
$old = $p
EndFunc

[mikell]

J'ai édité....

[ELGAMALI]

La solution la plus simple est toujours la meilleure?????????????????????
Si ça peut vous aider, ci-joint la barre de progression que j’ai ajouté au script de Matwachich sans % en cours de téléchargement.

► Afficher le texte

#NoTrayIcon

#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Process.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
$list = ProcessList()

#include-once
DirCreate(@ProgramFilesDir&"\xxxxxxxxxx"); creer un dossier de destination
;=================================
ConnexionActive()
;====================================================
$url = _Url_To_Host("xxxx.com/nom de fichier à telecharger.exe")

For $i In $url
ConsoleWrite($i & @CRLF)
Next
Do
$ret = _InetGetX( $url[0], $url[1], @ProgramFilesDir& "\repertire de destination\nom de fichier à telecharger.exe", -1, 0, "_callBack")
ConsoleWrite($ret & " - " & @error & " - " & @extended & @CRLF)
Until $ret = 1 And not @error
Func _callBack($i, $total)

Local $p = Round(($i/$total)*100)
Global $old
If $old <> $p Then ConsoleWrite("- " & $p & " %" & @CRLF)
$old = $p

EndFunc
#EndRegion ###
;================================

Func _InetGetX($sHost, $sRessource, $sFile, $iStartByte = 0, $bForce = 0, $sCallBack = "", $iTimeOut = 5, $sAgent = "AutoItMacro")

; Checking parameters
If String($sHost) <> $sHost Or $sHost = "" Then Return SetError(-1, 0, 0)
If String($sRessource) <> $sRessource Or $sRessource = "" Then Return SetError(-2, 0, 0)
If String($sFile) <> $sFile Or $sFile = "" Then Return SetError(-3, 0, 0)
If Number($iStartByte) <> $iStartByte Then Return SetError(-4, 0, 0)
If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0)
If String($sCallBack) <> $sCallBack Then Return SetError(-6, 0, 0)
If Number($iTimeOut) <> $iTimeOut Or $iTimeOut = 0 Then Return SetError(-7, 0, 0)
If String($sAgent) <> $sAgent Or $sAgent = "" Then Return SetError(-8, 0, 0)

$iTimeOut = $iTimeOut * 1000

If StringRight($sHost, 1) = "/" Then $sHost = StringTrimRight($sHost, 1)

If StringLeft($sHost, 7) = "http://" Then $sHost = StringTrimLeft($sHost, 7)

If StringLeft($sRessource, 1) <> "/" Then $sRessource = "/" & $sRessource

Local $iFileSize = FileGetSize($sFile)

If $iStartByte < 0 Then $iStartByte = $iFileSize

; Getting ressource size
Local $iSize = 0x10 ; just random value

If Not $bForce Then

$iSize = InetGetSize("http://" & $sHost & "/" & $sRessource, 1)

ConsoleWrite($iSize & @CRLF) ; 1 declaration de la taille du fichier à telecharger = $iSize


If @error Then Return SetError(1, @error, 0)
; If Local FileSize = Remote FileSize Then cancel download
;MsgBox(64, "Félicitations11" , "")
If $iSize = $iFileSize Then Return SetError(2, $iFileSize, 1)
EndIf

; Connecting to Server
TCPStartup()
Local $ip = TCPNameToIP($sHost)
Local $socket = TCPConnect($ip, 80)
If $socket <= 0 Then Return SetError(3, @error, 0) ; Could not connect XXX
;wwwwwwwwwwwwwwwwwwwwwwww
;emplacement pour lancer BarreDeProgression


ProgressionTimer(); emplecement de ProgressionTimer

;wwwwwwwwwwwwwwwwwwwwwwwww
; Creating command string
Local $command = "GET " & $sRessource & " HTTP/1.1" & @CRLF
$command &= "Host: " & $sHost & @CRLF
$command &= "User-Agent: " & $sAgent & @CRLF
If $iStartByte > 0 Then $command &= "Range: bytes=" & $iStartByte & "-" & @CRLF
$command &= "Connection: close" & @CRLF & @CRLF
ConsoleWrite($command & @CRLF)

; Sending command string
Local $bytessent = TCPSend($socket, $command)
If $bytessent = 0 Then
;FileClose($hFile)
;FileDelete($sFile)
TCPCloseSocket($socket)
TCPShutdown()
Return SetError(4, @error, 0) ; Could not send request XXX

EndIf

; Receiving and writing
Local $hFile, $openFlag = 1, $bBinary = 0, $bStripLastCRLF = 0
Local $recv, $crlfPos, $split, $writing = 0, $iFirst = 1
Local $timer = TimerInit()
; Pour ne pas fausser la fonction call-back si c'est une reprise de téléchargement
Local $iTotalDwn = $iStartByte

While 1
$recv = TCPRecv($socket, 4096) ; On recoit un paquet de données
If @error Then ExitLoop ; $socket n'est plus valide (déconnecté)
If Not $recv Then ; Pas de données
; Test time-out

If TimerDiff($timer) >= $iTimeOut Then
FileClose($hFile)
TCPCloseSocket($socket)
TCPShutdown()
Return SetError(5, $iTotalDwn, 0) ; Timed out XXX

EndIf
ContinueLoop ; => continuer la boucle % % % % % %
EndIf

$timer = TimerInit() ; Si des données sont reçues, on réinitialise le timer

; Si on recoit des données binaires, on les convertie en String
If IsBinary($recv) Then
$recv = BinaryToString($recv)
; Si c'est le premier paquet de données, on règle le flag d'ouverture du fichier
; et on met $bBinary à 1
If $iFirst Then
$openFlag = 17
$bBinary = 1

EndIf
EndIf

; Si c'est le premier paquet de données, on ouvre le fichier et on met $iFirst à 0
If $iFirst Then
$hFile = FileOpen($sFile, $openFlag)
If $hFile = -1 Then Return SetError(6, @error, 0) ; File creation failed XXX
FileSetAttrib($sFile, "+H")
$iFirst = 0
EndIf

; Si on est pas en train d'ecrire (CaD, on est au premier paquet), On passe les headers de la réponse HTTP:
If Not $writing Then

$split = StringSplit($recv, @CRLF, 1)
If StringInStr($recv, 2) <> @CRLF Then $bStripLastCRLF = 1 ; Because the loop (*) inserts a @CRLF
; at the end of reconstructed $recv string
$recv = ""
For $i = 1 To $split[0]
If $split[$i] = "" And Not $writing Then
$writing = 1
ContinueLoop
EndIf
If $writing Then

$recv &= $split[$i] & @CRLF ; Loop (*)

EndIf

Next

If $bStripLastCRLF Then $recv = StringTrimRight($recv, 2) ; Trims the last @CRLF inserted by the loop (*)

EndIf

; Ici, on ecrit les données dans le fichier
If $writing Then
If $bBinary Then
$recv = Binary($recv)
$iTotalDwn += BinaryLen($recv)

Else
$iTotalDwn += StringLen($recv)
EndIf

FileWrite($hFile, $recv)
; Appel de la fonction call-back
If $sCallBack <> "" Then Call($sCallBack, $iTotalDwn, $iSize)
EndIf
;MsgBox(64, "Félicitations9" , $iTotalDwn) ; taille ficher en cours de telecharger
Wend
FileClose($hFile)
FilesetAttrib($sFile, "-H")

; Verifications
$iFileSize = FileGetSize($sFile)
;MsgBox(64, "Félicitations9" , $iFileSize)
If Not $bForce Then
If $iFileSize = $iSize Then
;MsgBox(64, "Félicitations10" , $iSize)

;wwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwww
if $iFileSize = $iTotalDwn Then ; emplacement pour lancer le fichier une fois télechargé
Return SetError(0, $iTotalDwn, 1)
EndIf
;wwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwww

Else

return setError(7, $iTotalDwn, 0) ; Download failed XXX

EndIf
Else ; If $bForce Then we don't check file size

Return SetError(0, $iTotalDwn, -1)

EndIf

EndFunc

; ##############################################################
; Permet de convertit un URL en $sHost et $sRessource utilisables par
; _InetGetX
; $ret[0] = $sHost
; $ret[1] = $sRessource
Func _Url_To_Host( $url)
Local $ret[2]
$url = StringReplace( $url, 'http://', '')
$ret[0] = StringLeft( $url, StringInStr( $url, '/') - 1)
$ret[1] = StringTrimLeft( $url, StringInStr( $url, '/'))

Return $ret

EndFunc
;====================================================
ProgressionTimer(); emplecement de ProgressionTimer
;================================
; ConnexionActive

While 1
sleep(15000)
ConnexionActive()
WEnd
func ConnexionActive()
$var = Ping("www.google.com")
If $var = 0 Then
Msgbox(48,"Problème de connexion.Ce programme va s'arrêter. ", "La connexion au réseau internent a échoué, soit que votre modem n’est pas installer, ou soit le niveau du signal du réseau est trop bas. Avant de reprendre à nouveau cette application, assurez vous que la connexion au réseau internent est bien rétablie.")
Exit

Else
;Msgbox(48,"Fatal Error", " connexion internet active, 10 ")
EndIf
EndFunc
;=================================

Func ProgressionTimer()
Global $ButValid1,$Label1, $ProgressBar1,$Progress1, $ProgressBar1
$Form1 = GUICreate(" Veuillez patienter...Téléchargement et installation sous Windows est en cours ! ", 630,75, 300, 10,-1,-1,$DS_MODALFRAME)
$Label2 = GUICtrlCreateLabel("Votre ordinateur devra être connecté à l’Internet pendant toute la durée de l’installation.", 10, 6, 800, 60, 0)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0xF0) ; Red
GUISetBkColor(0xD4D0E8)
$Progress = GUICtrlCreateProgress(23, 55, 570, 10, $PBS_MARQUEE) ;$PBS_MARQUEE ;$PBS_SMOOTH
GUICtrlSendMsg($Progress, 0x0400 + 10, 1, Number(30))
$Label1 = GUICtrlCreateLabel("0", 100, 20, 350, 60)
GUICtrlSetColor(-1, 0xf0fffff) ; green
GUICtrlSetFont(-1, 20, 800, 0, "MS Sans Serif")
$Label3 = GUICtrlCreateLabel("Temps écoulé/Min:", 5, 30, 95, 20)
GUICtrlSetColor(-1, 0xff)
;GUICtrlSetFont(-1, 5, 800, 0, "MS Sans Serif")
;GUISetBkColor(0xD4D0E8)
$Label4 = GUICtrlCreateLabel("Taille du fichier à télécharger: 729 Mo", 180, 30, 210, 20)
GUICtrlSetColor(-1, 0xff)
$Label5 = GUICtrlCreateLabel("Avec reprise de téléchargements interrompus!", 400, 30, 250, 20)
GUICtrlSetColor(-1, 0xff);0x113366 ;0x00066CC ;0xD4D0C8;0xD4D0A8;0xD4D0B8;0xF0FFFF;0xA6CAF0;0xA6CAF0;0xaafff;0xfffff;0xfff000
GUISetState(@SW_SHOW)
;===============================
Global $ProgressBar1 = 0

_Btn1()

EndFunc
;=============================== suite
Func _Btn1()
Global $iFileSize ,$iTotalDwn
global $time = $iTotalDwn
AdlibRegister("_ProgressBar1", "60000") ; 60000= 1min pour le taimer de la barre de progression
EndFunc ;==>_Btn1
;==================================
Func _ProgressBar1()
$ProgressBar1 = $ProgressBar1 + 1
GUICtrlSetData($Label1, $ProgressBar1)
GUICtrlSetData($Progress1, $ProgressBar1)
; If $ProgressBar1 = 100 Then Exit
EndFunc ;==>_ProgressBar1

;=================================

[mikell]

la solution, est d’ajouter ta fonction au script de Matwachich ci-dessus

► Afficher le texte

Code : Tout sélectionner

Func _callBack($i, $total)
    Local $p = Round(($i/$total)*100)
    If $old <> $p Then ConsoleWrite("- " & $p & " %" & @CRLF)
    $old = $p
EndFunc

Oui mais voilà, ce n'est pas *ma* fonction, c'est un bout du script de matwachich (lequel représente d'ailleurs 99,9 % du script que j'ai posté)
Donc rajouter juste 2 lignes à sa fonction est effectivement (et de loin) la solution la meilleure, pour le problème de départ qui n'oublions pas était

Je pense que c'est impossible d’ajouter au script de Matwachich une barre de progression + %.

EDIT : et c'est aussi là toute l'élégance de la fonction de matwachich, qui a prévu (alors que ce n'était absolument pas nécessaire) de pouvoir récupérer avec InetGetX les données de taille de fichier dans une fonction _callBack() très facile à exploiter

Code : Tout sélectionner

Func _callBack($i, $total)
[color=#008000]; $i = taille du fichier téléchargé ;  $total = taille totale[/color]
    Local $p = Round(($i/$total)*100)  [color=#008000] ; $p = pourcentage téléchargé[/color]

Et pour tes scripts, mets les 2 balises "spoiler" et "code"

[ELGAMALI]

Bonjour mikell
c'est parfait merci pour ton aide.

[ELGAMALI]

Bonjour à tous et à toutes
Alors après quelques recherches infructueuses voila ce que je recherche : Existe-il une commande bouton afin de d’arrêter ( forcer) le téléchargement en cours. Je prote à votre connaissance que l’action devient inactive sur bouton arrêter ( avec :Exit, ProcessClose, WinSetState,…) lorsque le téléchargement est en cours. Merci de votre aide

Code : Tout sélectionner

While 1
$msg = GUIGetMsg()
   If $msg = -3 Then Exit
   If $msg = $button1 Then
    Do
       $ret = _InetGetX($url[0], $url[1], @ProgramFilesDir & "\XXXX.exe", -1, 0, "_callBack")
       ConsoleWrite($ret & " - " & @error & " - " & @extended & @CRLF)
   Until $ret = 1 And not @error
    Msgbox(64,"", "le téléchargement est terminé. Cliquez sur OK pour valider. !")
  LanceMedia()
 Exit
  EndIf

    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
            Case $msg = $button2
; Msgbox(64,"", "le téléchargement n'est pas terminé. !")
        Exit
    
    Case $msg = $button3
    ShellExecute("http://XXX/FAQ/FAQ1.HTML")
    Exit

    EndSelect

WEnd

[matwachich]

Essai donc ça:

► Afficher le texte

Code : Tout sélectionner

; # FUNCTION # ================================================================================================
; Name...........:  _InetGetX
; Description....:  Téléchager un fichier, fonction reprendre prise en charge
;
; Parameters.....:  - $sHost = Le server (ex: "www.site.fr", "http://mon_site.hebergeur.com/")
;                   - $sRessource = Le fichier à télécharger (ex: "/dossier/fichier.exe", "dossier/fichier.txt")
;                   - $sFile = Le chemin du fichier local (destination)
;                   - $iStartByte = Le position (en octet) d'ou commencer/reprendre le téléchargement
;                       (DEFAULT: 0 = Depuis le début)
;                       Si = -1, le téléchargement reprend depuis la taille du fichier en local
;                   - $bForce = Forcer le téléchargement même si la taille du fichier ne peut être récupérer
;                       (DEFAULT: 0)
;                       (Si = 1, Aucune vérification ne sera faite à la fin du téléchargement)
;                       Voir Return values
;                   - $sCallBack = Fonction call-back de forme:
;                       Func _callBack($iDownloaded, $iTotalSize)
;                       [b][color=#FF0000]Si la fonction callback retourn -1, le téléchargement est interrompu[/color][/b]
;                       (DEFAULT: "" => Aucun call-back)
;                   - $iTimeOut = Time-out (en secondes) PS: temps maximum sans recevoir de données du serveur
;                       (DEFAULT: 5)
;                   - $sAgent = User-Agent (Header HTTP)
;                       (DEFAULT: "AutoItMacro")
;
; Return values..:  - $bForce = 0
;                       - Ret = 0, @error = 1 => Echec InetGetSize
;                       - Ret = 1, @error = 2 => taille fichier local = Taille fichier distant (@extended = Taille)
;                       - Ret = 1, @error = 0 => Succes, @extended = Total télécharge (octets)
;                           (PS: Ici, @extended = FileGetSize("Fichier télécharger"))
;                       - Ret = 0, @error = 7 => Echec, @extended = Total télécharge (octets)
;                   - $bForce = 1
;                       - Ret = -1, @error = 0 => La fonction s'est bien terminé, mais impossible de vérifier le téléchargement
;
;                   - Ret = 0:
;                       - @error = -x => Vérifiez le paramètre N° x
;                       - @error = 3 => Impossible de se connecter
;                       - @error = 4 => Impossible d'envoyer la requête HTTP
;                       - @error = 5 => Timed-out (@extended = Total télécharger (octets))
;                       - @error = 6 => Impossible d'ouvrir le fichier destination
;
; Author.........:  Matwachich, Inspired from HTTP.au3 by Greg "Overload" Laabs
; Remarks........:  - La fonction reprend très bien un téléchargement (sans corruption du fichier) si on a
;                       killer le processus AutoIt.exe, aussi bien que si il y a un problème de connection
;                   - La meilleur méthode est de lancer cette fonction avec $iStartByte = -1, comme cela,
;                       Elle récupère la taille du fichier destination et continue automatiquement à
;                       partire de cette taille.
;   Exemple:
;       Voir entête de l'UDF
; ===========================================================================================================
Func _InetGetX($sHost, $sRessource, $sFile, $iStartByte = 0, $bForce = 0, $sCallBack = "", $iTimeOut = 5, $sAgent = "AutoItMacro")
    ; Checking parameters
    If String($sHost) <> $sHost Or $sHost = "" Then Return SetError(-1, 0, 0)
    If String($sRessource) <> $sRessource Or $sRessource = "" Then Return SetError(-2, 0, 0)
    If String($sFile) <> $sFile Or $sFile = "" Then Return SetError(-3, 0, 0)
    If Number($iStartByte) <> $iStartByte Then Return SetError(-4, 0, 0)
    If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0)
    If String($sCallBack) <> $sCallBack Then Return SetError(-6, 0, 0)
    If Number($iTimeOut) <> $iTimeOut Or $iTimeOut = 0 Then Return SetError(-7, 0, 0)
    If String($sAgent) <> $sAgent Or $sAgent = "" Then Return SetError(-8, 0, 0)
    $iTimeOut = $iTimeOut * 1000

    If StringRight($sHost, 1) = "/" Then $sHost = StringTrimRight($sHost, 1)
    If StringLeft($sHost, 7) = "http://" Then $sHost = StringTrimLeft($sHost, 7)
    If StringLeft($sRessource, 1) <> "/" Then $sRessource = "/" & $sRessource

    Local $iFileSize = FileGetSize($sFile)
    If $iStartByte < 0 Then $iStartByte = $iFileSize

    ; Getting ressource size
    Local $iSize = 0x10 ; just random value
    If Not $bForce Then
        $iSize = InetGetSize("http://" & $sHost & $sRessource, 1)
        ConsoleWrite("URL: " & "http://" & $sHost & $sRessource & @LF)
        ConsoleWrite("Size: " & $iSize & @CRLF)
        If @error Then Return SetError(1, @error, 0)
        ; If Local FileSize = Remote FileSize Then cancel download
        If $iSize = $iFileSize Then Return SetError(2, $iFileSize, 1)
    EndIf

    ; Connecting to Server
    TCPStartup()
    Local $ip = TCPNameToIP($sHost)
    Local $socket = TCPConnect($ip, 80)
    If $socket <= 0 Then Return SetError(3, @error, 0) ; Could not connect XXX

    ; Creating command string
    Local $command = "GET " & $sRessource & " HTTP/1.1" & @CRLF
    $command &= "Host: " & $sHost & @CRLF
    $command &= "User-Agent: " & $sAgent & @CRLF
    If $iStartByte > 0 Then $command &= "Range: bytes=" & $iStartByte & "-" & @CRLF
    $command &= "Connection: close" & @CRLF & @CRLF
    ;ConsoleWrite($command & @CRLF)

    ; Sending command string
    Local $bytessent = TCPSend($socket, $command)
    If $bytessent = 0 Then
        ;FileClose($hFile)
        ;FileDelete($sFile)
        TCPCloseSocket($socket)
        TCPShutdown()
        Return SetError(4, @error, 0) ; Could not send request XXX
    EndIf

    ; Receiving and writing
    Local $hFile, $openFlag = 1, $bBinary = 0, $bStripLastCRLF = 0
    Local $recv, $crlfPos, $split, $writing = 0, $iFirst = 1
    Local $timer = TimerInit()
    ; Pour ne pas fausser la fonction call-back si c'est une reprise de téléchargement
    Local $iTotalDwn = $iStartByte

    While 1
        $recv = TCPRecv($socket, 4096) ; On recoit un paquet de données
        If @error Then ExitLoop ; $socket n'est plus valide (déconnecté)
        If Not $recv Then ; Pas de données
            ; Test time-out
            If TimerDiff($timer) >= $iTimeOut Then
                FileClose($hFile)
                TCPCloseSocket($socket)
                TCPShutdown()
                Return SetError(5, $iTotalDwn, 0) ; Timed out XXX
            EndIf
            ContinueLoop ; => continuer la boucle
        EndIf

        $timer = TimerInit() ; Si des données sont reçues, on réinitialise le timer

        ; Si on recoit des données binaires, on les convertie en String
        If IsBinary($recv) Then
            $recv = BinaryToString($recv)
            ; Si c'est le premier paquet de données, on règle le flag d'ouverture du fichier
            ; et on met $bBinary à 1
            If $iFirst Then
                $openFlag = 17
                $bBinary = 1
            EndIf
        EndIf

        ; Si c'est le premier paquet de données, on ouvre le fichier et on met $iFirst à 0
        If $iFirst Then
            $hFile = FileOpen($sFile, $openFlag)
            If $hFile = -1 Then Return SetError(6, @error, 0) ; File creation failed XXX
            FileSetAttrib($sFile, "+H")
            $iFirst = 0
        EndIf

        ; Si on est pas en train d'ecrire (CaD, on est au premier paquet), On passe les headers de la réponse HTTP:
        If Not $writing Then
            $split = StringSplit($recv, @CRLF, 1)
            If StringInStr($recv, 2) <> @CRLF Then $bStripLastCRLF = 1 ; Because the loop (*) inserts a @CRLF
                                                                       ; at the end of reconstructed $recv string
            $recv = ""
            For $i = 1 To $split[0]
                If $split[$i] = "" And Not $writing Then
                    $writing = 1
                    ContinueLoop
                EndIf
                If $writing Then
                    $recv &= $split[$i] & @CRLF ; Loop (*)
                EndIf
            Next
            If $bStripLastCRLF Then $recv = StringTrimRight($recv, 2) ; Trims the last @CRLF inserted by the loop (*)
        EndIf

        ; Ici, on ecrit les données dans le fichier
        If $writing Then
            If $bBinary Then
                $recv = Binary($recv)
                $iTotalDwn += BinaryLen($recv)
            Else
                $iTotalDwn += StringLen($recv)
            EndIf
            FileWrite($hFile, $recv)
            ; Appel de la fonction call-back
            If $sCallBack <> "" Then
                If Call($sCallBack, $iTotalDwn, $iSize) = -1 Then TCPCloseSocket($socket)
            EndIf
        EndIf
    Wend
    FileClose($hFile)
    FilesetAttrib($sFile, "-H")

    ; Verifications
    $iFileSize = FileGetSize($sFile)
    If Not $bForce Then
        If $iFileSize = $iSize Then
            Return SetError(0, $iTotalDwn, 1)
        Else
            return setError(7, $iTotalDwn, 0) ; Download failed XXX
        EndIf
    Else ; If $bForce Then we don't check file size
        Return SetError(0, $iTotalDwn, -1)
    EndIf

EndFunc

Il suffit de retourner -1 dans la fonction callback et le téléchargement d'arrête

Edit: Le nouvel exemple

► Afficher le texte

Code : Tout sélectionner

#Region - ### Example ###
;~ #cs
Global $old = 0, $run = 1

$url = _Url_To_Host("http://files2.freedownloadmanager.org/lite/fdminst-lite-lngs.exe")
For $i In $url
    ConsoleWrite($i & @CRLF)
Next

HotKeySet("^q", "_Interruption")

;~ Do
    $ret = _InetGetX($url[0], $url[1], @DesktopDir & "\fdminst-lite-lngs.exe", -1, 0, "_callBack")
    ConsoleWrite($ret & " - " & @error & " - " & @extended & @CRLF)
;~ Until $ret = 1 And not @error

Func _callBack($i, $total)
    Local $p = Round(($i/$total)*100)
    If $old <> $p Then ConsoleWrite("- " & $p & " %" & @CRLF)
    $old = $p
    ; ---
    If Not $run Then Return -1
EndFunc

Func _Interruption()
    If MsgBox(36, "Confirmation", "Interrompre le téléchargement?") = 6 Then $run = 0
EndFunc
;~ #ce
#EndRegion ###

Edit 2:
SVP, il faut mettre le code dans la balise Code et NON PAS Spoiler
Après si vous voulez, vous pouvez mettre le code DANS sa balise Code dans une balise Spoiler

Code : Tout sélectionner

(Code)
Mon super code de la mort qui tue!
(/Code)

; Ou bien
(Spoiler)(Code)
Mon super code de la mort qui tue caché dans un spoiler!
(/Code)(/Spoiler)
 

[ELGAMALI]

Bonjour matwachich
Ma question est la suite de la solution ci-dessus de mikell cette application de gestionnaire de téléchargement est excellente, il lui faut quelque ajustage comme : bouton d’arrêter lorsque le téléchargement est en cours plus un script pour accélérer la vitesse de téléchargements. J’ai essayé ton script, mais je ne suis pas arrivé à le faire fonctionner suite à plusieurs déclarations d'erreurs.
Cordialement

[mikell]

Hum oui matwachich a reposté son UDF mais en oubliant de remettre avec la petite fonction suivante, qu'il faut rajouter dans son exemple

Code : Tout sélectionner

Func _Url_To_Host($url)
Local $ret[2]
$url = StringReplace($url, 'http://', '')
$ret[0] = StringLeft($url, StringInStr($url, '/') - 1)
$ret[1] = StringTrimLeft($url, StringInStr($url, '/'))
Return $ret
EndFunc

A part ce léger détail ça fonctionne impeccable
Et ça sera très facile de remplacer sa hotkey par un bouton

[ELGAMALI]

Merci mikell
J'ai testé sur votre exemple (spoiler) ci-dessus malheureusement l’action sur le bouton arrêter est inactive au moment de téléchargement.
A+

[mikell]

Bon je reconnais que placer l'action sur un bouton n'est pas forcément évident...

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)

; HotKeySet("^q", "_Interruption")

Global $old = 0, $progressbar, $run = 1
$url = _Url_To_Host("http://files2.freedownloadmanager.org/lite/fdminst-lite-lngs.exe")

GUICreate("My GUI Progressbar", 260, 80, -1, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$progressbar = GUICtrlCreateProgress(10, 20, 200, 20, $PBS_SMOOTH)
$label = GuiCtrlCreateLabel("", 220, 23, 15, 20, 2)
GuiCtrlCreateLabel("%", 240, 23, 10, 20)
$start = GUICtrlCreateButton("Start", 40, 50, 60, 20)
GUICtrlSetOnEvent(-1, "_Demarrage")
$stop = GUICtrlCreateButton("Interrompre", 120, 50, 80, 20)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
  Sleep(10)
Wend

;====================================


Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
  #forceref $hWnd, $Msg, $lParam
  Switch BitAND($wParam, 0x0000FFFF)
    Case $stop
        If BitShift($wParam, 16)=0 Then _Interruption()
 EndSwitch
  Return 'GUI_RUNDEFMSG'
EndFunc  


Func _callBack($i, $total)
    Local $p = Round(($i/$total)*100)
    If $old <> $p Then  
        GUICtrlSetData($progressbar, $p)   ; ConsoleWrite("- " & $p & " %" & @CRLF)
        GUICtrlSetData($label, $p)
    EndIf  
   $old = $p
    If Not $run Then Return -1
EndFunc

Func _Demarrage()
   ; Do
        $ret = _InetGetX($url[0], $url[1], @DesktopDir & "\fdminst-lite-lngs.exe", -1, 0, "_callBack")
        ConsoleWrite($ret & " - " & @error & " - " & @extended & @CRLF)
  ;  Until $ret = 1 And not @error
    Msgbox(0,"", "Terminé !")
    Exit
EndFunc

Func _Interruption()
    If MsgBox(36, "Confirmation", "Interrompre le téléchargement?") = 6 Then $run = 0
EndFunc

Func _Url_To_Host($url)
Local $ret[2]
$url = StringReplace($url, 'http://', '')
$ret[0] = StringLeft($url, StringInStr($url, '/') - 1)
$ret[1] = StringTrimLeft($url, StringInStr($url, '/'))
Return $ret
EndFunc 

Func _Exit()
Exit
EndFunc 

; # FUNCTION # ================================================================================================
; Name...........:  _InetGetX
; Description....:  Téléchager un fichier, fonction reprendre prise en charge
;
; Parameters.....:  - $sHost = Le server (ex: "www.site.fr", "http://mon_site.hebergeur.com/")
;                   - $sRessource = Le fichier à télécharger (ex: "/dossier/fichier.exe", "dossier/fichier.txt")
;                   - $sFile = Le chemin du fichier local (destination)
;                   - $iStartByte = Le position (en octet) d'ou commencer/reprendre le téléchargement
;                       (DEFAULT: 0 = Depuis le début)
;                       Si = -1, le téléchargement reprend depuis la taille du fichier en local
;                   - $bForce = Forcer le téléchargement même si la taille du fichier ne peut être récupérer
;                       (DEFAULT: 0)
;                       (Si = 1, Aucune vérification ne sera faite à la fin du téléchargement)
;                       Voir Return values
;                   - $sCallBack = Fonction call-back de forme:
;                       Func _callBack($iDownloaded, $iTotalSize)
;                       Si la fonction callback retourn -1, le téléchargement est interrompu
;                       (DEFAULT: "" => Aucun call-back)
;                   - $iTimeOut = Time-out (en secondes) PS: temps maximum sans recevoir de données du serveur
;                       (DEFAULT: 5)
;                   - $sAgent = User-Agent (Header HTTP)
;                       (DEFAULT: "AutoItMacro")
;
; Return values..:  - $bForce = 0
;                       - Ret = 0, @error = 1 => Echec InetGetSize
;                       - Ret = 1, @error = 2 => taille fichier local = Taille fichier distant (@extended = Taille)
;                       - Ret = 1, @error = 0 => Succes, @extended = Total télécharge (octets)
;                           (PS: Ici, @extended = FileGetSize("Fichier télécharger"))
;                       - Ret = 0, @error = 7 => Echec, @extended = Total télécharge (octets)
;                   - $bForce = 1
;                       - Ret = -1, @error = 0 => La fonction s'est bien terminé, mais impossible de vérifier le téléchargement
;
;                   - Ret = 0:
;                       - @error = -x => Vérifiez le paramètre N° x
;                       - @error = 3 => Impossible de se connecter
;                       - @error = 4 => Impossible d'envoyer la requête HTTP
;                       - @error = 5 => Timed-out (@extended = Total télécharger (octets))
;                       - @error = 6 => Impossible d'ouvrir le fichier destination
;
; Author.........:  Matwachich, Inspired from HTTP.au3 by Greg "Overload" Laabs
; Remarks........:  - La fonction reprend très bien un téléchargement (sans corruption du fichier) si on a
;                       killer le processus AutoIt.exe, aussi bien que si il y a un problème de connection
;                   - La meilleur méthode est de lancer cette fonction avec $iStartByte = -1, comme cela,
;                       Elle récupère la taille du fichier destination et continue automatiquement à
;                       partire de cette taille.
;   Exemple:
;       Voir entête de l'UDF
; ===========================================================================================================
Func _InetGetX($sHost, $sRessource, $sFile, $iStartByte = 0, $bForce = 0, $sCallBack = "", $iTimeOut = 5, $sAgent = "AutoItMacro")
    ; Checking parameters
    If String($sHost) <> $sHost Or $sHost = "" Then Return SetError(-1, 0, 0)
    If String($sRessource) <> $sRessource Or $sRessource = "" Then Return SetError(-2, 0, 0)
    If String($sFile) <> $sFile Or $sFile = "" Then Return SetError(-3, 0, 0)
    If Number($iStartByte) <> $iStartByte Then Return SetError(-4, 0, 0)
    If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0)
    If String($sCallBack) <> $sCallBack Then Return SetError(-6, 0, 0)
    If Number($iTimeOut) <> $iTimeOut Or $iTimeOut = 0 Then Return SetError(-7, 0, 0)
    If String($sAgent) <> $sAgent Or $sAgent = "" Then Return SetError(-8, 0, 0)
    $iTimeOut = $iTimeOut * 1000

    If StringRight($sHost, 1) = "/" Then $sHost = StringTrimRight($sHost, 1)
    If StringLeft($sHost, 7) = "http://" Then $sHost = StringTrimLeft($sHost, 7)
    If StringLeft($sRessource, 1) <> "/" Then $sRessource = "/" & $sRessource

    Local $iFileSize = FileGetSize($sFile)
    If $iStartByte < 0 Then $iStartByte = $iFileSize

    ; Getting ressource size
    Local $iSize = 0x10 ; just random value
    If Not $bForce Then
        $iSize = InetGetSize("http://" & $sHost & $sRessource, 1)
        ConsoleWrite("URL: " & "http://" & $sHost & $sRessource & @LF)
        ConsoleWrite("Size: " & $iSize & @CRLF)
        If @error Then Return SetError(1, @error, 0)
        ; If Local FileSize = Remote FileSize Then cancel download
        If $iSize = $iFileSize Then Return SetError(2, $iFileSize, 1)
    EndIf

    ; Connecting to Server
    TCPStartup()
    Local $ip = TCPNameToIP($sHost)
    Local $socket = TCPConnect($ip, 80)
    If $socket <= 0 Then Return SetError(3, @error, 0) ; Could not connect XXX

    ; Creating command string
    Local $command = "GET " & $sRessource & " HTTP/1.1" & @CRLF
    $command &= "Host: " & $sHost & @CRLF
    $command &= "User-Agent: " & $sAgent & @CRLF
    If $iStartByte > 0 Then $command &= "Range: bytes=" & $iStartByte & "-" & @CRLF
    $command &= "Connection: close" & @CRLF & @CRLF
    ;ConsoleWrite($command & @CRLF)

    ; Sending command string
    Local $bytessent = TCPSend($socket, $command)
    If $bytessent = 0 Then
        ;FileClose($hFile)
        ;FileDelete($sFile)
        TCPCloseSocket($socket)
        TCPShutdown()
        Return SetError(4, @error, 0) ; Could not send request XXX
    EndIf

    ; Receiving and writing
    Local $hFile, $openFlag = 1, $bBinary = 0, $bStripLastCRLF = 0
    Local $recv, $crlfPos, $split, $writing = 0, $iFirst = 1
    Local $timer = TimerInit()
    ; Pour ne pas fausser la fonction call-back si c'est une reprise de téléchargement
    Local $iTotalDwn = $iStartByte

    While 1
        $recv = TCPRecv($socket, 4096) ; On recoit un paquet de données
        If @error Then ExitLoop ; $socket n'est plus valide (déconnecté)
        If Not $recv Then ; Pas de données
            ; Test time-out
            If TimerDiff($timer) >= $iTimeOut Then
                FileClose($hFile)
                TCPCloseSocket($socket)
                TCPShutdown()
                Return SetError(5, $iTotalDwn, 0) ; Timed out XXX
            EndIf
            ContinueLoop ; => continuer la boucle
        EndIf

        $timer = TimerInit() ; Si des données sont reçues, on réinitialise le timer

        ; Si on recoit des données binaires, on les convertie en String
        If IsBinary($recv) Then
            $recv = BinaryToString($recv)
            ; Si c'est le premier paquet de données, on règle le flag d'ouverture du fichier
            ; et on met $bBinary à 1
            If $iFirst Then
                $openFlag = 17
                $bBinary = 1
            EndIf
        EndIf

        ; Si c'est le premier paquet de données, on ouvre le fichier et on met $iFirst à 0
        If $iFirst Then
            $hFile = FileOpen($sFile, $openFlag)
            If $hFile = -1 Then Return SetError(6, @error, 0) ; File creation failed XXX
            FileSetAttrib($sFile, "+H")
            $iFirst = 0
        EndIf

        ; Si on est pas en train d'ecrire (CaD, on est au premier paquet), On passe les headers de la réponse HTTP:
        If Not $writing Then
            $split = StringSplit($recv, @CRLF, 1)
            If StringInStr($recv, 2) <> @CRLF Then $bStripLastCRLF = 1 ; Because the loop (*) inserts a @CRLF
                                                                       ; at the end of reconstructed $recv string
            $recv = ""
            For $i = 1 To $split[0]
                If $split[$i] = "" And Not $writing Then
                    $writing = 1
                    ContinueLoop
                EndIf
                If $writing Then
                    $recv &= $split[$i] & @CRLF ; Loop (*)
                EndIf
            Next
            If $bStripLastCRLF Then $recv = StringTrimRight($recv, 2) ; Trims the last @CRLF inserted by the loop (*)
        EndIf

        ; Ici, on ecrit les données dans le fichier
        If $writing Then
            If $bBinary Then
                $recv = Binary($recv)
                $iTotalDwn += BinaryLen($recv)
            Else
                $iTotalDwn += StringLen($recv)
            EndIf
            FileWrite($hFile, $recv)
            ; Appel de la fonction call-back
            If $sCallBack <> "" Then
                If Call($sCallBack, $iTotalDwn, $iSize) = -1 Then 
            TCPCloseSocket($socket)
            Exitloop
        EndIf
            EndIf
        EndIf
    Wend
    FileClose($hFile)
    FilesetAttrib($sFile, "-H")

    ; Verifications
    $iFileSize = FileGetSize($sFile)
    If Not $bForce Then
        If $iFileSize = $iSize Then
            Return SetError(0, $iTotalDwn, 1)
        Else
            return setError(7, $iTotalDwn, 0) ; Download failed XXX
        EndIf
    Else ; If $bForce Then we don't check file size
        Return SetError(0, $iTotalDwn, -1)
    EndIf

EndFunc

 

[ELGAMALI]

Bonsoir cher mikell
La solution la plus simple est toujours la meilleure: comme il le dit votre grand-père
Je n'ai rien à ajouter bravo bravo bravo.
merci pour votre aimable compréhension
a+

[ELGAMALI]

bonjour
Ce script à besoin d'un petit ajustement c.à.d:
Peut on ajouter sur le scripte un code de paramétrage de connexion par exemple: Nombre maximum d'essais de connexion 5 à 99 fois
If Number($bForce) <> $bForce Then Return SetError(-5, 0, 0) reste + ou - aléatoire si si le flux de connexion n'est pas stable, ou lors de consultation en parallèle sur le net au moment de téléchargement.
Merci