[R] Sauvegarde choix de Checkbox pour utilisation ultérieur

[Chrono47]

Bonjour à tous.

Je vous explique brièvement ce que je recherche :

J'ai crée un petit logiciel qui me permet d'installer de façon automatique et silencieuse une suite de différents logiciels (Firefox, Avast, Open Office etc) à l'aide de checkbox toute bête (en gros, si la checkbox 1 est cochée alors on installe Avast, si la checkbox 2 est cochée alors on installe OpenOffice ...)

Ca m'aide dans mon travail, car je dépanne des PC et les clients aiment bien retrouver la plupart des logiciels après un format ou une réinstallation du système par exemple.

Le truc, c'est que souvent les clients reviennent après quelques mois pour d'autres choses (des virus ou des plantages ...) et que j'aimerai pouvoir leur reinstaller leur suite logiciel au possible au mieux, même si le système est HS et qu'il ne démarre pas et qu'il m'est donc impossible de faire la " liste " de logiciels.

Cas concret :

Le client vient aujourd'hui le 24/07/2012 pour des lenteurs sur son PC, après diagnostique je m'aperçois que des virus sont présents sur sa machine et je décide donc de reinstaller complètement son système afin de repartir sur quelque chose de propre, je me munis donc d'un petit papier et d'un crayon, note les logiciels qui sont installés sur son PC : Avast, Open Office, Chrome, Picasa.

Je lance la reinstallation de son système, hop Windows s'installe et j'arrive sur le bureau, je file sur mon serveur, je lance mon logiciel d'auto installer de fichier et je coche les cases : Avast / Open Office Chrome & Picasa et je clique sur " Installer "

Et là, c'est ici que j'ai un grand besoin d'aide, j'aimerai qu'au moment ou je clique sur " Installer " un fichier (texte ?) se crée sur le disque du client à une adresse qui sera toujours la même (par exemple : C:\Reinstallation\ListingLogiciels.txt) et enregistre le choix des logiciels de ce clients.

De sorte à ce que, le 29 Septembre 2012 si le client revient encore pour des virus (beaucoup aiment ça faut croire ) mais que le Windows ne démarre plus du tout cette fois, avoir le choix au moment du lancement de mon logiciel d'installation automatique (après la réinstallation du Windows donc) avoir une fenêtre du genre " Un fichier listing pour ce client a été trouvé, voulez-vous le réutilisé ou en crée un nouveau après un nouveau choix ? ", ainsi si je choisis d'utiliser ce fichier listing, sont cochés automatiquement Avast, Open Office, Chrome & Picasa et que je n'ai plus qu'à cliquer sur installer pour lancé l'installation !

ça serait vraiment très pratique pour moi, car je vois environ 20 clients par jour, 6 jours / semaine et j'ai donc environ 100/120 pc par semaine qui viennent avec tous des logiciels différents, et que le fait d'avoir la liste trouvé à chaque fois me ferai gagné un temps fou (pour la reinstallation, mais surtout pour le SAV que j'aurai en moins, à savoir le client qui m'appelle deux jours après en me disant " mais pourquoi vous m'avez pas remis Picasa cette fois ?? "


Bref, si quelqu'un à un début de script qui permet de faire ça, je me débrouillerai pour l'implanter dan mon script actuel.

J'ai également une petite question concernant les checkbox à savoir, est-il possible de choisir l'ordre d'execution de ces checkbox :

Prenons :

Checkbox 1 = Avast
Checkbox 2 = OpenOffice
Checkbox 3 = Chrome

Si je choisis les trois logiciels à installer, automatiquement ça va commencer par Avast, puis Open Office pour enfin finir par Chrome ... est-il possible de chambouler ces ordres sans changer l'ordre des logiciels au niveau des checkbox (en gros, la solution " change l'ordre des logiciels dans les checkbox (Checkbox 1 = Open Office, Checkbox 2 = Avast ...) ne m'intéresse pas, car j'ai selon les cas de figure (du système d'exploitation en faite) besoin d'installer en premier avast, ou des fois en premier Open Office !)


Merci pour votre aide, aussi minime qu'elle soit, car j'ai vraiment pas le temps de m'occuper de ça en ce moment (et oui, c'est pas les vacances pour tout le monde )

Cdt

Chrono

[PandiPanda]

Bonjour,

ceci vous conviendrai? ^^
Si vous avez besoin d'explication sur le fonctionnement du script ou pour la modification, n'hésitez pas ...
*j'ai pas vraiment commenté '^^*

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Include <Array.au3>
#Include <File.au3>

#region variable Globale
    Dim $ordreExecution[1]=[0]
    Global $nbProgramme = 3
    Global $execution[$nbProgramme]=["_1erChoix","_2emeChoix","_3meChoix"]
    Global $checked[$nbProgramme]=[false,false,False]
    Global $pathFileWrite = @HomeDrive&"\test1.chrono"
    Local $n=0
#endregion

#Region ### START Koda GUI section ### Form=
    Global $Form1_1 = GUICreate("Form1", 206, 124, 192, 124)
    Global $Label1 = GUICtrlCreateLabel("2eme choix", 16, 32, 58, 17)
    Global $Label2 = GUICtrlCreateLabel("1er choix", 16, 8, 47, 17)
    Global $Label3 = GUICtrlCreateLabel("3eme choix", 16, 56, 58, 17)
    Global $checkBox[$nbProgramme] = [GUICtrlCreateCheckbox("Checkbox1", 80, 8, 17, 17), _
    GUICtrlCreateCheckbox("Checkbox1", 80, 32, 17, 17),GUICtrlCreateCheckbox("Checkbox3", 80, 56, 17, 17)]
    Global $Button1 = GUICtrlCreateButton("Run", 16, 88, 81, 25, $WS_GROUP)
    Global $Button2 = GUICtrlCreateButton("charger", 104, 80, 81, 25, $WS_GROUP)
    GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            If IsArray($ordreExecution) And $ordreExecution[0] > 0 Then
                For $i=1 To $ordreExecution[0]
                    Call($ordreExecution[$i])
                Next
                _writeChoix($pathFileWrite,$ordreExecution)
            Else
                MsgBox(48,"erreur","faites au moins un choix")
            EndIf
        Case $Button2
            Local $path = FileOpenDialog("fichier type chrono",@HomeDrive,"(*.chrono)")
            If $path <> "" Then _readChoix($path)
        EndSwitch
    If ( GUICtrlRead($checkBox[$n]) = $GUI_CHECKED And (Not $checked[$n]) ) Then
        $checked[$n] = True
        _ArrayAdd($ordreExecution,$execution[$n])
        $ordreExecution[0] = $ordreExecution[0] + 1
    ElseIf ( GUICtrlRead($checkBox[$n]) = $GUI_UNCHECKED And ($checked[$n]) ) Then
        $checked[$n] = False
        Local $iSearch = _ArraySearch($ordreExecution,$execution[$n])
        If Not @error Then
            _ArrayDelete($ordreExecution,$iSearch)
            $ordreExecution[0] = $ordreExecution[0] - 1
        EndIf
    EndIf
    $n = Mod($n+1,$nbProgramme)
WEnd

Func _1erChoix()
    MsgBox(0,"1er choix","1er choix OK")
EndFunc

Func _2emeChoix()
    MsgBox(0,"2eme choix","2eme choix OK")
EndFunc

Func _3meChoix()
    MsgBox(0,"3eme choix","3eme choix OK")
EndFunc

Func _writeChoix($pathFile,$a_array)
    _FileWriteFromArray($pathFile,$a_array,1)
EndFunc
Func _readChoix($pathFile)
    Local $array
    _FileReadToArray($pathFile,$array)
    For $i=1 To $array[0]
        Local $iSearch = _ArraySearch($execution,$array[$i])
        If Not @error Then
            GUICtrlSetState($checkBox[$iSearch],$GUI_CHECKED)
        EndIf
    Next
EndFunc

[Chrono47]

Merci pour votre aide PandiPanda, j'épluche ce code et j'essaye de l'adapter au mien dés que j'ai 5 minutes à moi (bon allez, peut-être que dix me seront nécessaire !)


En tout cas, merci beaucoup pour votre rapidité !


(Cependant, aucune idée pour mon second problème ? à savoir l'ordre des checkbox ?)

[Chrono47]

Je viens de regarder et c'est un très bon début, cependant est-il possible de faire en sorte que lorsqu'on lance le logiciel, il cherche automatiquement la présence du fichier ".chrono" sur le disque dur et me propose si je veux ou non l'utiliser ? plutôt que de devoir le charger " à la main " ?

[PandiPanda]

pour votre demande, ceci?

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Include <Array.au3>
#Include <File.au3>

#region variable Globale
    Dim $ordreExecution[1]=[0]
    Global $nbProgramme = 3
    Global $execution[$nbProgramme]=["_1erChoix","_2emeChoix","_3meChoix"]
    Global $checked[$nbProgramme]=[false,false,False]
    Global $pathFileWrite = @HomeDrive&"\test1.chrono"
    Local $n=0
#endregion

#Region ### START Koda GUI section ### Form=
    Global $Form1_1 = GUICreate("Form1", 206, 124, 192, 124)
    Global $Label1 = GUICtrlCreateLabel("2eme choix", 16, 32, 58, 17)
    Global $Label2 = GUICtrlCreateLabel("1er choix", 16, 8, 47, 17)
    Global $Label3 = GUICtrlCreateLabel("3eme choix", 16, 56, 58, 17)
    Global $checkBox[$nbProgramme] = [GUICtrlCreateCheckbox("Checkbox1", 80, 8, 17, 17), _
    GUICtrlCreateCheckbox("Checkbox1", 80, 32, 17, 17),GUICtrlCreateCheckbox("Checkbox3", 80, 56, 17, 17)]
    Global $Button1 = GUICtrlCreateButton("Run", 16, 88, 81, 25, $WS_GROUP)
    Global $Button2 = GUICtrlCreateButton("charger", 104, 80, 81, 25, $WS_GROUP)
    GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
#region chercherFileChrono
    If FileExists($pathFileWrite) Then
        Local $ret = MsgBox(4,"trouvé","voulez vous utilisez le fichier .chrono trouvé ?")
        If $ret = 6 Then _readChoix($pathFileWrite)
    EndIf
#endregion
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            If IsArray($ordreExecution) And $ordreExecution[0] > 0 Then
                For $i=1 To $ordreExecution[0]
                    Call($ordreExecution[$i])
                Next
                _writeChoix($pathFileWrite,$ordreExecution)
            Else
                MsgBox(48,"erreur","faites au moins un choix")
            EndIf
        Case $Button2
            Local $path = FileOpenDialog("fichier type chrono",@HomeDrive,"(*.chrono)")
            If $path <> "" Then _readChoix($path)
        EndSwitch
    If ( GUICtrlRead($checkBox[$n]) = $GUI_CHECKED And (Not $checked[$n]) ) Then
        $checked[$n] = True
        _ArrayAdd($ordreExecution,$execution[$n])
        $ordreExecution[0] = $ordreExecution[0] + 1
    ElseIf ( GUICtrlRead($checkBox[$n]) = $GUI_UNCHECKED And ($checked[$n]) ) Then
        $checked[$n] = False
        Local $iSearch = _ArraySearch($ordreExecution,$execution[$n])
        If Not @error Then
            _ArrayDelete($ordreExecution,$iSearch)
            $ordreExecution[0] = $ordreExecution[0] - 1
        EndIf
    EndIf
    $n = Mod($n+1,$nbProgramme)
WEnd

Func _1erChoix()
    MsgBox(0,"1er choix","1er choix OK")
EndFunc

Func _2emeChoix()
    MsgBox(0,"2eme choix","2eme choix OK")
EndFunc

Func _3meChoix()
    MsgBox(0,"3eme choix","3eme choix OK")
EndFunc

Func _writeChoix($pathFile,$a_array)
    _FileWriteFromArray($pathFile,$a_array,1)
EndFunc
Func _readChoix($pathFile)
    Local $array
    _FileReadToArray($pathFile,$array)
    For $i=1 To $array[0]
        Local $iSearch = _ArraySearch($execution,$array[$i])
        If Not @error Then
            GUICtrlSetState($checkBox[$iSearch],$GUI_CHECKED)
        EndIf
    Next
EndFunc

[Chrono47]

Extra !!

Merci (Maintenant il ne me reste plus qu'à comprendre votre code et l’implanter dans le mien, mais le plus gros du boulot est fait, encore merci !!)