[..] Une Gui afaite avec une image .png (transparence)...

[Utilisateur 3643 supprimé]

Bonjour !!
je voudrait que quelqu'un me creer un script avec une gui .png c'est à dire qu'on ne voit pas la fenetre normale et banal de windows mais une image personnalisé avec de la transparence...
Je vous remercie d'avance


voici l'image:

[mikell]

Oula
Va y avoir du vent dans les voiles, le sujet a déjà été traité 127 fois...
Pour cette 128ème faudra l'approbation du boss avant d'espérer une réponse

[Tlem]

Ce forum est "Demande de création de Scripts", donc ça passe plus facilement que sur le forum d'aide générale.
Ici, l'utilisateur indique bien qu'il ne veut pas ou ne peut pas faire les choses par lui même !

Ceci dit, rien n’empêche d'indiquer les bonnes références ou de tout simplement dire que cela à déjà été abordé et que des exemples détaillés existent, mais que pour cela il faut jouer un peut avec l'outil d'aide du forum.

[mikell]

Alors OK

La gui est draggable et on ferme en cliquant sur la croix rouge ^^

► Afficher le texte

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
 
Global $hGUI2, $hImage

; gui principale
$hGUI2 = GUICreate("Test", 400, 400, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
$exit = GuiCtrlCreateLabel("", 290, 80, 30, 30)
GUICtrlSetState(-1, $GUI_ONTOP) 
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUISetState()

_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\GUI.png")
SetBitMap($hGUI2, $hImage, 255)

; gui pour placer des controles
$gui_bis = GUICreate("", 400, 400, 0, 0, $WS_POPUP, $WS_EX_LAYERED  + $WS_EX_COMPOSITED + $WS_EX_MDICHILD, $hGUI2) 
$btn = GuiCtrlCreateButton("bouton", 200, 200, 60, 30)  ; exemple ^^
GUICtrlSetBkColor(-1, 0xf0f0ff)
GUISetBkColor(0x00FF00)
_WinAPI_SetLayeredWindowAttributes($gui_bis, 0x00FF00)
GUISetState(@SW_SHOWNOACTIVATE)  ; pour éviter le focus moche sur le controle

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")


While 1
$msg = GuiGetMsg()
If $msg = $exit Then ExitLoop
If $msg = $btn Then Msgbox(0,"", "bouton pressé")
Wend

_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()

;=====================================================

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
  if ($hWnd = $hGUI2) and ($iMsg = $WM_NCHITTEST) then Return $HTCAPTION
EndFunc


Func SetBitmap($hGUI, $hImage, $iOpacity)
  Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
  $hScrDC  = _WinAPI_GetDC(0)
  $hMemDC  = _WinAPI_CreateCompatibleDC($hScrDC)
  $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
  $hOld    = _WinAPI_SelectObject($hMemDC, $hBitmap)
  $tSize   = DllStructCreate($tagSIZE)
  $pSize   = DllStructGetPtr($tSize  )
  DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth ($hImage))
  DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
  $tSource = DllStructCreate($tagPOINT)
  $pSource = DllStructGetPtr($tSource)
  $tBlend  = DllStructCreate($tagBLENDFUNCTION)
  $pBlend  = DllStructGetPtr($tBlend)
  DllStructSetData($tBlend, "Alpha" , $iOpacity    )
  DllStructSetData($tBlend, "Format", 1)
  _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
  _WinAPI_ReleaseDC   (0, $hScrDC)
  _WinAPI_SelectObject($hMemDC, $hOld)
  _WinAPI_DeleteObject($hBitmap)
  _WinAPI_DeleteDC    ($hMemDC)
EndFunc