[Ex] Startup Software v2.0

[jbnh]

Startup Software v2.0


Quoi?
C'est un simple programme qui gère les lancements des programmes au démarrage. L'utilisateur peut désormais facilement grâce a une mini-interface, ajouter ou supprimer des lancements de programmes au démarrage de Windows.

Options:
Aussi un fichier Htm sera crée (une sorte de logfile, mais plus joli voir screenshot) pour se souvenir des précédentes manipulations et donc mieux s'y retrouver.

Faq
-Comment dois-je faire?
Pour ajouter un programme, indiquez le nom (sans trop d'importance) et l'exécutable.
Pour supprimer un programme, indiquez juste le nom (selon la colonne de gauche).

-Est ce dangereux?
En effet, il faut faire attention, et savoir ce que l'on ajoute ou supprime.

-Comment y vais-je manuellement?
Démarrer -> Exécuter -> Tapez Regedit
Chemin complet: HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run

-A quoi cela sert-il vraiment?
Si a chaque boot de votre pc, vous lancez systématiquement MSN, internet explorer, un script, il est pratique d'utiliser ce programme.

Source?

► Afficher le textepour voir le code

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TreeViewConstants.au3>
#include <StaticConstants.au3>
#include <IE.au3>
;====================================================================================
; Name              : Startup_software
; Description     : Manage the startup-software
; Author            : Jbnh <hardwarez@hotmail.co.uk>
; Note(s)           : Please be carefull with this kind of manipulation
; ===================================================================================

If Not FileExists("Startup_soft_log.htm") Then
    FileWrite("Startup_soft_log.htm","<font face=Verdana size=1> All your modifications...<br>")
EndIf

GUICreate("Startup", 430, 210)


$treeview = GUICtrlCreateTreeView(6, 6, 150, 200, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
$generalitem = GUICtrlCreateTreeViewItem("CurrentVersion\Run", $treeview)
GUICtrlSetColor(-1, 0x0000C0)
_GetInstalledItems()
GUICtrlSetState($generalitem, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))

Func _GetInstalledItems()
    $i = 0
    Do
        $i = $i + 1
        $var = RegEnumVal("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $i)
        If @error <> 0 Then $i = -1
        GUICtrlCreateTreeViewItem($var, $generalitem)
       
    Until $i = -1
Endfunc


GUICtrlCreateLabel("Nom", 160, 10) ;Le nom de la key 
$nom = GUICtrlCreateInput("", 190, 10, 210, 20)
GUICtrlCreateLabel("Path", 160, 40) ;Le chemin de l'executable
$path = GUICtrlCreateInput("", 190, 40, 210, 20)
$btn1 = GUICtrlCreateButton("...", 405, 40, 20, 20)
$btn2 = GUICtrlCreateButton("Create", 165, 70, 80)
$btn3 = GUICtrlCreateButton("Delete", 250, 70, 80)
$btn4 = GUICtrlCreateButton ("Annuler ",  335, 70, 80) 
$pic1 = GUICtrlCreatePic ("help.jpg", 170, 105, 255,100)


GUISetState(@SW_SHOW)

GUICtrlSetState($Btn2, $GUI_DISABLE)


While 1
   
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        
        Case $msg = $btn1
             $Opened_File = FileOpenDialog("Open Script/Executable File", "", "All executable Files (*.exe;*.au3)|All Files (*.*)",12)
             GUICtrlSetData($path, $Opened_File)
             GUICtrlSetState($btn2, $GUI_ENABLE)
             
        Case $msg = $btn2
            Regwrite ("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", GUICtrlRead($nom),"REG_SZ", GUICtrlRead($path))
            $var = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", GUICtrlRead($nom))
            
            If $var = GUICtrlRead($path) Then
            MsgBox(0, "Startup_Create", "The key has been well created")
            $file = FileOpen("Startup_soft_log.htm", 1)
            FileWrite($file, "The keyname <font color=#FF8000 style=font-size:12px><i>"&GUICtrlRead($nom)&"</i></font>with the value <font color=#FF8000 style=font-size:12px><i>"&GUICtrlRead($path)&"</i></font> has been created in "&@year&"\"&@mon&"\"&@mday&"<br> ")
            Else
            MsgBox(0, "Startup_Create", "An error occurred")
            Endif       
            
        
            ExitLoop  
        
          Case $msg = $btn3
            $var2 = RegDelete ("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", GUICtrlRead($nom))
                        
            If $var2 = 1 Then
            MsgBox(0, "Startup_Create", "The key has been well deleted")
            $file = FileOpen("Startup_soft_log.htm", 1)
            FileWrite($file, "The keyname <font color=#FF8000 style=font-size:12px><i>"&GUICtrlRead($nom)&"</i></font> has been deleted in "&@year&"\"&@mon&"\"&@mday&" <br>")
            Else
            MsgBox(0, "Startup_Create", "This name doesn't exist")
            Endif
                                
            ExitLoop
            
        Case $msg = $btn4
            ExitLoop 

            
        Case $msg = $pic1
            $oIE = _IECreate ("http://www.autoitscript.fr/forum/viewtopic.php?f=6&t=1114")
    EndSelect           
Wend

 

Historique
Version 1.0
-Creation Gui
-Premieres fonctions
-fichier log

Version 1.1
-Correction du code

Version 2.0
-Amelioration Gui
-Creation d'une FAQ
-Vue directe sur les HKEy


Jbnh.

[Tlem]

Bonsoir.

Je suggérerais une ou deux petites choses :

Code : Tout sélectionner

If Not FileExists("Startup_soft_log.htm") Then
    FileWrite("Startup_soft_log.htm","<font face=Verdana size=1> All your modifications...<br>")
EndIf

au lie de

Code : Tout sélectionner

If FileExists("Startup_soft_log.htm") Then
   
Else
    FileWrite("Startup_soft_log.htm","<font face=Verdana size=1> All your modifications...<br>")
EndIf

Ensuite, dans le

Code : Tout sélectionner

Case $msg = $btn2

j'utiliserais la vérification de l'écriture de la clé dans la BDR.
Idem pour le RegDelete de

Code : Tout sélectionner

Case $msg = $btn3

Et sur l'écriture du fichier aussi !

Voila ... Sinon ça m'a l'air sympa.

[jbnh]

Version 1.1 déja disponnible

Plusieurs améliorations à venir !

[jbnh]

Version 2.0 disponnible
-amélioration de l'interface
-creation d'une faq
-amélioration du code
-vue directe sur les HKEY

[Tlem]

Après un test rapide de la V2, ouverture de la page Web à plusieurs reprise sans action particulière.
Impossibilité de fermer la GUI normalement.
Impossibilité d'éditer les valeurs ajoutées.

Sinon, code propre et super boulot.

[jbnh]

Je vois très bien ce que tu veux dire tlem. Mais il est impératif de unzipper le rar dans un dossier, car l'image est utilisée par GUI. Si il trouve pas l'image, en effet, il ouvrira la page ie en boucle.

Aussi si quelqu'un a une idée pour mettre les HKEY par ordre alphabétique, elle est la bienvenue !

Voila a quoi ca ressemble avec l'image :

[Tlem]

Autant pour moi.
Il serait bien de contourner ce problème au cas ou l'image n'est pas disponible ...

[ani]

Aussi si quelqu'un a une idée pour mettre les HKEY par ordre alphabétique, elle est la bienvenue !

Il faut juste ajouter une include supplémentaire"

#include <GuiTreeView.au3>

Fonction = _GUICtrlTreeView_Sort($treeview)
On peut l'indiquer juste en dessous de GUICtrlSetState($generalitem, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))

ou juste avant la boucle while !!

Pour le HKEY_LOCAL_MACHINE tu peux indiquer HKLM c'est identique , je serais toi je creerai une variable supplémentaire comme ci-dessous.

Global $HKEY_RUN = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"

La fonction _GetInstalledItems() , tu devrai plutôt l'indiquer en bas de script, sinon elle fonctionne sur une partie de la ruche, pour la rendre universelle, j'ai indiqué _GetInstalledItems($Key, $IdControl), vu que j'ai un peu de mal à m'exprimer rien de tel que l'exemple :p

Code : Tout sélectionner

Func _GetInstalledItems($Key, $IdControl)
    $i = 0
    Do
        $i = $i + 1
        $var = RegEnumVal($Key, $i)
        If @error <> 0 Then $i = -1
        GUICtrlCreateTreeViewItem($var, $IdControl)
       
    Until $i = -1
Endfunc

Ensuite faudra juste changer _GetInstalledItems() par _GetInstalledItems($HKEY_RUN, $generalitem)

Je ne suis pas trop sûre, donc je pose la question
Est-ce juste si on inscrit par référence ? _GetInstalledItems(byref $key, byref $IdControl)


On peut aussi créer une variable pour l'image, Global $PIC_HELP = ".\help.jpg"

ceux-ci = .\ est identique à la macro @scriptdir

Dans le cas ou elle ne serait plus disponible, faudrai l'inclure dans l'exe avec fileinstall, comme çà pas deproblème, mais dans le cas ou l'utilisateur utilise juste l'au3 là je réflechi :p

Ensuite quand on crée des variables comme $btn1 ect faut les déclarer
genre = Dim $btn1, $btn2, $btn3, $btn4, $nom, $path (à indiquer juste avant guicreate ou juste en dessous des includes)

Sinon moi quand je le lance, j'ai en item Aucune donnée n'est disponible et ensuite le msconfig bizarre

je réediterai ce message

voilàvoilà

[chezsteph1]

Petit ajout pour afficher le contenu des clés via l'arborescence :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TreeViewConstants.au3>
#Include <GuiTreeView.au3>
#include <StaticConstants.au3>
#include <IE.au3>
;====================================================================================
; Name              : Startup_software
; Description     : Manage the startup-software
; Author            : Jbnh <hardwarez@hotmail.co.uk>
; Note(s)           : Please be carefull with this kind of manipulation
; ===================================================================================

If Not FileExists("Startup_soft_log.htm") Then
    FileWrite("Startup_soft_log.htm","<font face=Verdana size=1> All your modifications...<br>")
EndIf

GUICreate("Startup", 430, 210)


$treeview = GUICtrlCreateTreeView(6, 6, 150, 200, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)
$generalitem = GUICtrlCreateTreeViewItem("CurrentVersion\Run", $treeview)
GUICtrlSetColor(-1, 0x0000C0)
_GetInstalledItems()
GUICtrlSetState($generalitem, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
_GUICtrlTreeView_Sort($treeview)
Func _GetInstalledItems()
    $i = 0
    Do
        $i = $i + 1
        $var = RegEnumVal("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $i)
        If @error <> 0 Then $i = -1
        GUICtrlCreateTreeViewItem($var, $generalitem)
       
    Until $i = -1
Endfunc


GUICtrlCreateLabel("Nom", 160, 10) ;Le nom de la key 
$nom = GUICtrlCreateInput("", 190, 10, 210, 20)
GUICtrlCreateLabel("Path", 160, 40) ;Le chemin de l'executable
$path = GUICtrlCreateInput("", 190, 40, 210, 20)
$btn1 = GUICtrlCreateButton("...", 405, 40, 20, 20)
$btn2 = GUICtrlCreateButton("Create", 165, 70, 80)
$btn3 = GUICtrlCreateButton("Delete", 250, 70, 80)
$btn4 = GUICtrlCreateButton ("Annuler ",  335, 70, 80) 
$pic1 = GUICtrlCreatePic ("help.jpg", 170, 105, 255,100)


GUISetState(@SW_SHOW)

GUICtrlSetState($Btn2, $GUI_DISABLE)
GUIRegisterMsg($WM_NOTIFY, "WM_Notify_Events") ; Déclare la fonction WM_Notify_Events

While 1
   
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        
        Case $msg = $btn1
             $Opened_File = FileOpenDialog("Open Script/Executable File", "", "All executable Files (*.exe;*.au3)|All Files (*.*)",12)
             GUICtrlSetData($path, $Opened_File)
             GUICtrlSetState($btn2, $GUI_ENABLE)
             
        Case $msg = $btn2
            Regwrite ("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", GUICtrlRead($nom),"REG_SZ", GUICtrlRead($path))
            $var = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", GUICtrlRead($nom))
            
            If $var = GUICtrlRead($path) Then
            MsgBox(0, "Startup_Create", "The key has been well created")
            $file = FileOpen("Startup_soft_log.htm", 1)
            FileWrite($file, "The keyname <font color=#FF8000 style=font-size:12px><i>"&GUICtrlRead($nom)&"</i></font>with the value <font color=#FF8000 style=font-size:12px><i>"&GUICtrlRead($path)&"</i></font> has been created in "&@year&"\"&@mon&"\"&@mday&"<br> ")
            Else
            MsgBox(0, "Startup_Create", "An error occurred")
            Endif       
            
        
            ExitLoop  
        
          Case $msg = $btn3
            $var2 = RegDelete ("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", GUICtrlRead($nom))
                        
            If $var2 = 1 Then
            MsgBox(0, "Startup_Create", "The key has been well deleted")
            $file = FileOpen("Startup_soft_log.htm", 1)
            FileWrite($file, "The keyname <font color=#FF8000 style=font-size:12px><i>"&GUICtrlRead($nom)&"</i></font> has been deleted in "&@year&"\"&@mon&"\"&@mday&" <br>")
            Else
            MsgBox(0, "Startup_Create", "This name doesn't exist")
            Endif
                                
            ExitLoop
            
        Case $msg = $btn4
            ExitLoop
            
        Case $msg = $pic1
            $oIE = _IECreate ("http://www.autoitscript.fr/forum/viewtopic.php?f=6&t=1114")
    EndSelect           
Wend

Func Treeview_Click() ; action suite simple clic
    $cle = _GUICtrlTreeView_GetText($treeview,_GUICtrlTreeView_GetSelection($treeview))
    GUICtrlSetData($nom,$cle)
    GUICtrlSetData($path,RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $cle))
EndFunc ;==>Treeview_Click

Func WM_Notify_Events($hWndGUI, $MsgID, $wParam, $lParam) ; WM_NOTIFY event handler
    Local $tagNMHDR, $event
    $tagNMHDR = DllStructCreate("int;int;int", $lParam) ;NMHDR (hwndFrom, idFrom, code)
    If @error Then Return
    $event = DllStructGetData($tagNMHDR, 3)
    Select
        Case $wParam = $treeview
            Select
                Case $event = $NM_CLICK
                    Treeview_Click()
            EndSelect       
    EndSelect

    Return $GUI_RUNDEFMSG
EndFunc ;==>WM_Notify_Events
 

[ani]

Excellent chezsteph1

Doit manquer quelque chose ou c'est juste une petite erreur dans la fonction treeviewclick, car lors d'un click çà ne s'affiche pas de suite, faut reclicker.

bon bein moi je retourne en mode lecture encore et encore ^^'

Up jbnh