[..] Problème avec la fonction TrayItemSetText

[toM]

Bonjour,
J'ai un problème avec la fonction TrayItemSetText, qui sert à personnaliser le menu de la tray icône.
Soit le code ci-dessous :

Code : Tout sélectionner

#include <Constants.au3>

TraySetState()
TrayItemSetText($TRAY_ITEM_PAUSE, "Guard en pause")
TrayItemSetText($TRAY_ITEM_EXIT, "Quitter")

While 1
    Sleep(100)
WEnd
 

Sur mon PC, j'obtiens le message "r" pour les 2 entrées de menu (Script paused et Exit). Sur un autre PC, un caractère carré vide. J'ai bien l'impression que cette fonction marchait correctement auparavant. Là, je ne vois pas ce qui cloche . Lorsque j'omets les lignes TrayItemSetText, les menus par défaut apparaissent correctement.
Merci de votre aide.

ToM

PS : je ne me rappelle plus le titre que j'avais mis, donc je ne sais pas pourquoi il 'était pas conforme. J'espère que celui-ci est conforme...

[zeshrek]

Titre non conforme, merci de rectifier

[ethneldryt]

A ben ca alors je suis pas le seul ! Sur certain pc ca marche et d'autre petit carré aussi. Mais j'ai aussi un autre problème moi, quand je clique sur un item du tray menu, ben se menu, il se coche, alors qu'avant non.

[jchd]

Voici un exemple :

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>

Opt("TrayMenuMode", 1)      ; voici ce qu'il faut employer

$settingsitem   = TrayCreateMenu("Mon menu à moi perso dans mon coin")
$slowdown       = TrayCreateItem("Au ralenti", $settingsitem)
$pauseitem      = TrayCreateItem("En pause", $settingsitem)
TrayCreateItem("")
$aboutitem      = TrayCreateItem("A propos")
TrayCreateItem("")
$exititem       = TrayCreateItem("Quitter")

TraySetState()

While 1
    $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $aboutitem
            Msgbox(64,"A propos de : ","AutoIt3 exemple de menu personnalisé")
        Case $msg = $exititem
            ExitLoop
    EndSelect
WEnd

[sylvanie]

Bonsoir

Il s'agit bien d'un bug relaté sur le forum américain, dont visiblement un correctif est attendu en 3.7 ...
Le pb était plus relaté sur Win7, mais effectivement il est facilement reproductible sur XP

Le contournement de Jchd permet bien d'avoir l'affichage nickel, mais on fait une croix sur l'appel à la pause (ou alors il faut la réimplémenter)

En alternative demi-satisfaisante, on peut relancer le setitemtext dans le corps de message, car si on observe bien, c'est le premier click sur le tray qui ne marche pas. Il y a ensuite une sorte de déblocage, et là le settext fonctionne :

► Afficher le texte

Code : Tout sélectionner

#Include <Constants.au3>
#NoTrayIcon

Opt("TrayAutoPause",0)  ; Script will not be paused when clicking the tray icon.
Opt("TrayMenuMode",2)
$valitem    = TrayCreateItem("Val:")
TrayCreateItem("")
$aboutitem  = TrayCreateItem("About")

TraySetState()
_inittext()


While 1
    $msg = TrayGetMsg()
    _inittext()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $valitem
            TrayItemSetText($valitem,"Val:" & Int(Random(1,10,1)))
        Case $msg = $aboutitem
            Msgbox(64,"About&#058;","AutoIt3-Tray-sample")
    EndSelect
WEnd

Exit

Func _inittext()
    Static $is_initialized=0
    If Not $is_initialized Then
        if ( TrayItemSetText($TRAY_ITEM_EXIT,"Exit Program")* TrayItemSetText($TRAY_ITEM_PAUSE,"Pause Program") <> 0 ) Then $is_initialized=1
    EndIf
EndFunc
 

NB : la variable static permet de ne pas refaire l'action une fois qu'elle s'est faite correctement

[jchd]

Sylvanie, sans vouloir traîner dans la boue ton idée, je ne suis pas trop chaud au niveau du principe et voici pourquoi.

Certes on peut faire ainsi, mais s'il ne s'agit que de reimplémenter la pause, l'exit et une ligne entre les deux, ce n'est pas vraiment bien sorcier, pas plus que ce fix. Le problème avec une "astuce" comme ça est qu'elle repose sur deux choses instables : un bug abscons au niveau de la gestion du tray (dont seuls les devs connaissent les caractéristiques, et encore s'ils ont assez planché dessus, ce qui n'est pas une priorité) et une "feature" (static) qui ne fait pas partie intégrale du langage (et qui a aussi des bugs connus). Si on veux faire propre, il faut aussi documenter le "pourquoi on fait comme ça", ce qui revient à écrire un roman sur le bug qu'on contourne.

L'avantage qu'il y a dans la méthode où on créé le menu de toutes pièces est qu'on en maîtrise tous les aspects avec du code reposant sur des appels qui fonctionnent et de ce fait tout se trouve intégralement documenté rien qu'à l'examen du source.

D'ailleurs, on a aussi un souci similaire avec le gettext et le delete des items par défaut, ce qui complique encore la solution "hack".

Soit dit juste entre nous, tray et GUI ne sont pas forcément les meilleures parties d'AutoIt (au niveau du code d'AutoIt).
Par ailleurs, que _personne_ ne retienne sa respiration jusqu'à la sortie de la prochaine mouture stable...

[sylvanie]

Je ne considère point ceci comme un trainage dans la boue, tout le monde a le droit de s'exprimer ^^

Pour le static, on peut passer par une globale si on n'a pas confiance, par contre pour la pause, je ne la trouve pas si simple que ça à réimplémenter, car si on est "emprisonné" dans une boucle consommatrice en CPU, je ne pense pas qu'on puisse facilement interrompre celle-ci come le fait là pause native qui arrive à faire une interruption nette. C'est pour çà que je proposais cette version que je qualifiait bien de demi satisfaisante.

Par contre si on a une implémentation de pause qui est aussi efficace, effectivement c'est gangé.

[jchd]

Voici un exemple d'utilisation (idiot, je l'accorde). En pause, on ne consomme quasiment aucun CPU mesurable mais on a le contrôle complet sur le fonctionnement du tray et de ses composants.

► Afficher le textetext

Code : Tout sélectionner

#include <Constants.au3>

Global $pause = False

Opt("TrayMenuMode", 1)      ; voici ce qu'il faut employer
Opt("TrayOnEventMode", 1)   ; mode évènementiel

$settingsitem   = TrayCreateMenu("Réglages disponibles")
$opt1item       = TrayCreateItem("Option 1", $settingsitem)
TrayItemSetOnEvent(-1, "Option_1")
$opt2item       = TrayCreateItem("Option 2", $settingsitem)
TrayItemSetOnEvent(-1, "Option_2")
TrayCreateItem("")
$aboutitem      = TrayCreateItem("A propos")
TrayItemSetOnEvent(-1, "A_propos")
TrayCreateItem("")
$pauseitem      = TrayCreateItem("Pause")
TrayItemSetOnEvent(-1, "Pause")
TrayCreateItem("")
$exititem       = TrayCreateItem("Quitter")
TrayItemSetOnEvent(-1, "Quitter")

TraySetState()

While 1
    While $pause
        Sleep(50)
    WEnd
;; reste du traitement
    Sleep(10)
WEnd

Func Option_1()
    Local $onoff
    If BitAND(TrayItemGetState($opt1item), $TRAY_CHECKED) Then
        $onoff = "en"
    Else
        $onoff = "hors"
    EndIf
    MsgBox(0, "Réglages", "Option 1 " & $onoff & " fonction", 2)
EndFunc

Func Option_2()
    Local $onoff = "activée"
    If BitAND(TrayItemGetState($opt2item), $TRAY_CHECKED) Then
    Else
        $onoff = "dés" & $onoff
    EndIf
    MsgBox(0, "Réglages", "Option 2 " & $onoff, 2)
EndFunc

Func A_propos()
    TrayItemSetState($aboutitem, $TRAY_UNCHECKED)       ; pas besoin de voir cette entrée sélectionnée
    MsgBox(0, "A propos de ...", "Avec nos compliments.", 2)
EndFunc

Func Pause()
;~  Local $onoff
    If Not $pause Then
        TrayItemSetText($pauseitem, 'En pause ...')
        TraySetIcon(@AutoItExe, -3)
;~      TrayItemSetState($pauseitem, BitOR(TrayItemGetState($pauseitem), $TRAY_CHECKED))    ; au cas où l'option auto-check ne soit pas employée
        $pause = True
;~      $onoff = "en"
        MsgBox(0, "J'ai comme un coup de barre, là ...", "ZZZzzzzz", 1)
        TrayItemSetState($opt1item, BitOR(TrayItemGetState($opt1item), $TRAY_DISABLE))
    Else
        TrayItemSetText($pauseitem, 'Pause')
        TraySetIcon()
;~      TrayItemSetState($pauseitem, BitAND(TrayItemGetState($pauseitem), BitNOT($TRAY_UNCHECKED))) ; au cas où l'option auto-check ne soit pas employée
        $pause = False
;~      $onoff = "hors"
        TrayItemSetState($opt1item, BitOR(BitAND(TrayItemGetState($opt1item), BitNOT($TRAY_DISABLE)), $TRAY_ENABLE))
    EndIf
;~  MsgBox(0, "Suivi de la fonction pause", "La pause est " & $onoff & " fonction", 2)
EndFunc

Func Quitter()
    MsgBox(0, "Fin des hostilités", "Nous espérons vous revoir bientôt sur nos lignes.", 2)
    Exit
EndFunc

J'ai rendu l'option 1 non sélectable tant qu'on est en pause, tandis que l'emploi de l'option 2 est indifférent à la pause.
Si on sucre les variables et msgbox de démo, le code est robuste, compact et clair.

[sylvanie]

Bien vu