[..] Importer des fichiers scénario.au3 d'un fichier .ini

[sylvain910]

Bonjour,

j'ai pour objectif de créer une IHM qui permettrait de lancer de manière automatique
plusieurs scénario aux formats .au3
Pour celà, j'aimerais récupérer les fichiers de scénario à partir d'un fichier .ini.
A la suite de cela, les fichiers de scénarios s'inscrirons dans l'IHM de départ précédé
d'une checkbox (pour pouvoir l'annulée au cas ou).

L'IHM doit être capable d'indiquer tous les scénarios ( nombre de scénario; de 1 à ...)
Pour cela j'ai penser à créer une listview qui s'adapterais au nombre de scénario.au3


là ou je bloc:

- Comment pouvoir insérer des scénarios.au3 à l'IHM à l'aide du fichier.ini
- Savoir si listview est le meilleur moyen pour cela car je n'arrive pas à créer de checkbox par dessus
- Lancer les procédures sélectionnés

Voici mes codes sources, .ini et .au3
J'ai pris un fichier scénario bidon ( lancement de la calculatrice )

Code fichier .ini

► Afficher le texte

[SectionDemo]
Procédure 1 = C:\Documents and Settings\sylvain\scenariodetest.au3

Code IHM

► Afficher le texte

#include <GUIConstantsEx.au3>

; ===============================================================================================================================
; Création de la principal fenêtre
; ===============================================================================================================================
$Form1 = GUICreate("Automatisation", 400, 700, -1, -1)
GuiCtrlCreateTab(0, 0, 800, 700)

; ===============================================================================================================================
; Création des différentes Onglets
; ===============================================================================================================================
$tab0 = GuiCtrlCreateTabItem("DEMO")


; ===============================================================================================================================
; Création des différentes CheckBox
; ===============================================================================================================================
;~ Global $Demo_Automatisation = GUICtrlCreateCheckbox("DEMO1", 25, 124, 300, 25)
;~ GUICtrlSetTip($Demo_Automatisation , "Automatisation" &@LF& "16/02/2012")
;~ GUICtrlSetFont(-1, 10, 100, 0, "Verdana")


; ===============================================================================================================================
; Création des bouttons
; ===============================================================================================================================
Global $Button_Start = GUICtrlCreateButton("Start >>", 300, 670, 100, 30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $Button_Quitter = GUICtrlCreateButton("<< Quit",0, 670, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $ToutCocher = GUICtrlCreateButton("Tout Cocher",100, 670, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $ToutDecocher = GUICtrlCreateButton("Tout Decocher",200, 670, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
GUISetState()


; ===============================================================================================================================
; Create LIST VIEW
; ===============================================================================================================================
$listView = GuiCtrlCreateListView("Check|Procédure|", 0, 20, 400, 650)
;~ GUICtrlCreateCheckbox("DEMO1", 25, 124, 300, 25)
GuiCtrlCreateListViewItem("GUICtrlCreateCheckbox", $listView)
GuiCtrlCreateListViewItem("B|Two", $listView)
GuiCtrlCreateListViewItem("C|Three", $listView)
GuiCtrlCreateListViewItem("Etc|Etc", $listView)


; ===============================================================================================================================
; IniReadSection
; ===============================================================================================================================

$var = IniReadSection("\demo.ini", "Section_TEST")
If @error Then
MsgBox(4096, "", "Error occurred, probably no INI file.")
Else
For $i = 1 To $var[0][0]

MsgBox(4096, "", "Key: " & $var[$i][0] & @CRLF & "Value: " & $var[$i][1])
Next
EndIf

; ===============================================================================================================================
; Event clic Button
; ===============================================================================================================================

While 1
$nMsg = GUIGetMsg()

Switch $nMsg

Case $Button_Start
;If $nMsg = $Button_Start Then
;!!! Lancement des scénarios séléctionnés !!!
;Exit
;EndIf

Case $ToutCocher
For $i = 1 To 5
GUICtrlSetState(Eval("DEMO" & $i), $GUI_CHECKED); Eval: Return the value of the variable defined by an string.
Next

Case $ToutDecocher
For $i=1 To 5
GUICtrlSetState(Eval("DEMO" & $i), $GUI_UNCHECKED)

Next
EndSwitch

If $nMsg = $GUI_EVENT_CLOSE Or $nMsg = $Button_Quitter Then ExitLoop
WEnd

GuiSetState()

Si quelqu'un peut m'aider
Sylvain

[mikell]

C'est bien les listviews...

Le fichier "demo.ini" :

► Afficher le texte

Code : Tout sélectionner

[SectionDemo]
Procédure 1 = C:\Documents and Settings\sylvain\scenario1.au3 
Procédure 2 = C:\Documents and Settings\sylvain\scenario2.au3
Procédure 3 = C:\Documents and Settings\sylvain\scenario3.au3
; etc

Et le script :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Automatisation", 400, 700, -1, -1)
GuiCtrlCreateTab(0, 0, 800, 700)
$tab0 = GuiCtrlCreateTabItem("DEMO")
Global $Button_Start = GUICtrlCreateButton("Start >>", 300, 670, 100, 30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $Button_Quitter = GUICtrlCreateButton("<< Quit",0, 670, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $ToutCocher = GUICtrlCreateButton("Tout Cocher",100, 670, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $ToutDecocher = GUICtrlCreateButton("Tout Decocher",200, 670, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")

; [color=#FF0000]- Savoir si listview est le meilleur moyen pour cela car je n'arrive pas à créer de checkbox par dessus[/color]
$listView = GuiCtrlCreateListView("Check|Procédure", 0, 20, 400, 650, -1, $LVS_EX_CHECKBOXES)
GUICtrlSendMsg($listView , $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg($listView , $LVM_SETCOLUMNWIDTH, 1, 290)
GuiSetState()

$var = IniReadSection("demo.ini", "SectionDemo")
If @error Then
    MsgBox(4096, "", "Error occurred, probably no INI file.")
Else
;[color=#FF0000] - Comment pouvoir insérer des scénarios.au3 à l'IHM à l'aide du fichier.ini[/color]
For $i = 1 To $var[0][0]
    GuiCtrlCreateListViewItem($var[$i][0] &"|" & $var[$i][1], $listView)
Next
EndIf
$count = ControlListView ($Form1, "", $listView, "GetItemCount")


While 1
$nMsg = GUIGetMsg()
Switch $nMsg

Case $GUI_EVENT_CLOSE, $Button_Quitter
    ExitLoop

Case $Button_Start
; [color=#FF0000]- Lancer les procédures sélectionnés[/color]
    For $i = 0 to $count-1
    If _GUICtrlListView_GetItemChecked($listView, $i) Then 
        MsgBox(0,"", ControlListView ($Form1, "", $listView, "GetText", $i, 1))
        ; ShellExecute(ControlListView ($Form1, "", $listView, "GetText", $i, 1))
    EndIf
    Next

Case $ToutCocher
    For $i = 0 to $count-1
        _GUICtrlListView_SetItemChecked($listView, $i, True)
    Next

Case $ToutDecocher
    For $i = 0 to $count-1
        _GUICtrlListView_SetItemChecked($listView, $i, False)
    Next
EndSwitch

WEnd
 

Et pour exécuter, bin tu remplaces les msgbox par les ShellExecute

[sylvain910]

Thx, je vais tester ça de suite
Sylvain

[sylvain910]

j'ai apporté quelques modifications à mon scripts

► Afficher le texte

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <Excel.au3>
#include <Timers.au3>
#include <Date.au3>
#include <GuiStatusBar.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>


; ===============================================================================================================================
; Création de la principal fenêtre
; ===============================================================================================================================
$Form1 = GUICreate("Automatisation", 600, 700, -1, -1)
;~ GuiCtrlCreateTab(50, 50, 1100, 700)
; création des menus
GuiCtrlCreateMenu("Fichier")
GuiCtrlCreateMenu("Edition")
GuiCtrlCreateMenu("Affichage")
GuiCtrlCreateMenu("Outils")
GuiCtrlCreateMenu("?")

; ===============================================================================================================================
; Création Icones
; ===============================================================================================================================
;~ Global $Pic1 = GUICtrlCreatePic("C:\Documents and Settings\Bureau\Pictures IHM\play1.bmp",50, 20, 50, 50)
;~ Global $Pic2 = GUICtrlCreatePic("C:\Documents and Settings\Bureau\Pictures IHM\stop1.bmp", 50, 85, 50, 50)

; ===============================================================================================================================
; Création des bouttons
; ===============================================================================================================================
Global $Button_Start = GUICtrlCreateButton("Démarrer >>", 500, 650, 100, 30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $Button_Quitter = GUICtrlCreateButton("<< Quitter",0, 650, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $ToutCocher = GUICtrlCreateButton("Tout Cocher",350, 650, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")
Global $ToutDecocher = GUICtrlCreateButton("Tout Decocher",150, 650, 100,30,1)
GUICtrlSetFont(-1, 10, 10, 0, "Verdana")

; ===============================================================================================================================
; Creation d'une List view
; ===============================================================================================================================

$listView = GuiCtrlCreateListView("Check|Procédure|Status", 0,0, 890, 600, -1, $LVS_EX_CHECKBOXES)
GUICtrlSendMsg($listView , $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg($listView , $LVM_SETCOLUMNWIDTH, 1, 420)
GuiSetState()
; ===============================================================================================================================
; Creation d'une progressBar Général
; ===============================================================================================================================
Local $valLeft = 5, $valTop = 610, $valWidth = 590, $valHeight = 20, $valCurseur = 0, $labelPourcent

$progressBar1 = GUICtrlCreateProgress($valLeft, $valTop, $valWidth, $valHeight)
;ajouter le label % au milieu de la barre de progression
$valCurseur = $valCurseur+1 ; Augmente la valeur du curseur de 1


; ===============================================================================================================================
; IniReadSection
; ===============================================================================================================================
$var = IniReadSection("demo.ini", "SectionDemo")
If @error Then
MsgBox(4096, "", "Error occurred, probably no INI file.")
Else
; - Comment pouvoir insérer des scénarios.au3 à l'IHM à l'aide du fichier.ini
For $i = 1 To $var[0][0]
GuiCtrlCreateListViewItem($var[$i][0] &"|" & $var[$i][1], $listView)
Next
EndIf
$count = ControlListView ($Form1, "", $listView, "GetItemCount")

; ===============================================================================================================================
; Event clic Button
; ===============================================================================================================================
While 1
$nMsg = GUIGetMsg()
Switch $nMsg

Case $GUI_EVENT_CLOSE, $Button_Quitter
ExitLoop

Case $Button_Start
;~ _TimerInit()

; - Lancer les procédures sélectionnés
For $i = 0 to $count-1
If _GUICtrlListView_GetItemChecked($listView, $i) Then
ShellExecuteWait(ControlListView ($Form1, "", $listView, "GetText", $i, 1))
;~ GUICtrlSetData($labelpourcent, " " & Round(($i)/($count-1) * 100, 0) & "%" ) ; Indique le %
GUICtrlSetData($progressBar1, ( $i/($count-1))*100) ; Augmente la position du curseur
EndIf
Next
sleep(5000)

Case $ToutCocher
For $i = 0 to $count-1
_GUICtrlListView_SetItemChecked($listView, $i, True)
Next

Case $ToutDecocher
For $i = 0 to $count-1
_GUICtrlListView_SetItemChecked($listView, $i, False)
Next
EndSwitch

WEnd


; ===============================================================================================================================
; ===============================================================================================================================
; ===============================================================================================================================

Mon Objectif:

Pouvoir mettre un status à chaque procédure,
je m'explique:
- Si la procédure est en cours d'execution j'aimerais pouvoir mettre "En cours"
- Si la procédure est terminé j'aimerais pouvoir mettre " Terminé"

J'ai essayé de le faire mais je n'est pas réussi,
La ou je bloc, c'est de pouvoir dire quelle scénario est en train d'être joué et d'indiquer son status " En cours" et une fois fini "Terminé"
je ne vois pas comment faire pour le changement d'état ( "En cours", "Terminé") et l'indiqué dans la listview
Si quelqu'un peut m'aider
Merci d'avance
Sylvain

[mikell]

AMHA le seul problème c'est la détection du .au3 ouvert
Si tes scénarios comportent des fenêtres qui peuvent être détectées, alors ça devient facile (status du scénario = existence ou non de sa fenêtre)
Après pour la listview il suffit de modifier en temps réel la colonne status (subitems)

[sylvain910]

Ok Merci,
Je vais devoir créer une msgbox factif qui se lance au début et qui se ferme à la fin de mon scénario.au3, car les programmes que je lance sont codés avec Lab Window CVI et impossible de détecter si oui ou non la fenetre est ouverte.

[mikell]

Une msgbox est bloquante, je suppose que tu veux dire une fenêtre vide en mode hide
Mais si les scénarios sont compilés alors tu peux détecter le processus

[sylvain910]

Je vais prendre la solution de tester si l'execution "process" est en marche pour pouvoir mettre mon status à jour,
Sinon, j'ai un problème avec ma barre de progression, le % ne s'affiche qu'au début et puis disparait, j'arrive pas cerner le problème :/ (j'aimerais mettre le % au milieu de la barre de progression )
Sylvain