[R] Bouton graphique avec timer dedans

[GhostLine]

Salut à tous !

Donc me voilà de retour, avec encore un problème à la c*n

J'ai besoin de faire pour mon travail une interface graphique adaptée à un écran tactile, qui permettent de décompter le temps de charge restant de batteries. J'ai un nombre à définir de chargeurs à disposition.

J'aurais aimé faire un bouton graphique vert qui contienne le n° du chargeur (de 1 à n), avec en dessous (toujours dans le bouton), le temps restant pour compléter la charge, mis à jour en temps réel. Lorsque la charge est complète, le bouton devient rouge, le timer est remplacé par des "---". Si on rappuit sur le bouton une fois quand il est dans cet état, il se réinitialise ("en attente"), et si on réappuit encore une fois, le décompte recommence.

Voilà, vous savez tout ma question est tout de même principalement sur la faisabilité de ce bouton magique

[sksbir]

Bonjour

Chargeur de 1 à n.... donc n boutons visibles sur la GUI ?

A priori , rien d'impossible à réaliser .

[GhostLine]

Oui, tout à fait, mais ca n'est pas vraiment le point qui m'inquiète (je vois même plutôt bien comment faire pour que n boutons s'affichent). C'est surtout que je ne sais pas du tout quelle UDF utiliser pour que mes boutons affichent des données dynamiques rafraichies régulièrement.

[ZDS]

Hello !

Pas d'UDF précise à utiliser à mon avis, si tu as une ébauche de l'interface graphique et des exemples de fonctions pour récupérer les infos de charge (%age, temps restant), le reste n'est que du cosmétique sur lequel je peux facilement t'aider.

En exemple :

► Afficher le texte

Code : Tout sélectionner

; Debut de script ...
    Global $stop = False, $n = 10
    Local $matrice_Infos[$n+1][2]
    $matrice_Infos[0][0] = $n
    $matrice_Infos[0][1] = "pourcentage / temps restant"
    For $i = 1 To $matrice_Infos[0][0]
        $matrice_Infos[0][0] = GUICtrlCreateButton("Bouton n°"&$i) ; A compléter
        $matrice_Infos[0][1] = "0 / ---"
    Next
    ; A compléter
    While Not $stop
        ; Traitement des messages
        Switch GUIGetMsg()
        Case $Bouton_Quitter ; Quitter le programme
            $stop = True
        Case $Bouton_Configurer ; Configurer le programme
            ; ...
        ; ...
        Case Else
            For $i = 1 To $matrice_Infos[0][0]
                Local $val = getInfosFromChargeurNuméro($i) ; retourne un array avec deux valeurs %age et temps
                If $val[0]&" / "&$val[1] <> $matrice_Infos[$i][1] Then ; Ne se met à jour que si il y a eu modification
                    $matrice_Infos[$i][1] = $val[0]&" / "&$val[1]
                    ; Mettre à jour bouton, son id est dans $matrice_Infos[$i][0]
                EndIf
            Next
        EndSwitch
    Wend
 

Ce n'est qu'un exemple, à améliorer et exploiter en fonction de tes besoins (exemple ne faire le rafraichissement que toutes les 30 secondes, grace à un timer).

A bientôt !

[sksbir]

Oui, tout à fait, mais ca n'est pas vraiment le point qui m'inquiète (je vois même plutôt bien comment faire pour que n boutons s'affichent). C'est surtout que je ne sais pas du tout quelle UDF utiliser pour que mes boutons affichent des données dynamiques rafraichies régulièrement.

Pour compléter la réponse de ZDS, il suffit d'utiliser guictrlsetdata dans une boucle pour modifier la valeur d'un objet graphique.

Voici une ébauche de script opérationnelle: Je me suis pas cassé la tête avec le décompteur hein: j'attends quasiment une seconde et je fais décroitre les compteurs en activité... si tu veux être plus précis surtout sur une longue période, alors il faut utiliser _timer_init et _timer_diff

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>


Dim Const $LEGENDE_COMPTEUR[5][2]=[ ["Compteur1",30],["Compteur2",10],["Compteur3",40],["Compteur4",5],["Compteur5",10] ]

Dim $GUI_BTN_COMPTEUR[UBound($LEGENDE_COMPTEUR)]


AutoItSetOption("GUIOnEventMode", 1)
$GUI_COMPTEURS=GUICreate("Suivi des compteurs",200,UBound($LEGENDE_COMPTEUR)*30+30)

GUISetOnEvent($GUI_EVENT_CLOSE, "gui_clic_close", $GUI_COMPTEURS)

For $CPT=0 To UBound($LEGENDE_COMPTEUR)-1
    GUICtrlCreateLabel($LEGENDE_COMPTEUR[$CPT][0],50,15+$CPT*30)
    $GUI_BTN_COMPTEUR[$CPT]=GUICtrlCreateButton($LEGENDE_COMPTEUR[$CPT][1],5,10+$CPT*30,40)
    GUICtrlSetBkColor(-1,"0x00FFFF")
    GUICtrlSetOnEvent(-1, "GUI_actionBouton")
Next

GUISetState(@SW_SHOW,$GUI_COMPTEURS)

Func gui_clic_close()
    Exit
EndFunc

Func GUI_actionBouton()
    Local $TROUVE=0
    local $CPT=0
    ; recherche sur quel bouton on a cliqué
    For $CPT=0 To UBound($LEGENDE_COMPTEUR)-1
        If @GUI_CtrlId = $GUI_BTN_COMPTEUR[$CPT] Then
            $TROUVE=1
            ExitLoop
        EndIf
    Next
    If $TROUVE Then
        $ETAT=GUICtrlRead($GUI_BTN_COMPTEUR[$CPT])
        ; changement d'état du compteur selon une logique 3 états ( initial, en cours, à zéro )
        If ($ETAT<$LEGENDE_COMPTEUR[$CPT][1]) And ($ETAT>0) Then
            $ETAT=0
            GUICtrlSetBkColor($GUI_BTN_COMPTEUR[$CPT],"0xFF0000")
        Elseif $ETAT=0 Then
            $ETAT=$LEGENDE_COMPTEUR[$CPT][1]
            GUICtrlSetBkColor($GUI_BTN_COMPTEUR[$CPT],"0x00FFFF")
        ElseIf $ETAT=$LEGENDE_COMPTEUR[$CPT][1] Then
            $ETAT-=1
            GUICtrlSetBkColor($GUI_BTN_COMPTEUR[$CPT],"0x00FF00")
        EndIf
        GUICtrlSetData($GUI_BTN_COMPTEUR[$CPT],$ETAT)
    EndIf

EndFunc


While 1
    Sleep(999)
    For $CPT=0 To UBound($LEGENDE_COMPTEUR)-1
        $ETAT=GUICtrlRead($GUI_BTN_COMPTEUR[$CPT])
        If ($ETAT<$LEGENDE_COMPTEUR[$CPT][1]) And ($ETAT>0) Then
            $ETAT-=1
            GUICtrlSetData($GUI_BTN_COMPTEUR[$CPT],$ETAT)
            If $ETAT<=0 Then GUICtrlSetBkColor($GUI_BTN_COMPTEUR[$CPT],"0xFF0000")
        EndIf
    Next
WEnd


 

[GhostLine]

Merci bcp, je devrais pouvoir m'en sortir avec ça !