[R] Modifier les couleurs des pixels

[karime1]

bonjours,
je cherche un moyen pour pouvoir rendre tout les pixels d'une image noir a part ceux dont le code est égale a 0xFDFDFD ou plus.
merci

[PandiPanda]

Pour faire avancé un peu

L'image en question, on peux l'afficher à l'ecran = monopolise l'ecran pour un moment
Ou il faut obligatoirement que tous ce fasse en "mémoire" sans passer par l'ecran?

en gros voici un script qui permet de recuperer dans un array 2D les pixels

► Afficher le texteca vien du fofo anglais ... ^^

Code : Tout sélectionner

Func _GetArrayColorPixelFromImg($Path)
    If $Path <> "" Then
        _GDIPlus_Startup()
        Local $hImage,$width,$height,$hBmp,$aSize
        $hImage = _GDIPlus_ImageLoadFromFile($Path)
        $width = _GDIPlus_ImageGetWidth($hImage)
        $height = _GDIPlus_ImageGetHeight($hImage)
        $hBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
        $aSize = DllCall('gdi32.dll', 'int', 'GetBitmapBits', 'ptr', $hBmp, 'int', 0, 'ptr', 0)
        If $aSize[0] Then
            Local $tBits,$sHex,$pix[$height][$width],$aTemp,$aArr
            $tBits = DllStructCreate('byte[' & $aSize[0] & ']')
            DllCall('gdi32.dll', 'int', 'GetBitmapBits', 'ptr', $hBmp, 'int', $aSize[0], 'ptr', DllStructGetPtr($tBits))
            $sHex = Hex(DllStructGetData($tBits, 1))
            $sHex = StringRegExpReplace($sHex, "([[:xdigit:]]{6})(FF)", "\1 ")
            $aArr = StringRegExp($sHex, "(.{" & ($width * 7) & "})", 3)
            For $x = 0 To UBound($aArr) - 1
                $aTemp = StringRegExp($aArr[$x] & " ", "(.{6}) ", 3)
                For $y = 0 To UBound($aTemp) - 1
                    $pix[$x][$y] = StringRegExpReplace($aTemp[$y], "(.{2})(.{2})(.{2})", "\3\2\1") ; To RGB format
                Next
            Next
            _WinAPI_DeleteObject($hBmp)
            _GDIPlus_ImageDispose($hImage)
            _GDIPlus_Shutdown()
            Return $pix
        EndIf
    Else
        SetError(1);erreur parametre
        Return -1
    EndIf
EndFunc

Il faudrai maintenant parcourir le tout par une double boucle for ... next et chercher ce que vous voulez et le remplacer

Ps: je passe la main ...

[karime1]

merci pour ton idée. j'ai refait la func, maintenant j'obtient une array beaucoup plus lègère puisque j'ai directement 1 et 0 (blanc ou noir). tout ce qui reste a faire c'est de reconstituer une image a partir de l'array

Code : Tout sélectionner

Dim $pix_true_color
Func _GetArrayColorPixelFromImg($Path)
    If $Path = "" Then
        SetError(1);erreur parametre
        Return -1
    EndIf

    _GDIPlus_Startup()
    Local $hImage, $width, $height, $hBmp, $aSize
    $hImage = _GDIPlus_ImageLoadFromFile($Path)
    $width = _GDIPlus_ImageGetWidth($hImage)
    $height = _GDIPlus_ImageGetHeight($hImage)
    $hBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $aSize = DllCall('gdi32.dll', 'int', 'GetBitmapBits', 'ptr', $hBmp, 'int', 0, 'ptr', 0)
    If $aSize[0] Then
        Local $tBits, $sHex, $pix[$height][$width], $aTemp, $aArr
        $tBits = DllStructCreate('byte[' & $aSize[0] & ']')
        DllCall('gdi32.dll', 'int', 'GetBitmapBits', 'ptr', $hBmp, 'int', $aSize[0], 'ptr', DllStructGetPtr($tBits))
        $sHex = Hex(DllStructGetData($tBits, 1))
        $sHex = StringRegExpReplace($sHex, "([[:xdigit:]]{6})(FF)", "\1 ")
        $aArr = StringRegExp($sHex, "(.{" & ($width * 7) & "})", 3)
        For $x = 0 To UBound($aArr) - 1
            $aTemp = StringRegExp($aArr[$x] & " ", "(.{6}) ", 3)
            For $y = 0 To UBound($aTemp) - 1
                $pix_true_color = StringRegExpReplace($aTemp[$y], "(.{2})(.{2})(.{2})", "\3\2\1") ; To RGB format
                If Number("0x" & $pix_true_color) >= 16645629 Then ; Number(0xFDFDFD)=16645629
                    $pix[$x][$y] = "1";blanc
                Else
                    $pix[$x][$y] = "0" ; noir
                EndIf
            Next
        Next
        _WinAPI_DeleteObject($hBmp)
        _GDIPlus_ImageDispose($hImage)
        _GDIPlus_Shutdown()
        Return $pix
    EndIf
EndFunc   ;==>_GetArrayColorPixelFromImg

[PandiPanda]

sinon j'ai vu ca sur ce forum en faisant une petite recherche ^^

ici
peut être cela pourrai vous être utile?

[karime1]

merci

► Afficher le texte

Code : Tout sélectionner

_GDIPlus_Startup()
ChangerCouleur(@DesktopDir & '\1.jpg', @DesktopDir & '\2.bmp')
_GDIPlus_Shutdown()
MsgBox(0, "Fin", "Transformation terminée.")
Func ChangerCouleur($Nom1, $Nom2)
    Local $Dimentions[2]
    Local $Pixel
    If Not (FileExists($Nom1)) Then
        SetError(1)
        Return 0
    EndIf

        $hImage = _GDIPlus_ImageLoadFromFile($Nom1)
        $Dimentions = DimentionsImages($hImage)
        For $j = 0 To $Dimentions[1]-1
            For $i = 0 To $Dimentions[0]-1
                $Pixel = _GDIPlus_BitmapGetPixel($hImage, $i, $j)
                If Number($Pixel) >= Number("0xFFFDFDFD") Then
                    _GDIPlus_BitmapSetPixel($hImage, $i, $j, 0xFFFFFFFF)
                Else
                    _GDIPlus_BitmapSetPixel($hImage, $i, $j, 0xFF000000)
                EndIf
            Next
        Next
        _GDIPlus_ImageSaveToFile($hImage, $Nom2)
        _GDIPlus_ImageDispose($hImage)
EndFunc


Func _GDIPlus_BitmapGetPixel($hBitmap, $iX, $iY)
    Local $tArgb, $pArgb, $aRet
    $tArgb = DllStructCreate("dword Argb")
    $pArgb = DllStructGetPtr($tArgb)
    $aRet = DllCall($ghGDIPDll, "int", "GdipBitmapGetPixel", "hwnd", $hBitmap, "int", $iX, "int", $iY, "ptr", $pArgb)
    Return "0x" & Hex(DllStructGetData($tArgb, "Argb"))
EndFunc

Func _GDIPlus_BitmapSetPixel($hBitmap, $iX, $iY, $iArgb)
    DllCall($ghGDIPDll, "int", "GdipBitmapSetPixel", "hwnd", $hBitmap, "int", $iX, "int", $iY, "dword", $iArgb)
EndFunc

Func DimentionsImages($Image)
    Local $Taille[2] = [-1, -1]
    Local $hImage
    If(FileExists($Image) Or IsPtr($Image)) Then
        If(IsPtr($Image)) Then
            $hImage = $Image
        Else
            $hImage = _GDIPlus_ImageLoadFromFile($Image)
        EndIf
        $Taille[0] = _GDIPlus_ImageGetWidth($hImage)
        $Taille[1] = _GDIPlus_ImageGetHeight($hImage)
        If($hImage <> $Image) Then
            _GDIPlus_ImageDispose($hImage)
        EndIf
    EndIf
    Return $Taille
EndFunc
 

;source original : http://autoit.fr/forum/viewtopic.php?p=40195#p40195 ;rééditer par karime1

[PandiPanda]

Même si votre post est résolu, voici la réponse pour créer une image avec les pixel ^^

► Afficher le texte

Code : Tout sélectionner

#Include <GDIPlus.au3>

Local $pathFile=@ScriptDir&"\test.bmp"
_GDIPlus_Startup()

Local $array=_GetArrayColorPixelFromImg($pathFile)
Local $width=UBound($array,2) ; <---> largeur
Local $heigth=UBound($array,1); hauteur

$hImage = _GDIPlus_BitmapCreateFromScan0($width,$heigth)
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)
$hPen = _GDIPlus_PenCreate()

For $x=0 To $width-1
    For $y=0 To $heigth-1
        If $array[$y][$x]=1 Then
            _GDIPlus_PenSetColor($hPen, 0xFFFFFFFF)
        Else
            _GDIPlus_PenSetColor($hPen, 0xFF000000)
        EndIf
        _GDIPlus_GraphicsDrawRect($hGraphic, $x, $y, 1, 1, $hPen)
    Next
Next
_GDIPlus_ImageSaveToFile($hImage, @ScriptDir & "\test2.bmp")

Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iStride = 0, $iPixelFormat = 0x0026200A, $pScan0 = 0)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "int*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aResult[6]
EndFunc

Func _GetArrayColorPixelFromImg($Path)
    If $Path = "" Then
        SetError(1);erreur parametre
        Return -1
    EndIf

    _GDIPlus_Startup()
    Local $hImage, $width, $height, $hBmp, $aSize
    $hImage = _GDIPlus_ImageLoadFromFile($Path)
    $width = _GDIPlus_ImageGetWidth($hImage)
    $height = _GDIPlus_ImageGetHeight($hImage)
    $hBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $aSize = DllCall('gdi32.dll', 'int', 'GetBitmapBits', 'ptr', $hBmp, 'int', 0, 'ptr', 0)
    If $aSize[0] Then
        Local $tBits, $sHex, $pix[$height][$width], $aTemp, $aArr
        $tBits = DllStructCreate('byte[' & $aSize[0] & ']')
        DllCall('gdi32.dll', 'int', 'GetBitmapBits', 'ptr', $hBmp, 'int', $aSize[0], 'ptr', DllStructGetPtr($tBits))
        $sHex = Hex(DllStructGetData($tBits, 1))
        $sHex = StringRegExpReplace($sHex, "([[:xdigit:]]{6})(FF)", "\1 ")
        $aArr = StringRegExp($sHex, "(.{" & ($width * 7) & "})", 3)
        For $x = 0 To UBound($aArr) - 1
            $aTemp = StringRegExp($aArr[$x] & " ", "(.{6}) ", 3)
            For $y = 0 To UBound($aTemp) - 1
                $pix_true_color = StringRegExpReplace($aTemp[$y], "(.{2})(.{2})(.{2})", "\3\2\1") ; To RGB format
                If Number("0x" & $pix_true_color) >= 16645629 Then ; Number(0xFDFDFD)=16645629
                    $pix[$x][$y] = "1";blanc
                Else
                    $pix[$x][$y] = "0" ; noir
                EndIf
            Next
        Next
        _WinAPI_DeleteObject($hBmp)
        _GDIPlus_ImageDispose($hImage)
        _GDIPlus_Shutdown()
        Return $pix
    EndIf
EndFunc   ;==>_GetArrayColorPixelFromImg

j'ai repris votre "modification" avec l'array qui contient les "0" & "1" et donc crée une image avec celle ci !